main.pas

ODAC 5.7.0.28

unit Main;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, QButtons, OdacClx,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, Buttons, OdacVcl,
{$ENDIF}
  Db, MemDS, DBAccess, Ora;

type
  TfmMain = class(TForm)
    OraSession: TOraSession;
    DBGrid: TDBGrid;
    DataSource: TDataSource;
    ToolBar: TPanel;
    btOpen: TButton;
    DBNavigator: TDBNavigator;
    btClose: TButton;
    ConnectDialog: TConnectDialog;
    OraQuery: TOraQuery;
    btApply: TBitBtn;
    btCancel: TBitBtn;
    btStartTrans: TBitBtn;
    btCommitTrans: TBitBtn;
    btRollbackTrans: TBitBtn;
    StatusBar: TStatusBar;
    cbCustomUpdate: TCheckBox;
    cbCachedUpdates: TCheckBox;
    OraQueryStatus: TStringField;
    btCommit: TBitBtn;
    cbDebug: TCheckBox;
    cbUnmodified: TCheckBox;
    Label1: TLabel;
    cbModified: TCheckBox;
    cbInserted: TCheckBox;
    cbDeleted: TCheckBox;
    OraQueryDEPTNO: TIntegerField;
    OraQueryDNAME: TStringField;
    OraQueryLOC: TStringField;
    btRevertRecord: TBitBtn;
    RefreshRecord: TButton;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure btApplyClick(Sender: TObject);
    procedure btCancelClick(Sender: TObject);
    procedure btStartTransClick(Sender: TObject);
    procedure btCommitTransClick(Sender: TObject);
    procedure btRollbackTransClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure cbCachedUpdatesClick(Sender: TObject);
    procedure OraQueryUpdateError(DataSet: TDataSet; E: EDatabaseError;
      UpdateKind: TUpdateKind; var UpdateAction: TUpdateAction);
    procedure OraQueryUpdateRecord(DataSet: TDataSet;
      UpdateKind: TUpdateKind; var UpdateAction: TUpdateAction);
    procedure cbCustomUpdateClick(Sender: TObject);
    procedure OraQueryCalcFields(DataSet: TDataSet);
    procedure btCommitClick(Sender: TObject);
    procedure cbDebugClick(Sender: TObject);
    procedure cbUnmodifiedClick(Sender: TObject);
    procedure cbModifiedClick(Sender: TObject);
    procedure cbInsertedClick(Sender: TObject);
    procedure cbDeletedClick(Sender: TObject);
    procedure DataSourceDataChange(Sender: TObject; Field: TField);
    procedure DataSourceStateChange(Sender: TObject);
    procedure DBGridDrawDataCell(Sender: TObject; const Rect: TRect;
      Field: TField; State: TGridDrawState);
    procedure btRevertRecordClick(Sender: TObject);
    procedure RefreshRecordClick(Sender: TObject);
  private
    { Private declarations }
    procedure ShowTrans;
    procedure ShowPending;
    procedure ShowUpdateRecordTypes;    
  public
    { Public declarations }
  end;

var
  fmMain: TfmMain;

implementation

uses
  UpdateAction;

{$R *.dfm}

procedure TfmMain.ShowTrans;
begin
  if OraSession.InTransaction then
    StatusBar.Panels[1].Text := 'In Transaction'
  else
    StatusBar.Panels[1].Text := '';
end;

procedure TfmMain.ShowPending;
begin
  if OraQuery.UpdatesPending then
    StatusBar.Panels[0].Text := 'Updates Pending'
  else
    StatusBar.Panels[0].Text := '';
end;

procedure TfmMain.ShowUpdateRecordTypes;
begin
  if OraQuery.CachedUpdates then begin
    cbUnmodified.Checked := rtUnmodified in OraQuery.UpdateRecordTypes;
    cbModified.Checked := rtModified in OraQuery.UpdateRecordTypes;
    cbInserted.Checked := rtInserted in OraQuery.UpdateRecordTypes;
    cbDeleted.Checked := rtDeleted in OraQuery.UpdateRecordTypes;
  end;
end;

procedure TfmMain.btOpenClick(Sender: TObject);
begin
  OraQuery.Open;
end;

procedure TfmMain.btCloseClick(Sender: TObject);
begin
  OraQuery.Close;
end;

procedure TfmMain.btApplyClick(Sender: TObject);
begin
  OraQuery.ApplyUpdates;
  ShowPending;
end;

procedure TfmMain.btCommitClick(Sender: TObject);
begin
  OraQuery.CommitUpdates;
  ShowPending;
end;

procedure TfmMain.btCancelClick(Sender: TObject);
begin
  OraQuery.CancelUpdates;
  ShowPending;
end;

procedure TfmMain.btStartTransClick(Sender: TObject);
begin
  OraSession.StartTransaction;
  ShowTrans;
end;

procedure TfmMain.btCommitTransClick(Sender: TObject);
begin
  OraSession.Commit;
  ShowTrans;
end;

