checkuserlogin.asp

来自「1.支持文章」· ASP 代码 · 共 102 行

<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<%option explicit%>
<!--#include file="Conn.asp"-->
<!--#include file="SysCls/KS_UserCommonCls.asp"-->
<%
'===================================================================================================================
'软件名称：科汛网站管理系统
'当前版本：科汛网站管理系统 V2.2 0628 Free
'Copyright (C) 2006-2008 Kesion.Com  All rights reserved.
'产品咨询QQ：9537636,41904294
'技术支持QQ：111394,54004407 
'程序版权：科汛网络
'程序开发：科汛网络开发组（总策划：林文仲）
'E-Mail  :[e-mail] [e-mail]
'官方网站：http://www.kesion.com  
'演示站点：http://test.kesion.com 
'郑重声明:
'    ①、免费版本请在程序首页保留版权信息，并做上本站LOGO友情连接,商业版本无此要求;
'    ②、任何个人或组织不得在授权允许的情况下删除、修改、拷贝本软件及其他副本上一切关于版权的信息；
'    ③、科汛网络保留此软件的法律追究权利
'===================================================================================================================
Dim KSCls
Set KSCls = New UserLogin
KSCls.Execute()
Set KSCls = Nothing

Class UserLogin
        Private KSCMS
		Private KSUser
		Private UserName,PassWord,Verifycode,ExpiresDate
		Private LoginVerificCodeTF
		Private Sub Class_Initialize()
		  Set KSCMS=New CommonCls
		  Set KSUser = New UserCls
		End Sub
        Private Sub Class_Terminate()
		 Call KSCMS.CloseConn()
		 Set KSCMS=Nothing
		 Set KSUser=Nothing
		End Sub
		Public Sub Execute()
			UserName=KSCMS.ReplaceBadChar(KSCMS.G("UserName"))
			PassWord=KSCMS.ReplaceBadChar(KSCMS.G("PassWord"))
			ExpiresDate=KSCMS.ReplaceBadChar(KSCMS.G("ExpiresDate"))
			Verifycode=KSCMS.ReplaceBadChar(KSCMS.G("Verifycode"))
			LoginVerificCodeTF=KSCMS.GetConfig("LoginVerificCodeTF")
			Dim LastLoginIP:LastLoginIP = Trim(Request.ServerVariables("HTTP_X_FORWARDED_FOR"))
			 If LastLoginIP = "" Then LastLoginIP = Request.ServerVariables("REMOTE_ADDR")
		 
			IF UserName="" Then
		   	 Response.Write("<script>alert('用户名不能为空，请输入！');history.back();</script>")
		     Exit Sub
			End IF
		    IF PassWord="" Then
		   	 Response.Write("<script>alert('登录密码不能为空，请输入！');history.back();</script>")
		     Exit Sub
			End IF
			IF Trim(Verifycode)<>Trim(Session("Verifycode")) And LoginVerificCodeTF=1 And KSCMS.G("From")<>"Top" then 
		   	 Response.Write("<script>alert('验证码有误，请重新输入！');history.back();</script>")
		     Exit Sub
			End IF
            If ExpiresDate = "" Or Not IsNumeric(ExpiresDate) Then
				ExpiresDate = 0
			Else
				ExpiresDate = CLng(ExpiresDate)
			End If
			
			PassWord=KSCMS.MD5(PassWord,16)
			Dim UserRS:Set UserRS=Server.CreateObject("Adodb.RecordSet")
			 UserRS.Open "Select UserID,UserName,PassWord,Locked,Score,LastLoginIP,LastLoginTime,LoginTimes From KS_User Where UserName='" &UserName & "' And PassWord='" & PassWord & "'",Conn,1,3
			 If UserRS.Eof And UserRS.BOf Then
				  Response.Write("<script>alert('你输入的用户名或密码有误，请重新输入！');history.back();</script>")
				  UserRS.Close:Set UserRS=Nothing
				 Exit Sub
			 ElseIf UserRS("Locked")=1 Then
			   Response.Write("<script>alert('您的账号已被管理员锁定，请与管理员联系！');history.back();</script>")
			   Exit Sub
			 Else
			            '登录成功，更新用户相应的数据
						UserRS("Score")=UserRS("Score")+KSCMS.GetConfig("LoginPerTimeAddScore")
						UserRS("LastLoginIP") = LastLoginIP
                        UserRS("LastLoginTime") = Now()
                        UserRS("LoginTimes") = UserRS("LoginTimes") + 1
                        UserRS.Update
						 
						 If ExpiresDate<>0 Then Response.Cookies(KSCMS.SiteSn).Expires = Date + 365

							Response.Cookies(KSCMS.SiteSn)("UserName") = UserName
							Response.Cookies(KSCMS.SiteSn)("Password") = Password
							
							If InStr(lcase(Request.ServerVariables("HTTP_REFERER")), "login") > 0 Then 
							   Response.Redirect KSCMS.GetDomain & "Member/Index.asp"
							else
                                Response.Redirect Request.ServerVariables("HTTP_REFERER")
						    end if
			 End IF
			
        End Sub
End Class
%>