ordergenerator.vb

Visual Basic.NET控件时尚编程百例

Imports System.IO
Imports System.Xml

Public Class OrderGenerator

    Public Enum ShopMethod As Integer
        SpeedyExpress = 1
        UnitedPackage = 2
        FederalShipping = 3
    End Enum

    Public CustomerID As String
    '定义一个实施购物的购物方式
    Public PreferShopMethod As ShopMethod
    '购物人所在地址
    Public ShopAddress As New Address()
    '购物物品细节
    Public Details As New RequestDetailCollection()
    '回复信箱地址
    Public ReponseEmail As String

    Public Sub Save(ByVal filename As String)
        Dim info As New FileInfo(filename)
        '定义一个新的文件信息类
        If info.Exists = True Then info.Delete()
        '如果文件已经存在，则删除该文件
        Dim stream As New FileStream(filename, FileMode.Create)
        '创建一个写入流，将数据写入到指定的文件中
        WriteXML(stream)
        '开始写入数据
        stream.Close()
        '关闭写入流
    End Sub

    Public Sub WriteXML(ByVal stream As Stream)
        Dim writer As New XmlTextWriter(stream, System.Text.Encoding.Unicode)
        WriteXML(writer)
        writer.Close()
    End Sub
    Public Sub WriteXML(ByVal writer As XmlTextWriter)
        writer.WriteStartElement("Order")
        writer.WriteElementString("CustomerID", CustomerID)
        writer.WriteElementString("PreferShopMethod", PreferShopMethod)
        writer.WriteElementString("ReponseEmail", ReponseEmail)
        ShopAddress.WriteXML("ShopAddress", writer)
        Details.WriteXML(writer)
        writer.WriteEndElement()
    End Sub

    Public Sub ReadXML(ByVal reader As XmlTextReader)
        Do While reader.Read
            Select Case reader.NodeType
                Case XmlNodeType.Element
                    Select Case reader.Name
                        Case "CustomerID"
                            reader.Read()
                            Me.CustomerID = reader.Value
                        Case "PreferShopMethod"
                            reader.Read()
                            Me.PreferShopMethod = reader.Value
                        Case "ReponseEmail"
                            reader.Read()
                            Me.ReponseEmail = reader.Value
                        Case "ShopAddress"
                            Me.ShopAddress.ReadXML(reader, reader.Name)
                        Case "Details"
                            Me.Details.ReadXML(reader)
                    End Select
            End Select
        Loop
    End Sub
End Class