rfc2234.txt

很多RFC的中文文档

3*3<element>只允许3而1*2<element>允许1或2。

3.7  指定循环												nRule
如下形式的规则：
        <n>element
等同于
        <n>*<n>element
即，<element>正好出现<N>次。因而2DIGIT是一个2位数，而3ALPHA是一个3字
母字符串。

3.8  可选序列												[RULE]
方括弧包括了一个可选元素序列：
        [foo bar]
等同于
        *1(foo bar).

3.9  ；注释
分号起始一行注释直到行末。这是一个简单的方法，用于在说明中平行地包括有用的注
解。

3.10操作符优先级
上述各种机制具有以下优先级关系，从上到下，优先级依次从高（结合最紧密）到低（结
合最松散）：
		字符串，名字格式
		注释
		值域
		循环
		分组，可选项
		连接
		选择
随意混用选择操作符与连接操作符，会引起混淆。
再次提醒，推荐使用分组操作符显式表明连接分组。

4.   扩展巴克斯范式形式的扩展巴克斯范式定义
本语法使用附录A（核心）中提供的规则
        rulelist       =  1*( rule / (*c-wsp c-nl) )
        rule           =  rulename defined-as elements c-nl
；若下一行以空白字符开头则继续
        rulename       =  ALPHA *(ALPHA / DIGIT / "-")
        defined-as     =  *c-wsp ("=" / "=/") *c-wsp
；基本规则定义以及增式选择
        elements       =  alternation *c-wsp
        c-wsp          =  WSP / (c-nl WSP)
        c-nl           =  comment / CRLF
；注释或新的一行
        comment        =  ";" *(WSP / VCHAR) CRLF
        alternation    =  concatenation
                          *(*c-wsp "/" *c-wsp concatenation)
        concatenation  =  repetition *(1*c-wsp repetition)
        repetition     =  [repeat] element
        repeat         =  1*DIGIT / (*DIGIT "*" *DIGIT)
        element        =  rulename / group / option /
                          char-val / num-val / prose-val
        group          =  "(" *c-wsp alternation *c-wsp ")"
        option         =  "[" *c-wsp alternation *c-wsp "]"
        char-val       =  DQUOTE *(%x20-21 / %x23-7E) DQUOTE
；SP和VCHAR的引用串，不使用DQUOTE
        num-val        =  "%" (bin-val / dec-val / hex-val)
        bin-val        =  "b" 1*BIT
                          [ 1*("." 1*BIT) / ("-" 1*BIT) ]
；一系列的连续位值或单个ONEOF域
        dec-val        =  "d" 1*DIGIT
                          [ 1*("." 1*DIGIT) / ("-" 1*DIGIT) ]
        hex-val        =  "x" 1*HEXDIG
                          [ 1*("." 1*HEXDIG) / ("-" 1*HEXDIG) ]
        prose-val      =  "<" *(%x20-3D / %x3F-7E) ">"
；括起来的SP和VCHAR字符串，不含尖括号
；行文描述，作为最后的方法来使用

5.   安全考虑
本文档确信与安全无关。

6.   附录A-核心
本附录给出一个特定语法的便捷核心。附录中的定义可作为规则的核心集使用。

6.1  核心规则
某些基本规则使用大写，如SP, HTAB, CRLF, DIGIT, ALPHA,等等。
        ALPHA          =  %x41-5A / %x61-7A   ; A-Z / a-z
        BIT            =  "0" / "1"
        CHAR           =  %x01-7F
；除NUL以外的任何7位US-ASCII字符
        CR             =  %x0D
；回车
        CRLF           =  CR LF
；互联网标准格式的换行
        CTL            =  %x00-1F / %x7F
；控制字符
        DIGIT          =  %x30-39
；0-9
        DQUOTE         =  %x22
；"（双引号）
        HEXDIG         =  DIGIT / "A" / "B" / "C" / "D" / "E" / "F"
        HTAB           =  %x09
；水平制表符
        LF             =  %x0A
