ldscript_ram_gnu.ld

含t h r e a d x,u c o s 的b s p

 /*;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 ; 
 ; Project: SDK7A404 example code linker file for GNU toolset
 ; 
 ; Description: 
 ;     This file implements a linker script for the LogicPD SDK7A404 EVB
 ;     when used with the SDK7A404 example code.
 ;
 ; Notes:
 ;     This linker script defines an image that executes starting at
 ;     address 0xC00C0000.
 ;
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;  
 ; SHARP MICROELECTRONICS OF THE AMERICAS MAKES NO REPRESENTATION
 ; OR WARRANTIES WITH RESPECT TO THE PERFORMANCE OF THIS SOFTWARE,
 ; AND SPECIFICALLY DISCLAIMS ANY RESPONSIBILITY FOR ANY DAMAGES, 
 ; SPECIAL OR CONSEQUENTIAL, CONNECTED WITH THE USE OF THIS SOFTWARE.
 ;
 ; SHARP MICROELECTRONICS OF THE AMERICAS PROVIDES THIS SOFTWARE SOLELY 
 ; FOR THE PURPOSE OF SOFTWARE DEVELOPMENT INCORPORATING THE USE OF A 
 ; SHARP MICROCONTROLLER OR SYSTEM-ON-CHIP PRODUCT. USE OF THIS SOURCE
 ; FILE IMPLIES ACCEPTANCE OF THESE CONDITIONS.
 ;
 ; COPYRIGHT (C) 2001 SHARP MICROELECTRONICS OF THE AMERICAS, INC.
 ;     CAMAS, WA
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;*/

/* Define the supported output formats - elf32-littlearm is the
   default */
OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")

/* Define the target architecture */
OUTPUT_ARCH(arm)

/* Define the system entry point */
ENTRY(__start)

/* Define the memory layout for the board */
SECTIONS
{
    /* Set up the location counter */
    . = 0xC00C0000;

    /* Define a execution region that resides at ram base */
    .text :
    {
        /* Start of .text segment */
        PROVIDE (__gnu_textstart = .);

        *(.text)               
    }

    /* Define a readonly data section in flash that resides at the
       end of the .rom execution region */
    .rodata : 
    { 
        /* Place all .rodata regions in this section. */
        *(.rodata); 
    }

    /* (Real) End of .text segment */
    PROVIDE (__gnu_textend = .);

    /* Define a read/write section at the end of the .text section */
    .data :
    {
        /* Start of .data segment */
        PROVIDE (__gnu_datastart = .);

        *(.data); 

        /* End of .data segment */
        PROVIDE (__gnu_dataend = .);
    }

    /* Define a ZI section at the end of the .data section */
    .bss :
    {
        /* Start of .bss segment */
        PROVIDE (__gnu_bssstart = .);

        *(.bss) *(COMMON); 

        /* End of .bss segment */
        PROVIDE (__gnu_bssend = .);
    }

    /* Define linker variable to reference end address of this
       section - required by gcc */
    PROVIDE (end = .);
    PROVIDE (__end = .);

      /* The __EH_FRAME_BEGIN__ symbol is not used, but the linker
         thinks it needs it for some libraries */
      __EH_FRAME_BEGIN__ = 0;

    /* DWARF debug sections
       Symbols in the DWARF debugging sections are relative 
       to the beginning of the section so we begin them at 0 */
        
    /* DWARF 1 */
    .debug          0   : { *(.debug) }
    .line           0   : { *(.line) }
        
    /* GNU DWARF 1 extensions */
    .debug_srcinfo  0   : { *(.debug_srcinfo) }
    .debug_sfnames  0   : { *(.debug_sfnames) }
        
    /* DWARF 1.1 and DWARF 2 */
    .debug_aranges  0   : { *(.debug_aranges) }
    .debug_pubnames 0   : { *(.debug_pubnames) }
        
    /* DWARF 2 */
    .debug_info     0   : { *(.debug_info) }
    .debug_abbrev   0   : { *(.debug_abbrev) }
    .debug_line     0   : { *(.debug_line) }
    .debug_frame    0   : { *(.debug_frame) }
    .debug_str      0   : { *(.debug_str) }
    .debug_loc      0   : { *(.debug_loc) }
    .debug_macinfo  0   : { *(.debug_macinfo) }
}