jd_pic.asp

微型论坛完整版

<%
dim UploadDir
dim conn,db,webname,sty
strFileName="jd_pic.asp"
%>
<!--#include file="CONN.ASP"-->
<%
call connopen(db)
set rs=conn.execute("select jd_webname,jd_imgpath,jd_uppath from admin",0,1)
	    if not rs.eof then
		webname=rs(0)
		sty=rs(1)
		UploadDir =rs(2) 
		end if
	rs.close
	conn.close
	set rs=nothing
	set conn=nothing
if Session("Admin"&webname)="" then 
response.Write("连接超时")
Response.end
end if
if right(UploadDir,1)="/" or right(UploadDir,1)="\" then UploadDir=left(UploadDir,len(UploadDir)-1)

response.Write("<link href="""&sty&"jd100.css"" rel=""stylesheet"" type=""text/css"">")
%>

<SCRIPT language=JavaScript>
<!--
function JM_cc(ob){
var obj=MM_findObj(ob); if (obj) { 
obj.select();js=obj.createTextRange();js.execCommand("Copy");}
}

function MM_findObj(n, d) { //v4.0
  var p,i,x;  if(!d) d=document; if((p=n.indexOf("?"))>0&&parent.frames.length) {
    d=parent.frames[n.substring(p+1)].document; n=n.substring(0,p);}
  if(!(x=d[n])&&d.all) x=d.all[n]; for (i=0;!x&&i<d.forms.length;i++) x=d.forms[i][n];
  for(i=0;!x&&d.layers&&i<d.layers.length;i++) x=MM_findObj(n,d.layers[i].document);
  if(!x && document.getElementById) x=document.getElementById(n); return x;
}
function CheckAll(form){
for (var i=0;i<form.elements.length;i++)
{var e = form.elements[i];
if (e.name != 'chkall')
e.checked = form.chkall.checked;
}
}

//-->
</SCRIPT>

<%
sub connopen(DBName)
    On Error Resume Next
    set conn=Server.CreateObject("ADODB.Connection")
dim DBHost,DBstr
if instr(DBName,",")>0 then DBHost="sql"
Select Case (DBHost) 
	Case "sql"
	DBstr=split(DBName,",")
    conn.Open "provider=sqloledb;uid=" & DBstr(2) & ";pwd=" & DBstr(3) & ";server=" & DBstr(1) & ";database="& DBstr(0)
	Case Else
    conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & DBName
End Select

    If Err Then
           err.Clear
           Set conn = Nothing
           Response.Write "数据库连接出错，请检查连接字串。"
           Response.End
     End If
end sub

if request("page")<>"" then
    currentPage=cint(request("page"))
else
	currentPage=1
end if
MaxPerPage=PageCount
maxperpage=25

TruePath=Server.MapPath(UploadDir)
If not IsObjInstalled("Scripting.FileSystemObject") Then
	Response.Write "<b><font color=red>你的服务器不支持 FSO(Scripting.FileSystemObject)! 不能使用本功能</font></b>"
Else
	set fso=CreateObject("Scripting.FileSystemObject")
	if request("Action")="Del" then
		call DelFiles()
	end if
	
  if fso.FolderExists(TruePath)then
	FileCount=0
	TotleSize=0
	Set theFolder=fso.GetFolder(TruePath)
	For Each theFile In theFolder.Files
		FileCount=FileCount+1
		TotleSize=TotleSize+theFile.Size
	next
    totalPut=FileCount
	if currentpage<1 then
   		currentpage=1
   	end if
   	if (currentpage-1)*MaxPerPage>totalput then
		if (totalPut mod MaxPerPage)=0 then
	  		currentpage= totalPut \ MaxPerPage
	  	else
	      	currentpage= totalPut \ MaxPerPage + 1
		end if

    end if
	if currentPage=1 then
		showContent     	
		showpage2 strFileName,totalput,MaxPerPage
		response.write "<br><div align='center'>本页共显示 <b>" & FileCount & "</b> 个文件，占用 <b>" & TotleSize\1024 & "</b> K</div>"
   	else
   	   	if (currentPage-1)*MaxPerPage<totalPut then
			showContent     	
			showpage2 strFileName,totalput,MaxPerPage
			response.write "<br><div align='center'>本页共显示 <b>" & FileCount & "</b> 个文件，占用 <b>" & TotleSize\1024 & "</b> K</div>"
       	else
        	currentPage=1
			showContent     	
			showpage2 strFileName,totalput,MaxPerPage
			response.write "<br><div align='center'>本页共显示 <b>" & FileCount & "</b> 个文件，占用 <b>" & TotleSize\1024 & "</b> K</div>"
    	end if
	end if
  else
	response.write "找不到文件夹！可能是配置有误！"
  end if
end if

sub showContent()
   	dim c
	FileCount=0
	TotleSize=0
%>
<form action="" name="form1" method="post">
<table width="95%" border="1" cellspacing="0" cellpadding="3" align="center" bordercolorlight="#ECEEE4" bordercolordark="#CCCABC" class=jd_tab style=border-collapse:collapse>
 
    <tr> 
      <td colspan="7" align="center" height="30" class=jd_titlemu><b>上 
        传 图 片 管 理</b> </td>
    </tr>
    <tr align="center" valign="middle"  class=jd_tab> 
      <td height="25">选中 <br> </td>
      <td height="25">文件名/复制地址</td>
      <td height="25">文件大小</td>
      <td height="25">预览</td>
      <td height="25">最后修改时间</td>
      <td height="25">操作</td>
    </tr>
	<%