；换行
        LWSP           =  *(WSP / CRLF WSP)
；线性空白字符（过去的换行）
        OCTET          =  %x00-FF
；8位数据
        SP             =  %x20
；空格符
        VCHAR          =  %x21-7E
；可见（可打印）字符
        WSP            =  SP / HTAB
；空白字符

6.2  公共编码
形式上，数据被描述成“网络虚ASCII”，即有8位域的7位US-ASCII编码，其中最高
位（第8位）置0。值串按“网络字节顺序”排列，高位字节在左边并且在网络中首先发送。

7.   致谢
扩展巴克斯范式的语法最初在RFC 733中说明。SRT International的Ken L. Harrenstien
负责将巴克斯范式重新编码成扩展巴克斯范式，这样使得描述更简短且更容易理解。
该新近项目始于一项简单的工作，希望从RFC 822中精选出反复被非电子邮件规范作
者引用的部分，即，扩展巴科斯范式的描述。工作组并非简单盲目地将已存在的文本转变成
单独的文档，而是经过15年对已有规范及相关规范优缺点的仔细考虑，以求进一步提高。
这使项目变得比最初的想法艰巨得多。有趣的是，尽管作出诸如删除列表符这样的让人意外
的决定，结果并非与原作非常的不同。
最近一轮的规范由DRUMS工作组完成，感谢Jerome Abela , Harald Alvestrand, Robert 
Elz, Roger Fajman, Aviva Garrett, Tom Harsch, Dan Kohn, Bill McQuillan, Keith Moore, 
Chris Newman , Pete Resnick和Henning Schulzrinne的杰出贡献。

8.   参考

   [US-ASCII]     Coded Character Set--7-Bit American Standard Code for
   Information Interchange, ANSI X3.4-1986.

   [RFC733]  Crocker, D., Vittal, J., Pogran, K., and D. Henderson,
   "Standard for the Format of ARPA Network Text Message," RFC 733,
   November 1977.

   [RFC822]  Crocker, D., "Standard for the Format of ARPA Internet Text
   Messages", STD 11, RFC 822, August 1982.

9.   作者地址
   David H. Crocker                 Paul Overell

   Internet Mail Consortium         Demon Internet Ltd
   675 Spruce Dr.                   Dorking Business Park
   Sunnyvale, CA 94086 USA          Dorking
                                    Surrey, RH4 1HN
                                    UK

   Phone:    [phone]
   Fax:      [phone]
   EMail:    [e-mail]       [e-mail]

10.  完整版权声明
   Copyright (C) The Internet Society (1997).  All Rights Reserved.

   This document and translations of it may be copied and furnished to
   others, and derivative works that comment on or otherwise explain it
   or assist in its implementation may be prepared, copied, published
   and distributed, in whole or in part, without restriction of any
   kind, provided that the above copyright notice and this paragraph are
   included on all such copies and derivative works.  However, this
   document itself may not be modified in any way, such as by removing
   the copyright notice or references to the Internet Society or other
   Internet organizations, except as needed for the purpose of
   developing Internet standards in which case the procedures for
   copyrights defined in the Internet Standards process must be
   followed, or as required to translate it into languages other than
   English.

   The limited permissions granted above are perpetual and will not be
   revoked by the Internet Society or its successors or assigns.

   This document and the information contained herein is provided on an
   "AS IS" basis and THE INTERNET SOCIETY AND THE INTERNET 
ENGINEERING
   TASK FORCE DISCLAIMS ALL WARRANTIES, EXPRESS OR IMPLIED, 
INCLUDING
   BUT NOT LIMITED TO ANY WARRANTY THAT THE USE OF THE 
INFORMATION
   HEREIN WILL NOT INFRINGE ANY RIGHTS OR ANY IMPLIED WARRANTIES 
OF
   MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.

RFC2234——Augmented BNF for Syntax Specifications: ABNF          语法规范的扩展巴科斯范式：ABNF


1
RFC文档中文翻译计划