buyers.cls

来自「制造业产供销与往来系统源码」· CLS 代码 · 共 110 行

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Buyers"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit
Dim OBuyers As Collection

Public Property Get Name() As String
   Name = "Buyers"
End Property

Private Sub Class_Initialize()
   Set OBuyers = New Collection
End Sub

Public Sub Add(OBuyer As Buyer, Optional Needsave As Integer = 1)
   Dim mKey As Integer
   Dim vBuyer As Buyer
   For Each vBuyer In OBuyers
      If mKey < vBuyer.BuyerKey Then
         mKey = vBuyer.BuyerKey
      End If
   Next
   OBuyer.BuyerKey = mKey + 1
   If Needsave = 1 Then
      OBuyer.Save
   End If
   OBuyers.Add Item:=OBuyer, Key:=CStr(mKey + 1)
End Sub

Public Sub Remove(Vindex, Optional Needdel As Integer = 1)
 
   Dim OBuyer As Buyer
   Set OBuyer = Item(Vindex)
   If Needdel = 1 And OBuyer.BuyerId = 1 Then
      OBuyer.Del
   End If
   OBuyers.Remove (Vindex)
   Set OBuyer = Nothing
   
End Sub

Public Property Get Count() As Integer
   Count = OBuyers.Count
End Property

Public Function Item(Vindex) As Buyer
Attribute Item.VB_UserMemId = 0
   Set Item = OBuyers.Item(Vindex)
End Function

Public Sub ClearAll()
   Dim I, Vcount As Integer
   Vcount = OBuyers.Count
   For I = 1 To Vcount
      OBuyers.Remove (1)
   Next
End Sub

Public Sub Fillbydb()
   Dim OBuyer As Buyer
   Dim Rs As DbRs
   Dim mKey As Integer
On Error GoTo Errorhandle

   ClearAll
   Set Rs = New DbRs
   Rs.Fillbydb "SELECT BuyerCODE,BuyerMC,BuyerISSTOP,BuyerNO FROM BuyerREC ORDER BY BuyerCODE"
   Rs.MoveFirst
   
   mKey = 1
   Do Until Rs.EOF
      Set OBuyer = New Buyer
      OBuyer.BuyerKey = mKey
      OBuyer.BatchLet Rs!BuyerCode, Rs!BuyerMc, Rs!BuyerIsStop, Rs!BuyerNo
      OBuyers.Add Item:=OBuyer, Key:=CStr(mKey)
      Rs.MoveNext
      mKey = mKey + 1
   Loop

   Set Rs = Nothing

Exit Sub
Errorhandle:
   Set Rs = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"
  Set NewEnum = OBuyers.[_NewEnum]
End Function

Private Sub Class_Terminate()
   ClearAll
   Set OBuyers = Nothing
End Sub