procedure TfmMain.btRollbackTransClick(Sender: TObject);
begin
  OraSession.Rollback;
  ShowTrans;
end;

procedure TfmMain.FormShow(Sender: TObject);
begin
  cbCachedUpdates.Checked := OraQuery.CachedUpdates;
  cbDebug.Checked := OraQuery.Debug;
  ShowUpdateRecordTypes;
end;

procedure TfmMain.cbCachedUpdatesClick(Sender: TObject);
begin
  OraQuery.CachedUpdates := cbCachedUpdates.Checked;
  ShowUpdateRecordTypes;
end;

procedure TfmMain.OraQueryUpdateError(DataSet: TDataSet; E: EDatabaseError;
  UpdateKind: TUpdateKind; var UpdateAction: TUpdateAction);
begin
  fmUpdateAction.rgAction.ItemIndex := Ord(UpdateAction);
  fmUpdateAction.rgKind.ItemIndex := Ord(UpdateKind);
  fmUpdateAction.lbField.Caption := string(DataSet.Fields[0].Value);
  fmUpdateAction.lbMessage.Caption := E.Message;
  fmUpdateAction.ShowModal;
  UpdateAction:= TUpdateAction(fmUpdateAction.rgAction.ItemIndex);
end;

procedure TfmMain.OraQueryUpdateRecord(DataSet: TDataSet;
  UpdateKind: TUpdateKind; var UpdateAction: TUpdateAction);
begin
  fmUpdateAction.rgAction.ItemIndex := Ord(UpdateAction);
  fmUpdateAction.rgKind.ItemIndex := Ord(UpdateKind);
  fmUpdateAction.lbField.Caption := string(DataSet.Fields[0].NewValue);
  fmUpdateAction.lbMessage.Caption := '';
  fmUpdateAction.ShowModal;
  UpdateAction := TUpdateAction(fmUpdateAction.rgAction.ItemIndex);
end;

procedure TfmMain.cbCustomUpdateClick(Sender: TObject);
begin
  if cbCustomUpdate.Checked then
    OraQuery.OnUpdateRecord := OraQueryUpdateRecord
  else
    OraQuery.OnUpdateRecord := nil;
end;

procedure TfmMain.OraQueryCalcFields(DataSet: TDataSet);
var
  St:string;
begin
  case Ord(TOraDataSet(DataSet).UpdateStatus) of
    0: St := 'Unmodified';
    1: St := 'Modified';
    2: St := 'Inserted';
    3: St := 'Deleted';
  end;
  DataSet.FieldByName('Status').AsString := St;

{  case Ord(TOraDataSet(DataSet).UpdateResult) of
    0: St := 'Fail';
    1: St := 'Abort';
    2: St := 'Skip';
    3: St := 'Applied';
  end;
  DataSet.FieldByName('Result').AsString := St;}
end;

procedure TfmMain.cbDebugClick(Sender: TObject);
begin
  OraQuery.Debug := cbDebug.Checked;
end;

procedure TfmMain.cbUnmodifiedClick(Sender: TObject);
begin
  if cbUnmodified.Checked then
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes + [rtUnmodified]
  else
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes - [rtUnmodified];
end;

procedure TfmMain.cbModifiedClick(Sender: TObject);
begin
  if cbModified.Checked then
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes + [rtModified]
  else
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes - [rtModified];
end;

procedure TfmMain.cbInsertedClick(Sender: TObject);
begin
  if cbInserted.Checked then
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes + [rtInserted]
  else
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes - [rtInserted];
end;

procedure TfmMain.cbDeletedClick(Sender: TObject);
begin
  if cbDeleted.Checked then
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes + [rtDeleted]
  else
    OraQuery.UpdateRecordTypes := OraQuery.UpdateRecordTypes - [rtDeleted];
end;

procedure TfmMain.DataSourceStateChange(Sender: TObject);
begin
  ShowPending;
  StatusBar.Panels[2].Text := 'RecordCount:' + IntToStr(OraQuery.RecordCount);
  StatusBar.Panels[3].Text := 'RecordNo:' + IntToStr(OraQuery.RecNo);
end;

procedure TfmMain.DataSourceDataChange(Sender: TObject; Field: TField);
begin
  DataSourceStateChange(nil);
end;

procedure TfmMain.DBGridDrawDataCell(Sender: TObject; const Rect: TRect;
  Field: TField; State: TGridDrawState);
begin
  if OraQuery.UpdateResult in [uaFail,uaSkip] then
    TDBGrid(Sender).Canvas.Brush.Color := clRed
  else
    if OraQuery.UpdateStatus <> usUnmodified then
      TDBGrid(Sender).Canvas.Brush.Color := clYellow;

  TDBGrid(Sender).DefaultDrawDataCell(Rect, Field, State);
end;

procedure TfmMain.btRevertRecordClick(Sender: TObject);
begin
  OraQuery.RevertRecord;
  ShowPending;
end;

procedure TfmMain.RefreshRecordClick(Sender: TObject);
begin
  OraQuery.RefreshRecord;
end;

end.