8-1.frm

vb6.0编程实例详解,很详细的介绍,对学习VB有帮助

VERSION 5.00
Begin VB.Form Form1 
   Caption         =   "橡皮筋功能演示"
   ClientHeight    =   4455
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   6225
   LinkTopic       =   "Form1"
   ScaleHeight     =   4455
   ScaleWidth      =   6225
   StartUpPosition =   3  '窗口缺省
   Begin VB.PictureBox Picture1 
      AutoRedraw      =   -1  'True
      BackColor       =   &H80000005&
      Height          =   975
      Left            =   720
      ScaleHeight     =   915
      ScaleWidth      =   1755
      TabIndex        =   0
      Top             =   720
      Width           =   1815
   End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Dim OldX As Long, OldY As Long
Dim X0 As Long, Y0 As Long


Private Sub Form_Resize()
    '调整Picture1控件位置与大小
    Picture1.Left = Me.ScaleLeft
    Picture1.Top = Form1.ScaleTop
    Picture1.Width = ScaleWidth
    Picture1.Height = ScaleHeight
End Sub

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 1 Then
    '用户按左键
        Screen.MousePointer = 2 '设置光标为十字
        X0 = X '保存光标位置
        Y0 = Y
        OldX = X '设置中间点位置
        OldY = Y
        Picture1.DrawMode = 7
        Picture1.ForeColor = vbWhite
        Picture1.Line (X0, Y0)-(OldX, OldY) '绘制初始异或线
    End If
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 1 Then
    '用户按左键
    '说明已经开始异或绘图，必须更新原图
        Picture1.Line (X0, Y0)-(OldX, OldY) '删除原异或线
        OldX = X '更新坐标点位置
        OldY = Y
        Picture1.Line (X0, Y0)-(OldX, OldY) '重新绘制异或线
    End If
End Sub

Private Sub Picture1_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 1 Then
    '用户按左键
        Screen.MousePointer = 0 '恢复鼠标指针
        Picture1.Line (X0, Y0)-(OldX, OldY) '删除最后的异或线
        Picture1.DrawMode = 13
        Picture1.ForeColor = vbBlack
        Picture1.Line (X0, Y0)-(X, Y) '绘制实际直线
    End If
End Sub