boot.ld

来自「ks8695 loader > > > > > &」· LD 代码 · 共 60 行

ENTRY(vectors)

MEMORY
{
	rom : ORIGIN = 0x0, LENGTH = 0x6000
	sram : ORIGIN = 0x400000, LENGTH = 0x2000
	ram : ORIGIN = 0x4300000, LENGTH = 0x100000
}

SECTIONS
{
	.vectors 0x0: AT (0)
	{
		KEEP( loader0.o );
	} > rom
	.softboot_text 0x400000 : AT ((LOADADDR(.vectors) + SIZEOF(.vectors) + 3) & ~ 3)
	{
		__softboot_text_ram_start = ABSOLUTE(.);
		softboot.o(*.text*);
	} > sram
	.softboot_data ALIGN(4) : AT ((LOADADDR(.softboot_text) +SIZEOF(.softboot_text) + 3) & ~ 3)
	{
		softboot.o(*.rodata*)
		softboot.o(*.data*);
	} > sram
	.softboot_bss ALIGN(4) :
	{
		softboot.o(*.bss*);
		softboot.o(COMMON);
		__softboot_bss_end = ABSOLUTE(.);
	} >sram
	__softboot_text_rom_start = LOADADDR (.softboot_text);
	__softboot_data_rom_end = LOADADDR (.softboot_data) + SIZEOF(.softboot_data);

	.text 0x4300000 : AT ((LOADADDR(.softboot_data) + SIZEOF(.softboot_data) + 3) & ~ 3)
	{
		__main_text_ram_start = ABSOLUTE(.);
		*(*.text*);
	} > ram
	.data ALIGN(4) : AT ((LOADADDR(.text) +SIZEOF(.text) + 3) & ~ 3)
	{		
		*(*.rodata*);
		*(*.data*);
		__main_ram_data_end = ABSOLUTE(.);
	} > ram
	.bss ALIGN(4) :
	{
		*(*.bss*);
		*(COMMON);
		__bss_end = ABSOLUTE(.);
	} > ram
	.glue ALIGN(4) :
	{
		*(*.glue*);
	} > ram
	__main_text_rom_start = LOADADDR (.text);
	__main_data_rom_end = LOADADDR (.data) + SIZEOF(.data);

}