main.pas

ODAC 5.7.0.28

unit Main;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, OdacClx,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, OdacVcl,
{$ENDIF}
  Db, Ora, OraScript, MemDS, DBAccess, OraSmart;

type
  TfmMain = class(TForm)
    OraSession: TOraSession;
    DBGrid: TDBGrid;
    dsData: TDataSource;
    ToolBar: TPanel;
    btOpen: TButton;
    DBNavigator: TDBNavigator;
    btClose: TButton;
    ConnectDialog: TConnectDialog;
    meComments: TDBMemo;
    SmartQuery: TSmartQuery;
    btCreate: TButton;
    btDrop: TButton;
    sqCreate: TOraScript;
    sqDrop: TOraScript;
    quInsertRecord: TOraQuery;
    Panel1: TPanel;
    btCopyRecord: TButton;
    quCopyRecord: TOraQuery;
    quSelectRecord: TOraQuery;
    btCopyRecord1: TButton;
    btCopyRecord2: TButton;
    Splitter1: TSplitter;
    OraQuery: TOraQuery;
    rbSmartQuery: TRadioButton;
    rbOraQuery: TRadioButton;
    cbDebug: TCheckBox;
    ToolBar1: TPanel;
    btLoad: TButton;
    btSave: TButton;
    OpenDialog: TOpenDialog;
    SaveDialog: TSaveDialog;
    btClear: TButton;
    cbUseNet: TCheckBox;
    cbDefLobRead: TCheckBox;
    cbCacheLobs: TCheckBox;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure btCreateClick(Sender: TObject);
    procedure btDropClick(Sender: TObject);
    procedure btCopyRecordClick(Sender: TObject);
    procedure btCopyRecord1Click(Sender: TObject);
    procedure btCopyRecord2Click(Sender: TObject);
    procedure rbSmartQueryClick(Sender: TObject);
    procedure rbOraQueryClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure cbDebugClick(Sender: TObject);
    procedure btLoadClick(Sender: TObject);
    procedure btSaveClick(Sender: TObject);
    procedure btLoad1Click(Sender: TObject);
    procedure btClearClick(Sender: TObject);
    procedure cbUseNetClick(Sender: TObject);
    procedure cbDefLobReadClick(Sender: TObject);
    procedure cbCacheLobsClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  fmMain: TfmMain;

implementation

{$R *.nfm}

procedure TfmMain.btOpenClick(Sender: TObject);
begin
  dsData.DataSet.Open;
end;

procedure TfmMain.btCloseClick(Sender: TObject);
begin
  dsData.DataSet.Close;
end;

procedure TfmMain.btCreateClick(Sender: TObject);
begin
  sqCreate.Execute;
end;

procedure TfmMain.btDropClick(Sender: TObject);
begin
  sqDrop.Execute;
end;

procedure TfmMain.btCopyRecordClick(Sender: TObject);
begin
  if not dsData.DataSet.EOF then begin
    quInsertRecord.ParamByName('Code').AsInteger :=
      dsData.DataSet.FieldByName('Code').AsInteger;
    quInsertRecord.ParamByName('Title').AsString :=
      dsData.DataSet.FieldByName('Title').AsString;
    quInsertRecord.ParamByName('Value').DataType := ftOraClob;
    quInsertRecord.ParamByName('Value').AsString :=
      dsData.DataSet.FieldByName('Value').AsString;
    quInsertRecord.Execute;

    dsData.DataSet.Refresh;
  end;
end;

procedure TfmMain.btCopyRecord1Click(Sender: TObject);
begin
  if not dsData.DataSet.EOF then begin
    quSelectRecord.ParamByName('RowId').AsString :=
      dsData.DataSet.FieldByName('RowId').AsString;
    quSelectRecord.ParamByName('Value').DataType := ftOraClob;
    quSelectRecord.Execute;

    quInsertRecord.ParamByName('Code').AsInteger :=
      quSelectRecord.ParamByName('Code').AsInteger;
    quInsertRecord.ParamByName('Title').AsString :=
      quSelectRecord.ParamByName('Title').AsString;
    quInsertRecord.ParamByName('Value').DataType := ftOraClob;
    quInsertRecord.ParamByName('Value').AsString :=
      quSelectRecord.ParamByName('Value').AsString;

    quInsertRecord.Execute;

    dsData.DataSet.Refresh;
  end;
