main.pas

ODAC 5.7.0.28

unit Main;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, OdacClx,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, ExtDlgs, OdacVcl,
{$ENDIF}
  Db, Ora, OraScript, MemDS, DBAccess, OraSmart;

type
  TfmMain = class(TForm)
    OraSession: TOraSession;
    Query: TSmartQuery;
    OraDataSource1: TOraDataSource;
    scCreate: TOraScript;
    scDrop: TOraScript;
    DBGrid1: TDBGrid;
    DBImage: TDBImage;
    ToolBar: TPanel;
    btOpen: TButton;
    btClose: TButton;
    DBNavigator: TDBNavigator;
    btCreate: TButton;
    btDrop: TButton;
    Splitter1: TSplitter;
    ToolBar1: TToolBar;
    btLoad: TButton;
    btSave: TButton;
    btClear: TButton;
    OraStoredProc: TOraStoredProc;
    btAddRecord: TButton;
    ToolButton2: TToolButton;
    cbUseNet: TCheckBox;
    ToolButton1: TToolButton;
    cbDefLobRead: TCheckBox;
    ToolButton3: TToolButton;
    cbCacheLobs: TCheckBox;
    cbDebug: TCheckBox;
    procedure btCreateClick(Sender: TObject);
    procedure btDropClick(Sender: TObject);
    procedure btLoadClick(Sender: TObject);
    procedure btSaveClick(Sender: TObject);
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure btClearClick(Sender: TObject);
    procedure btAddRecordClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure cbUseNetClick(Sender: TObject);
    procedure cbDefLobReadClick(Sender: TObject);
    procedure cbCacheLobsClick(Sender: TObject);
    procedure scCreateError(Sender: TObject; E: Exception; SQL: String;
      var Action: TErrorAction);
    procedure cbDebugClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  fmMain: TfmMain;

implementation

{$R *.nfm}

procedure TfmMain.btCreateClick(Sender: TObject);
begin
  scCreate.Execute;
end;

procedure TfmMain.btDropClick(Sender: TObject);
begin
  scDrop.Execute;
end;

procedure TfmMain.btOpenClick(Sender: TObject);
begin
  Query.Open;
end;

procedure TfmMain.btCloseClick(Sender: TObject);
begin
  Query.Close;
end;

procedure TfmMain.btLoadClick(Sender: TObject);
begin
{$IFDEF LINUX}
  with TOpenDialog.Create(nil) do
{$ELSE}
  with TOpenPictureDialog.Create(nil) do
{$ENDIF}
    try
      InitialDir := '.';
      if Query.Active and Execute then begin
        if Query.State = dsBrowse then
          Query.Edit;

        TBlobField(Query.FieldByName('Pic')).LoadFromFile(FileName);
      end;
    finally
      Free;
    end;
end;

procedure TfmMain.btSaveClick(Sender: TObject);
begin
{$IFDEF LINUX}
  with TSaveDialog.Create(nil) do
{$ELSE}
  with TSavePictureDialog.Create(nil) do
{$ENDIF}
    try
      InitialDir := '.';    
      if not Query.EOF and Execute then
        TBlobField(Query.FieldByName('Pic')).SaveToFile(FileName);
    finally
      Free;
    end;
end;

procedure TfmMain.btClearClick(Sender: TObject);
begin
  if Query.State = dsBrowse then
    Query.Edit;

  TBlobField(Query.FieldByName('Pic')).Clear;
end;

procedure TfmMain.btAddRecordClick(Sender: TObject);
begin
{$IFDEF LINUX}
  with TOpenDialog.Create(nil) do
{$ELSE}
  with TOpenPictureDialog.Create(nil) do
{$ENDIF}
    try
      InitialDir := '.';    
      if Execute then begin
        with OraStoredProc do begin
          StoredProcName := 'ODAC_BLOB_Insert';
          PrepareSQL;  // receive parameters

          Randomize;
          ParamByName('p_ID').AsInteger := Random(1000);
          ParamByName('p_Title').AsString := ExtractFileName(FileName);

          ParamByName('p_Pic').ParamType := ptInput;  // to transfer Lob data to Oracle
          ParamByName('p_Pic').AsOraBlob.LoadFromFile(FileName);
          Execute;
        end;
        Query.Refresh;
      end;
    finally
      Free;
    end;
end;

procedure TfmMain.FormShow(Sender: TObject);
begin
  cbUseNet.Checked := OraSession.Options.Net;
  cbDefLobRead.Checked := Query.OptionsDS.DeferredLobRead;
  cbCacheLobs.Checked := Query.OptionsDS.CacheLobs;
  cbDebug.Checked := Query.Debug;
end;

procedure TfmMain.cbUseNetClick(Sender: TObject);
begin
  OraSession.Options.Net := cbUseNet.Checked;
end;

procedure TfmMain.cbDefLobReadClick(Sender: TObject);
begin
  Query.OptionsDS.DeferredLobRead := cbDefLobRead.Checked;
end;

procedure TfmMain.cbCacheLobsClick(Sender: TObject);
begin
  Query.OptionsDS.CacheLobs := cbCacheLobs.Checked;
end;

procedure TfmMain.scCreateError(Sender: TObject; E: Exception; SQL: String;
  var Action: TErrorAction);
begin
//
end;

procedure TfmMain.cbDebugClick(Sender: TObject);
begin
  Query.Debug := cbDebug.Checked;
  OraStoredProc.Debug := cbDebug.Checked;
  scCreate.Debug := cbDebug.Checked;
  scDrop.Debug := cbDebug.Checked;
end;

end.