uitools.pro

qt-x11-opensource-src-4.1.4.tar.gz源码

TEMPLATE = lib
TARGET = QtUiTools
QT += xml
CONFIG += qt staticlib
DESTDIR = ../../../../lib
DLLDESTDIR = ../../../../bin
CONFIG += debug_and_release
CONFIG(debug, debug|release) {
    unix:TARGET = $$member(TARGET, 0)_debug
    else:TARGET = $$member(TARGET, 0)d
}

DEFINES += QUILOADERINTERNAL_NAMESPACE QT_DESIGNER_STATIC
isEmpty(QT_MAJOR_VERSION) {
   VERSION=4.1.0
} else {
   VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
}
QMAKE_TARGET_COMPANY = Trolltech ASA
QMAKE_TARGET_PRODUCT = UiLoader
QMAKE_TARGET_DESCRIPTION = QUiLoader
QMAKE_TARGET_COPYRIGHT = Copyright (C) 2003-2006 Trolltech ASA

include(../lib/uilib/uilib.pri)

HEADERS += quiloader.h
SOURCES += quiloader.cpp

include($$QT_SOURCE_TREE/include/QtUiTools/headers.pri)
quitools_headers.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES
quitools_headers.path = $$[QT_INSTALL_HEADERS]/QtUiTools
INSTALLS        += quitools_headers

target.path=$$[QT_INSTALL_LIBS]
INSTALLS        += target