sudec.asm

来自「pic单片机常用的汇编程序,很有用的,分成各个小模块」· 汇编 代码 · 共 40 行

;********************SUDEC********************
;本程序实现对单字节无符号数据块进行降序排列。
;入口参数：数据块首址在SADR中,数据个数在W中。
;出口参数：排好序的数据仍在原数据块中。
;占用资源：W,STATUS,FSR,020H,028H,029H,02AH,02BH,一重堆栈。

           IFNDEF       SUDEC1
            #DEFINE     SUDEC1

SUDEC       ADDLW       0FFH        ;字节数减1是比较次数
            MOVWF       TEMP3       ;TEMP3暂存内循环计数值
LOOP71      MOVF        TEMP3,W
            MOVWF       TEMP4       ;循环计数器减1
            BCF         TEMP1,0     ;TEMP1:0作为交换标志位
            MOVF        SADR,W
            MOVWF       FSR
LOOP70      MOVF        INDF,W
            INCF        FSR,F
            SUBWF       INDF,W
            BTFSS       STATUS,C
            GOTO        NEXT36
            BTFSC       STATUS,Z
            GOTO        NEXT36
            SUBWF       INDF,W
            MOVWF       TEMP2       ;TEMP2暂存将要交换的数
            MOVF        INDF,W
            DECF        FSR,F
            MOVWF       INDF
            MOVF        TEMP2,W
            INCF        FSR,F
            MOVWF       INDF        ;完成交换
            BSF         TEMP1,0     ;置交换标志
NEXT36      DECFSZ      TEMP4,F
            GOTO        LOOP70
            BTFSS       TEMP1,0
            RETLW       0
            DECFSZ      TEMP3,F
            GOTO        LOOP71
            RETLW       0
           ENDIF