dllmain.pas

ODAC 5.7.0.28

unit DLLMain;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Grids, DBGrids, Db, MemDS, Ora, StdCtrls, ExtCtrls, DBCtrls, DBAccess, OdacVcl;

type
  TfmDllMain = class(TForm)
    OraQuery: TOraQuery;
    DBGrid: TDBGrid;
    DataSource: TDataSource;
    pnToolBar: TPanel;
    btOpen: TButton;
    btClose: TButton;
    DBNavigator: TDBNavigator;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormShow(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

procedure AssignSession(Session: TOraSession); cdecl;
procedure ShowForm; cdecl;
procedure HideForms; cdecl;

implementation
uses
  OraCall;

{$R *.DFM}

var
  ExternalSession: TOraSession;
  FormList: TList;
  FormCount: integer;

procedure AssignSession(Session: TOraSession); cdecl;
begin
  ExternalSession:= Session;
end;

procedure ShowForm; cdecl;
begin
  InitOCI; // before using of ODAC components

  with TfmDllMain.Create(Application) do begin
    Inc(FormCount);
    Caption:= IntToStr(FormCount) + '. ' + Caption;
    OraQuery.Session := ExternalSession;
    OraQuery.Active := True;
    Show;
  end;
end;

procedure HideForms; cdecl;
begin
  while FormList.Count > 0 do begin
    TForm(FormList[0]).Free;
    FormList.Delete(0);
  end;
end;

procedure TfmDllMain.FormShow(Sender: TObject);
begin
  FormList.Add(Self);
end;

procedure TfmDllMain.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  FormList.Remove(Self);
  Action := caFree;
end;

procedure TfmDllMain.btOpenClick(Sender: TObject);
begin
  OraQuery.Open;
end;

procedure TfmDllMain.btCloseClick(Sender: TObject);
begin
  OraQuery.Close;
end;

initialization
  FormCount:= 0;
  FormList:= TList.Create;
finalization
  HideForms;
  FormList.Free;
end.