configure.ac

CFL是Unix下的通用抽象库,以简化Unix下的系统软件开发,CFL库中包含几个分组的函数和宏

# Process this file with autoconf to produce a configure script.
AC_INIT(libcfl, 1.1.1, [e-mail])
AM_INIT_AUTOMAKE(libcfl, 1.1.1)
AM_CONFIG_HEADER([config.h])

# Checks for programs.
AC_PROG_CC
AC_PROG_LIBTOOL

# Checks for libraries.

# Checks for header files.
AC_HEADER_DIRENT
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/file.h sys/ioctl.h sys/time.h termios.h unistd.h stdint.h crypt.h stropts.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_UID_T
AC_C_INLINE
AC_TYPE_MODE_T
AC_TYPE_OFF_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
AC_STRUCT_TM

dnl Checks for POSIX socket types

AH_TEMPLATE([HAVE_TYPE_IN_ADDR_T], [Define if netinet/in.h or sys/types.h defines in_addr_t])

AC_MSG_CHECKING(for in_addr_t in netinet/in.h or sys/types.h)
AC_TRY_COMPILE([#include <sys/types.h>
#include <netinet/in.h>],
[in_addr_t t;],
AC_DEFINE(HAVE_TYPE_IN_ADDR_T)
AC_MSG_RESULT(yes),
AC_MSG_RESULT(no))

AH_TEMPLATE([HAVE_TYPE_IN_PORT_T], [Define if netinet/in.h or sys/types.h defines in_port_t])

AC_MSG_CHECKING(for in_port_t in netinet/in.h or sys/types.h)
AC_TRY_COMPILE([#include <sys/types.h>
#include <netinet/in.h>],
[in_port_t t;],
AC_DEFINE(HAVE_TYPE_IN_PORT_T)
AC_MSG_RESULT(yes),
AC_MSG_RESULT(no))

dnl Checks for gethostbyname_r & friends

AC_SEARCH_LIBS(gethostbyname_r, [socket nsl])
AC_SEARCH_LIBS(getservbyname_r, [socket nsl])

AH_TEMPLATE([HAVE_GETxxxxBYyyyy_R_POSIX], [Define if POSIX-style getXXXXbyYYYY_r functions are available.])

AC_MSG_CHECKING([for POSIX-style gethostbyXXXX_r and getservbyXXXX_r])
AC_TRY_LINK([
#define _POSIX_PTHREAD_SEMANTICS
#include <netdb.h>
],
[
  struct hostent *he;
  struct servent *se;

  he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL,
	(char *)NULL, (int)0, (struct hostent **)NULL, (int *)NULL);
  he = gethostbyaddr_r((const char *)NULL, (int)0, (int)0,
	(struct hostent *)NULL, (char *)NULL, (int)0, (struct hostent **)NULL,
	(int *)NULL);

  se = getservbyname_r((const char *)NULL, (const char *)NULL,
	(struct servent *)NULL, (char *)NULL, (int)0, (struct servent **)NULL);
  se = getservbyport_r((int)0, (const char *)NULL,
	(struct servent *)NULL, (char *)NULL, (int)0, (struct servent **)NULL);
],
AC_DEFINE(HAVE_GETxxxxBYyyyy_R_POSIX)
AC_MSG_RESULT(yes),
AC_MSG_RESULT(no)
)

AH_TEMPLATE([HAVE_GETxxxxBYyyyy_R_SUN], [Define if Solaris-style getXXXXbyYYYY_r functions are available.])

AC_MSG_CHECKING([for Solaris-style gethostbyXXXX_r and getservbyXXXX_r])
AC_TRY_LINK([
#define _POSIX_PTHREAD_SEMANTICS
#include <netdb.h>
],
[ struct hostent *he;
  struct servent *se;

  he = gethostbyname_r((const char *)NULL, (struct hostent *)NULL,
	(char *)NULL, (int)0, (int *)NULL);
  he = gethostbyaddr_r((const char *)NULL, (int)0, (int)0,
	(struct hostent *)NULL, (char *)NULL, (int)0, (int *)NULL);

  se = getservbyname_r((const char *)NULL, (const char *)NULL,
	(struct servent *)NULL, (char *)NULL, (int)0);
  se = getservbyport_r((int)0, (const char *)NULL,
	(struct servent *)NULL, (char *)NULL, (int)0);
],
AC_DEFINE(HAVE_GETxxxxBYyyyy_R_SUN)
AC_MSG_RESULT(yes),
AC_MSG_RESULT(no)
)

dnl Checks for BSD-style pty function

AH_TEMPLATE([HAVE_OPENPTY], [Define to 1 if you have the `openpty' function.])

AC_MSG_CHECKING(for openpty)
AC_TRY_COMPILE([#include <util.h>],
[int main(void)
{
int mfd, sfd;

return(openpty(&mfd, &sfd, 0, 0, 0));
}],
AC_DEFINE(HAVE_OPENPTY)
AC_MSG_RESULT(yes),
AC_MSG_RESULT(no))

dnl Checks for library functions.

AC_FUNC_CLOSEDIR_VOID
AC_FUNC_FORK
AC_PROG_GCC_TRADITIONAL
AC_FUNC_LSTAT
AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
AC_FUNC_MKTIME
AC_FUNC_MMAP
AC_FUNC_REALLOC
AC_FUNC_SELECT_ARGTYPES
AC_FUNC_SETVBUF_REVERSED
AC_FUNC_STAT
AC_FUNC_STRFTIME
AC_FUNC_VPRINTF
AC_CHECK_FUNCS([dup2 flockfile ftruncate getcwd inet_ntoa localtime_r memmove memset mkdir munmap pathconf select socket strchr strerror strpbrk uname])

dnl Check for expat XML parser library

AC_CHECK_HEADER(expat.h,have_expat_h=yes,have_expat_h=no)
AC_CHECK_LIB(expat, XML_ParserCreate,have_expat_lib=yes,have_expat_lib=no)

AH_TEMPLATE([HAVE_LIBEXPAT], [Define if the expat XML parser library is available])

if test "x$have_expat_h" = xyes && test "x$have_expat_lib" = xyes; then
AC_DEFINE(HAVE_LIBEXPAT)
else
cat <<EOF

*******************************************************************
You do not have the expat library, so the XML functions will not be
compiled.
You may obtain this library at:
http://www.jclark.com/xml/expat.html
*******************************************************************
 
EOF
fi

dnl AC_CONFIG_FILES([])
AC_OUTPUT([Makefile lib/Makefile doc/Makefile])