requestdetailcollection.vb

Visual Basic.NET控件时尚编程百例

Imports System.IO
Imports System.Xml

Public Class RequestDetailCollection
    Inherits CollectionBase

    Public Sub Add(ByVal detail As Requestdetail)
        list.Add(detail)
    End Sub

    Public Function Add(ByVal ProductID As Integer, _
    ByVal quantity As Integer) As Requestdetail
        Dim detail As New Requestdetail()
        detail.ProductID = ProductID
        detail.Quantity = quantity
        Add(detail)
        Return detail
    End Function

    Public Sub Remove(ByVal detail As Requestdetail)
        list.Remove(detail)
    End Sub

    Default Public Property Item(ByVal index As Integer) _
    As Requestdetail
        Get
            Return list.Item(index)
        End Get
        Set(ByVal Value As Requestdetail)
            list.Item(index) = Value
        End Set
    End Property

    Public Sub WriteXML(ByVal writer As XmlTextWriter)
        writer.WriteStartElement("Details")
        Dim detail As Requestdetail
        For Each detail In innerlist
            detail.WriteXML(writer)
        Next
        writer.WriteEndElement()
    End Sub

    Public Sub ReadXML(ByVal reader As XmlTextReader)
        Do While reader.Read
            Select Case reader.NodeType
                Case XmlNodeType.Element
                    If reader.Name = "Detail" Then
                        Dim detail As New Requestdetail()
                        detail.ReadXML(reader)
                        Add(detail)
                    End If
                Case XmlNodeType.EndElement
                    If reader.Name = "Details" Then
                        Return
                    End If
            End Select
        Loop
    End Sub

End Class