main.pas

ODAC 5.7.0.28

unit Main;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, OdacClx,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, OdacVcl,
{$ENDIF}
  Db, Ora, DBAccess, OraScript, MemDS, OraSmart;

type
  TfmMain = class(TForm)
    ToolBar1: TPanel;
    btOpen: TButton;
    btClose: TButton;
    DBNavigator1: TDBNavigator;
    btCreate: TButton;
    btDrop: TButton;
    DBGrid: TDBGrid;
    dsData: TDataSource;
    Query: TSmartQuery;
    OraSession: TOraSession;
    ConnectDialog1: TConnectDialog;
    scCreate: TOraScript;
    scDrop: TOraScript;
    Panel: TPanel;
    cbObjectView: TCheckBox;
    cbDebug: TCheckBox;
    btShowCountry: TButton;
    btAddRecord: TButton;
    OraSQL: TOraSQL;
    btCloneObject: TButton;
    spGetName: TOraStoredProc;
    btCallMethod: TButton;
    procedure btCreateClick(Sender: TObject);
    procedure btDropClick(Sender: TObject);
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure cbObjectViewClick(Sender: TObject);
    procedure cbDebugClick(Sender: TObject);
    procedure btShowCountryClick(Sender: TObject);
    procedure btAddRecordClick(Sender: TObject);
    procedure btCloneObjectClick(Sender: TObject);
    procedure btCallMethodClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  fmMain: TfmMain;

implementation
uses
  OraCall, OraClasses, OraObjects;

{$R *.nfm}

procedure TfmMain.btCreateClick(Sender: TObject);
begin
  scCreate.Execute;
end;

procedure TfmMain.btDropClick(Sender: TObject);
begin
  scDrop.Execute;
end;

procedure TfmMain.btOpenClick(Sender: TObject);
begin
  dsData.DataSet.Open;
end;

procedure TfmMain.btCloseClick(Sender: TObject);
begin
  dsData.DataSet.Close;
end;

procedure TfmMain.FormShow(Sender: TObject);
begin
  cbObjectView.Checked := dsData.DataSet.ObjectView;
  cbDebug.Checked := Query.Debug;
end;

procedure TfmMain.cbObjectViewClick(Sender: TObject);
begin
  if not dsData.DataSet.Active then
    dsData.DataSet.ObjectView := cbObjectView.Checked
  else
    cbObjectView.Checked := dsData.DataSet.ObjectView;
end;

procedure TfmMain.cbDebugClick(Sender: TObject);
begin
  Query.Debug := cbDebug.Checked;
  OraSQL.Debug := cbDebug.Checked;
  spGetName.Debug := cbDebug.Checked;
  scCreate.Debug := cbDebug.Checked;
  scDrop.Debug := cbDebug.Checked;
end;

procedure TfmMain.btShowCountryClick(Sender: TObject);
var
  Value: string;
begin
  if Query.ObjectView then
    Value := TADTField(TADTField(
      Query.FieldByName('PERSON')).
      Fields.FieldByName('ADDRESS')).
      Fields.FieldByName('COUNTRY').AsString
  else
    Value := Query.FieldByName('PERSON.ADDRESS.COUNTRY').AsString;

  Value := Query.GetObject('PERSON').AttrAsString['ADDRESS.COUNTRY'];

  Application.MessageBox(PChar(Value), 'Country'{$IFDEF MSWINDOWS}, MB_OK{$ENDIF});
end;

procedure TfmMain.btAddRecordClick(Sender: TObject);
begin
  OraSQL.SQL.Text := 'INSERT INTO ODAC_Emp (PERSON, JOB, HIREDATE, SAL)' +
                     'VALUES (:PERSON, :JOB, : HIREDATE, :SAL)';

  with OraSQL.ParamByName('Person').AsObject do begin
    AllocObject(OraSession.OCISvcCtx, 'TPerson');
    AttrAsString['Name'] := 'JON';
    AttrAsString['Address.Country'] := 'USA';
    AttrAsString['Address.City'] := 'Boston';
    AttrAsInteger['Address.Apartment'] := 133;
    AttrAsDateTime['BirthDate'] := EncodeDate(1970, 7, 23);
  end;
  OraSQL.ParamByName('Job').AsString := 'MANAGER';
  OraSQL.ParamByName('HireDate').AsDateTime := EncodeDate(1998, 5, 14);
  OraSQL.ParamByName('Sal').AsInteger := 1700;
  OraSQL.Execute;

  Query.Refresh;
end;

procedure TfmMain.btCloneObjectClick(Sender: TObject);
var
  OraObject: TOraObject;
begin
  if not Query.IsEmpty then begin
    OraObject := Query.GetObject('Person');

    OraSQL.SQL.Text := 'INSERT INTO ODAC_Emp (PERSON)' +
                       'VALUES (:PERSON)';

    OraSQL.ParamByName('Person').AsObject := OraObject;
    OraSQL.Execute;

    Query.Refresh;
  end;
end;

procedure TfmMain.btCallMethodClick(Sender: TObject);
begin
  if not Query.IsEmpty then begin
    spGetName.ParamByName('Self').AsObject := Query.GetObject('Person');
    spGetName.Execute;
    Application.MessageBox(PChar(spGetName.ParamByName('Result').AsString), 'Country'{$IFDEF MSWINDOWS}, MB_OK{$ENDIF});
  end;
end;

end.