main.pas

ODAC 5.7.0.28

unit Main;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, OdacClx,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, OdacVcl,
{$ENDIF}
  Db, MemDS, DBAccess, Ora;

type
  TfmMain = class(TForm)
    OraSession: TOraSession;
    ToolBar: TPanel;
    btGet: TButton;
    ConnectDialog: TConnectDialog;
    sqGet: TOraSQL;
    Memo: TMemo;
    btPut: TButton;
    sqPut: TOraSQL;
    gdDept: TDBGrid;
    dsDept: TDataSource;
    DBNavigator: TDBNavigator;
    btClose: TButton;
    btOpen: TButton;
    quDept: TOraQuery;
    Splitter1: TSplitter;
    Memo1: TMemo;
    Panel1: TPanel;
    Label1: TLabel;
    Label2: TLabel;
    StatusBar1: TStatusBar;
    cbUseNet: TCheckBox;
    cbDebug: TCheckBox;
    procedure btGetClick(Sender: TObject);
    procedure btPutClick(Sender: TObject);
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure cbUseNetClick(Sender: TObject);
    procedure cbDebugClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  fmMain: TfmMain;

implementation
{$IFNDEF VER130}
uses
  Variants;
{$ENDIF}

{$R *.dfm}

procedure TfmMain.btGetClick(Sender: TObject);
var
  i: integer;
  RecCount: integer;
begin
  RecCount := OraSession.ExecSQL(
    'begin SELECT Count(*) INTO :Result FROM Scott.Dept; end;', [0]);

  sqGet.ArrayLength := RecCount; // set length of parameters

  for i := 1 to RecCount do begin
    sqGet.ParamByName('RowNum').ItemAsInteger[i]:= i;
  end;

  sqGet.Execute(RecCount);

  Memo.Lines.Clear;
  Memo1.Lines.Clear;
  for i := 1 to RecCount do begin
    Memo1.Lines.Add(sqGet.ParamByName('DeptNo').ItemAsString[i]);
    Memo.Lines.Add(sqGet.ParamByName('DName').ItemAsString[i]);
  end;
end;

procedure TfmMain.btPutClick(Sender: TObject);
var
  i: integer;
  DeptNoArr: variant;
  DNameArr: variant;
  RecCount: integer;
begin
  RecCount := OraSession.ExecSQL(
    'begin SELECT Count(*) INTO :Result FROM Scott.Dept; end;', [0]);

{sqPut.ArrayLength}

// Setting array parameters
//   Way 1 - DeptNo
//   Way 2 - DName
  DeptNoArr := VarArrayCreate([1, RecCount], varVariant); // explict creating array

  sqPut.ParamByName('DName').Length:= RecCount;
  DNameArr := sqPut.ParamByName('DName').Value;

  for i := 1 to RecCount do begin
    DeptNoArr[i] := Memo1.Lines[i - 1];
    DNameArr[i] := Memo.Lines[i - 1];
  // Way 3:
  // sqPut.ParamByName('DeptNo').ItemAsString[i]:= Memo1.Lines[i - 1];
  // sqPut.ParamByName('DName').ItemAsString[i]:= Memo.Lines[i - 1];

  end;
  sqPut.ParamByName('DeptNo').Value := DeptNoArr;
  sqPut.ParamByName('DName').Value := DNameArr;

  sqPut.Execute(RecCount);

  if quDept.Active then
    quDept.Refresh
  else
    quDept.Open;
end;

procedure TfmMain.btOpenClick(Sender: TObject);
begin
  quDept.Open;
end;

procedure TfmMain.btCloseClick(Sender: TObject);
begin
  quDept.Close;
end;

procedure TfmMain.FormShow(Sender: TObject);
begin
  cbUseNet.Checked := OraSession.Options.Net;
  cbDebug.Checked := quDept.Debug;
end;

procedure TfmMain.cbUseNetClick(Sender: TObject);
begin
  OraSession.Options.Net := cbUseNet.Checked;
end;

procedure TfmMain.cbDebugClick(Sender: TObject);
begin
  sqGet.Debug := cbDebug.Checked;
  sqPut.Debug := cbDebug.Checked;
  quDept.Debug := cbDebug.Checked;
end;

end.