For Each theFile In theFolder.Files
	c=c+1
	if FileCount>=MaxPerPage then
		exit for
	elseif c>MaxPerPage*(CurrentPage-1) then
%><input name="<%=theFile.Name%>" type="hidden" id="<%=theFile.Name%>" value="<%=UploadDir & "/" &theFile.Name%>">
    <tr align="center" valign="middle">
      <td height="25"><input name="FileName" type="checkbox" id="FileName" value="<%=theFile.Name%>"></td>
      <td height="25"><a style="cursor:hand;background-color:#e5e5e5;" onclick=JM_cc('<%=theFile.Name%>') title="点击图片复制地址到剪贴板"><%=UploadDir%>/<%=theFile.Name%></a></td>
      <td height="25"><%=theFile.size%>字节</td>
      <td height="25"><%'=theFile.type%>
        <a href="<%=(UploadDir & "/" & theFile.Name)%>" target="_blank" ><img src="<%=(UploadDir & "/" & theFile.Name)%>" alt="点击地址在新窗口浏览" width="50" height="50" border="0"></a> 
      </td>
      <td height="25"><%=theFile.DateLastModified%></td>
      <td height="25"><a href="<%=strFileName%>?Action=Del&FileName=<%=theFile.Name%>" onclick="{if(confirm('你真的要删除此文件吗!')){this.document.form1.submit();return true;}return false;}">删除</a></td>
    </tr>
	<%
		FileCount=FileCount+1
		TotleSize=TotleSize+theFile.Size
	end if
Next
%>
  
</table>
<table width="95%" border="0" cellpadding="0" cellspacing="0" align="center">
  <tr>
    <td width="200" height="30"><input name="chkall" type="checkbox" id="chkall" onClick="javascript:CheckAll(this.form)" value="checkbox">
      选中本页显示的所有文件</td>
    <td><input name="Action" type="hidden" id="Action" value="Del">
              <input type="submit" name="Submit" value="删除选中的文件"></td>
  </tr>
</table>
</form>
<%
end sub
sub showpage2(sfilename,totalnumber,maxperpage)
	dim n, i,strTemp
	if totalnumber mod maxperpage=0 then
    	n= totalnumber \ maxperpage
  	else
    	n= totalnumber \ maxperpage+1
  	end if
  	strTemp= "<table align='center'><form name='showpages' method='Post' action='" & sfilename & "'><tr><td>"
	strTemp=strTemp & "共 <b>" & totalnumber & "</b> 个文件，占用 <b>" & TotleSize\1024 & "</b> K&nbsp;&nbsp;&nbsp;"
	'sfilename=jd.JoinChar(sfilename)
  	if CurrentPage<2 then
    		strTemp=strTemp & "首页 上一页&nbsp;"
  	else
    		strTemp=strTemp & "<a href='" & sfilename & "?page=1'>首页</a>&nbsp;"
    		strTemp=strTemp & "<a href='" & sfilename & "?page=" & (CurrentPage-1) & "'>上一页</a>&nbsp;"
  	end if

  	if n-currentpage<1 then
    		strTemp=strTemp & "下一页 尾页"
  	else
    		strTemp=strTemp & "<a href='" & sfilename & "?page=" & (CurrentPage+1) & "'>下一页</a>&nbsp;"
    		strTemp=strTemp & "<a href='" & sfilename & "?page=" & n & "'>尾页</a>"
  	end if
   	strTemp=strTemp & "&nbsp;页次：<strong><font color=red>" & CurrentPage & "</font>/" & n & "</strong>页 "
    strTemp=strTemp & "&nbsp;<b>" & maxperpage & "</b>" & "个文件/页"
	strTemp=strTemp & "&nbsp;转到：<select name='page' size='1' onchange='javascript:submit()'>"   
    for i = 1 to n   
   		strTemp=strTemp & "<option value='" & i & "'"
		if cint(CurrentPage)=cint(i) then strTemp=strTemp & " selected "
		strTemp=strTemp & ">第" & i & "页</option>"   
	next
	strTemp=strTemp & "</select>"
	strTemp=strTemp & "</td></tr></form></table>"
	response.write strTemp
end sub

sub DelFiles()
	dim whichfile,arrFileName,i
	whichfile=trim(Request("FileName"))
	if whichfile="" then exit sub
	if instr(whichfile,",")>0 then
		arrFileName=split(whichfile,",")
		for i=0 to ubound(arrFileName)
			if left(trim(arrFileName(i)),3)<>"../" and left(trim(arrFileName(i)),1)<>"/" then
				whichfile=server.MapPath(UploadDir & "/" & trim(arrFileName(i)))
				set thisfile=fso.GetFile(whichfile)
				thisfile.Delete True
			end if
		next
	else
		if left(whichfile,3)<>"../" and left(whichfile,1)<>"/" then
			Set thisfile = fso.GetFile(server.MapPath(UploadDir & "/" & whichfile))
			thisfile.Delete True
		end if
	end if
	Response.Write("<script>alert(""删除成功"");location.href="""&strFileName&""";</script>")
end sub
Public Function IsObjInstalled(strClassString)
	On Error Resume Next
	IsObjInstalled = False
	Err = 0
	Dim xTestObj
	Set xTestObj = Server.CreateObject(strClassString)
	If 0 = Err Then IsObjInstalled = True
	Set xTestObj = Nothing
	Err = 0
End Function

%>