📄 cstartup.s
字号:
;/*=================================文件信息================================*/;
;/*文 件 名：Cstartup.s */;
;/*创 建 人：葛康 */;
;/*最后修改日期：2006年3月9日 */;
;/*文 件 描 述： 无 */;
;/*=========================================================================*/;
;/*-------------------------------------------------------------------------*/;
;/*ARM模式与状态位 */;
;/*-------------------------------------------------------------------------*/;
ARM_MODE_USER EQU 0x10
ARM_MODE_FIQ EQU 0x11
ARM_MODE_IRQ EQU 0x12
ARM_MODE_SVC EQU 0x13
ARM_MODE_ABORT EQU 0x17
ARM_MODE_UNDEF EQU 0x1B
ARM_MODE_SYS EQU 0x1F
I_BIT EQU 0x80
F_BIT EQU 0x40
T_BIT EQU 0x20
;/*-------------------------------------------------------------------------*/;
;/*中断相关寄存器 */;
;/*-------------------------------------------------------------------------*/;
AT91C_BASE_AIC EQU 0xFFFFF000
AIC_FVR EQU 0x00000104
AIC_IVR EQU 0x00000100
AIC_EOICR EQU 0x00000130
;/*-------------------------------------------------------------------------*/;
;/*AREA定义 */;
;/*-------------------------------------------------------------------------*/;
AREA Reset, CODE, READONLY
ENTRY
EXPORT entry
entry
;/*-------------------------------------------------------------------------*/;
;/*异常向量 */;
;/*-------------------------------------------------------------------------*/;
B InitReset ; 0x00 Reset handler
Undefvec
B Undefvec ; 0x04 Undefined Instruction
Swivec
B Swivec ; 0x08 Software Interrupt
Pabtvec
B Pabtvec ; 0x0C Prefetch Abort
Dabtvec
B Dabtvec ; 0x10 Data Abort
Rsvdvec
B Rsvdvec ; 0x14 reserved
Irqvec
B IRQ_Handler_Entry ; 0x18 IRQ
Fiqvec ; 0x1c FIQ
;/*-------------------------------------------------------------------------*/;
;/*FIQ中断处理入口 */;
;/*-------------------------------------------------------------------------*/;
FIQ_Handler_Entry
;- Switch in SVC/User Mode to allow User Stack access for C code
; because the FIQ is not yet acknowledged
;- Save and r0 in FIQ_Register
MOV R9,R0
LDR R0 , [R8, #AIC_FVR]
MSR CPSR_c,#I_BIT :OR: F_BIT :OR: ARM_MODE_SVC
;- Save scratch/used registers and LR in User Stack
STMFD SP!, { R1-R3, R12, LR}
;- Branch to the routine pointed by the AIC_FVR
MOV R14, PC
BX R0
;- Restore scratch/used registers and LR from User Stack
LDMIA SP!, { R1-R3, R12, LR}
;- Leave Interrupts disabled and switch back in FIQ mode
MSR CPSR_c, #I_BIT :OR: F_BIT :OR: ARM_MODE_FIQ
;- Restore the R0 ARM_MODE_SVC register
MOV R0,R9
;- Restore the Program Counter using the LR_fiq directly in the PC
SUBS PC,LR,#4
;/*-------------------------------------------------------------------------*/;
;/*复位处理程序 */;
;/*-------------------------------------------------------------------------*/;
InitReset
;/*-------------------------------------------------------------------------*/;
;/*调用C函数AT91F_LowLevelInit初始化（APMC, AIC, EBI, ....） */;
;/*-------------------------------------------------------------------------*/;
IMPORT AT91F_LowLevelInit
LDR R13,=0x00204000 ; temporary stack in internal Ram
LDR R0,=AT91F_LowLevelInit
MOV LR, PC
BX R0
;/*-------------------------------------------------------------------------*/;
;/*堆栈大小定义 */;
;/*-------------------------------------------------------------------------*/;
IRQ_STACK_SIZE EQU (3*8*4) ; 2 words per interrupt priority level
;/*-------------------------------------------------------------------------*/;
;/*设置每种模式下的堆栈指针 */;
;/*-------------------------------------------------------------------------*/;
LDR R0, =0x00204000
;- Set up Fast Interrupt Mode and set FIQ Mode Stack
MSR CPSR_c, #ARM_MODE_FIQ:OR:I_BIT:OR:F_BIT
;- Init the FIQ register
LDR R8, =AT91C_BASE_AIC
;- Set up Interrupt Mode and set IRQ Mode Stack
MSR CPSR_c, #ARM_MODE_IRQ:OR:I_BIT:OR:F_BIT
MOV R13, r0 ; Init stack IRQ
SUB R0, R0, #IRQ_STACK_SIZE
;- Set up Supervisor Mode and set Supervisor Mode Stack
MSR CPSR_c, #ARM_MODE_SVC
MOV R13, R0 ; Init stack Sup
;/*-------------------------------------------------------------------------*/;
;/*跳转到C运行时库 */;
;/*-------------------------------------------------------------------------*/;
IMPORT __main
LDR R0, =__main
MOV LR, PC
BX R0
;/*-------------------------------------------------------------------------*/;
;/*无限循环 */;
;/*-------------------------------------------------------------------------*/;
End
B End
;/*-------------------------------------------------------------------------*/;
;/*IRQ中断处理入口 */;
;/*-------------------------------------------------------------------------*/;
IRQ_Handler_Entry
;- Manage Exception Entry
;- Adjust and save LR_irq in IRQ stack
SUB LR, LR, #4
STMFD SP!, {LR}
;- Save SPSR need to be saved for nested interrupt
MRS R14, SPSR
STMFD SP!, {R14}
;- Save and r0 in IRQ stack
STMFD SP!, {R0}
;- Write in the IVR to support Protect Mode
;- No effect in Normal Mode
;- De-assert the NIRQ and clear the source in Protect Mode
LDR R14, =AT91C_BASE_AIC
LDR R0 , [R14, #AIC_IVR]
STR R14, [R14, #AIC_IVR]
;- Enable Interrupt and Switch in Supervisor Mode
MSR CPSR_c, #ARM_MODE_SVC
;- Save scratch/used registers and LR in User Stack
STMFD SP!, { R1-R3, R12, R14}
;- Branch to the routine pointed by the AIC_IVR
MOV R14, PC
BX R0
;- Restore scratch/used registers and LR from User Stack
LDMIA SP!, { R1-R3, R12, R14}
;- Disable Interrupt and switch back in IRQ mode
MSR CPSR_c, #I_BIT :OR: ARM_MODE_IRQ
;- Mark the End of Interrupt on the AIC
LDR R14, =AT91C_BASE_AIC
STR R14, [R14, #AIC_EOICR]
;- Restore SPSR_irq and r0 from IRQ stack
LDMIA SP!, {R0}
;- Restore SPSR_irq and r0 from IRQ stack
LDMIA SP!, {R14}
MSR SPSR_cxsf, R14
;- Restore adjusted LR_irq from IRQ stack directly in the PC
LDMIA SP!, {PC}^
;/*-------------------------------------------------------------------------*/;
;/*设置缺省中断向量 */;
;/*-------------------------------------------------------------------------*/;
EXPORT AT91F_Default_FIQ_handler
AT91F_Default_FIQ_handler
B AT91F_Default_FIQ_handler
EXPORT AT91F_Default_IRQ_handler
AT91F_Default_IRQ_handler
B AT91F_Default_IRQ_handler
EXPORT AT91F_Spurious_handler
AT91F_Spurious_handler
B AT91F_Spurious_handler
END
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -