make.bat

gsm modem 发送短信 闪信 WAP PUSH开发包

@echo off
echo.
echo jSMSEngine API Library.
echo Copyright (C) 2002-2006, Thanasis Delenikas, Athens / GREECE.
echo Visit http://www.jsmsengine.org for latest information.

if "%1" == "build" goto build
if "%1" == "clean" goto clean
if "%1" == "distro" goto distro
if "%1" == "" goto help
goto help

:help
echo.
echo Build utility.
echo   Usage: make {build - clean - distro}
echo     make build: Builds jSMSEngine API, examples, jSMSServer, javadoc.
echo     make clean: Removes all temporary files, jars, class, etc.
echo     make distro [rxtx - sun]: Creates the distribution directory.
goto end

:build
echo.
echo Building jSMSEngine API Library, please wait...
if not exist docs mkdir docs
javac -deprecation org\jsmsengine\*.java
jar c0fm jSMSEngine.jar org\jSMSEngine\jSMSEngine.mf org\jsmsengine\*.class
javac -deprecation examples\*.java
copy jSMSEngine.jar "C:\Program Files\Java\jdk1.5.0_06\jre\lib\ext"
copy jSMSEngine.jar "C:\Program Files\Java\jre1.5.0_06\lib\ext"
javadoc -private -d docs -windowtitle "jSMSEngine API" -doctitle "jSMSEngine API v2.0.9" -footer "<strong>jSMSEngine API v2.0.9</strong><br><strong>Web:</strong><a href="http://www.jsmsengine.org">http://www.jsmsengine.org</a></strong>" -overview extradocs\overview.html org\jsmsengine\*.java
echo.
echo Building jSMSServer application, please wait...
cd jSMSServer
javac -classpath ..\jSMSEngine.jar;.\ *.java
jar -c0fm jSMSServer.jar jSMSServer.mf *.class
cd ..
goto end

:distro
mkdir distro
mkdir distro\CommLib
if "%2" == "rxtx" goto distro_rxtx
if "%2" == "sun" goto distro_sun
goto distro2
:distro_rxtx:
copy ..\releases\rxtx-2.1-7-bins.zip distro\CommLib
goto distro2
:distro_sun
copy ..\releases\javacomm20-win32.zip distro\CommLib
:distro2
xcopy docs distro\docs /s/e/i
xcopy org distro\org /s/e/i
xcopy examples distro\examples /s/e/i
xcopy jSMSServer distro\jSMSServer /s/e/i
xcopy misc distro\misc /s/e/i
xcopy extradocs distro\extradocs /s/e/i
copy jSMSEngine.jar distro
copy LICENSE.txt distro
copy make.bat distro
del distro\*.class /s > nul 2>&1
del distro\*.$ /s > nul 2>&1
cd distro
zip -r jSMSEngine *
cd ..
goto end

:clean
echo Cleaning temporary files...
del *.jar /s> nul 2>&1
del *.bak /s> nul 2>&1
del *.class /s > nul 2>&1
del *.*~ /s > nul 2>&1
if exist docs rmdir docs /s/q > nul
if exist distro rmdir distro /s/q > nul
del jSMSServer\xml.in\*.xml > nul  2>&1
del jSMSServer\xml.out\*.xml > nul  2>&1
del jSMSServer\misc\*.raw > nul  2>&1
goto end

:end
echo.
echo ***** Done.