end;

procedure TfmMain.btCopyRecord2Click(Sender: TObject);
begin
  if not dsData.DataSet.EOF then begin
    quCopyRecord.ParamByName('RowId').AsString :=
      dsData.DataSet.FieldByName('RowId').AsString;
    quCopyRecord.Execute;

    dsData.DataSet.Refresh;
  end;
end;

procedure TfmMain.rbSmartQueryClick(Sender: TObject);
begin
  dsData.DataSet := SmartQuery;
end;

procedure TfmMain.rbOraQueryClick(Sender: TObject);
begin
  dsData.DataSet := OraQuery;
end;

procedure TfmMain.FormShow(Sender: TObject);
begin
  rbSmartQuery.Checked := dsData.DataSet = SmartQuery;
  rbOraQuery.Checked := dsData.DataSet = OraQuery;
  cbDebug.Checked := TOraDataSet(dsData.DataSet).Debug;
  cbUseNet.Checked := OraSession.Options.Net;
  cbDefLobRead.Checked := TOraDataSet(dsData.DataSet).OptionsDS.DeferredLobRead;
  cbCacheLobs.Checked := TOraDataSet(dsData.DataSet).OptionsDS.CacheLobs;
end;

procedure TfmMain.cbDebugClick(Sender: TObject);
begin
  SmartQuery.Debug := cbDebug.Checked;
  OraQuery.Debug := cbDebug.Checked;
  quSelectRecord.Debug := cbDebug.Checked;
  quInsertRecord.Debug := cbDebug.Checked;
  quCopyRecord.Debug := cbDebug.Checked;
  sqCreate.Debug := cbDebug.Checked;
  sqDrop.Debug := cbDebug.Checked;
end;

procedure TfmMain.btLoadClick(Sender: TObject);
begin
  if dsData.DataSet.Active and OpenDialog.Execute then begin
    if dsData.DataSet.State = dsBrowse then
      dsData.DataSet.Edit;
    TBlobField(dsData.DataSet.FieldByName('Value')).LoadFromFile(OpenDialog.FileName);
  end;
end;

procedure TfmMain.btLoad1Click(Sender: TObject);
var
  Stream: TStream;
  BlobStream: TStream;
begin
  if dsData.DataSet.Active and OpenDialog.Execute then begin
    if dsData.DataSet.State = dsBrowse then
      dsData.DataSet.Edit;

    Stream := nil;
    BlobStream := nil;
    try
      Stream := TFileStream.Create(OpenDialog.FileName, fmOpenRead);
      BlobStream := dsData.DataSet.CreateBlobStream(
        dsData.DataSet.FieldByName('Value'), bmWrite);

      BlobStream.CopyFrom(Stream, 0);
    finally
      BlobStream.Free;
      Stream.Free;
    end;
  end;
end;

procedure TfmMain.btSaveClick(Sender: TObject);
begin
  if not dsData.DataSet.EOF and SaveDialog.Execute then
    TBlobField(dsData.DataSet.FieldByName('Value')).SaveToFile(SaveDialog.FileName);
end;

procedure TfmMain.btClearClick(Sender: TObject);
begin
  if dsData.DataSet.Active then begin
    if dsData.DataSet.State = dsBrowse then
      dsData.DataSet.Edit;
    dsData.DataSet.FieldByName('Value').AsString := '';
  end;
end;

procedure TfmMain.cbUseNetClick(Sender: TObject);
begin
  OraSession.Options.Net := cbUseNet.Checked;
end;

procedure TfmMain.cbDefLobReadClick(Sender: TObject);
begin
  TOraDataSet(dsData.DataSet).OptionsDS.DeferredLobRead := cbDefLobRead.Checked;
end;

procedure TfmMain.cbCacheLobsClick(Sender: TObject);
begin
  TOraDataSet(dsData.DataSet).OptionsDS.CacheLobs := cbCacheLobs.Checked;
end;

end.