applycolorbar_rgb_object.pro

IDL开发源码

PRO Applycolorbar_RGB_object
; 确定文件 "glowing_gas.jpg" 的路径。
cosmicFile =FILEPATH('glowing_gas.jpg ',$
SUBDIRECTORY=['examples', 'data'])
; 从文件中向 IDL 输入图象。
READ_JPEG,cosmicFile,cosmicImage
; 确定图象大小。
cosmicsize=SIZE (cosmicImage ,/DIMENSIONS )
;初始化对象。
;初始化显示。
owindow=OBJ_NEW('IDLgrwindow',RETAIN=2,$
DIMENSIONS=[cosmicsize[1],cosmicsize[2]],$
TITLE ='glowing_gas.jpg')
oview=OBJ_NEW('IDLgrview',$
VIEWPLANE_RECT=[0.,0.,cosmicsize[1],cosmicsize[2]])
oModel=OBJ_NEW('IDLgrModel')
; 初始化图象。

oImage=OBJ_NEW('IDLgrImage',cosmicImage,$
INTERLEAVE =0,DIMENSIONS=[cosmicsize[1],cosmicsize[2]])
;添加图象至模型 , 添加模型至视窗 ,
; 在窗口中显示视窗。
oModel -> Add ,oImage
oview -> Add ,oModel
owindow -> Draw ,oview

; 初始化颜色参数。
fillcolor=[[0,0,0],$; 黑
[255,0,0],$; 红
[255,255,0],$; 黄
[0,255,0],$; 绿
[0,255,255],$; 青色
[0,0,255],$; 蓝
[255,0,255],$; 紫色
[255,255,255]]; 白
; 初始化多边形位置参数。
X=[5.,25.,25.,5.,5.]
Y=[5.,5.,25.,25.,5.]+5.
offset =20.* FINDGEN(9)+5.
; 初始化颜色条的临界位置。
X_border =[x[0]+offset[0],x[1]+ offset [7],$
 x[2]+offset[7],x[3]+ offset[0],x[4]+offset[0]]
; 初始化多边形对象。
opolygon=OBJARR(8)
FOR i=0,(N_ELEMENTS(opolygon)-1) DO opolygon[i]=$
OBJ_NEW('IDLgrPolygon',X+ offset[i],y,$
COLOR =fillcolor[*,i ])
; 初始化折线 ( 边界 ) 对象。
z=[0.001,0.001,0.001,0.001,0.001]
opolyline=OBJ_NEW('IDLgrpolyline',x_border ,y,z ,$
COLOR =[255,255,255])
;添加多边表和折线至模型并在窗口中重新显示视窗。
OModel -> Add ,opolygon
oModel -> Add ,opolyline
owindow -> Draw ,oview
;清除对象参数
OBJ_DESTROY,[oView]
END