ssinc.asm

来自「pic单片机常用的汇编程序,很有用的,分成各个小模块」· 汇编 代码 · 共 46 行

;********************SSINC********************
;本程序实现对单字节有符号数据块进行增序排列。
;入口参数：数据块首址在SADR中,数据个数在W中。
;出口参数：排好序的数据仍在原数据块中。
;占用资源：W,STATUS,FSR,020H,023H,028H,029H,02AH,02BH,一重堆栈。

           IFNDEF       SSINC1
            #DEFINE     SSINC1

SSINC       ADDLW       0FFH        ;字节数减1是比较次数
            MOVWF       TEMP3       ;TEMP3暂存内循环计数值
LOOP67      MOVF        TEMP3,W
            MOVWF       CNT         ;循环计数器减1
            BCF         TEMP1,0     ;TEMP1:0作为交换标志位
            MOVF        SADR,W
            MOVWF       FSR
LOOP66      MOVF        INDF,W
            INCF        FSR,F
            XORWF       INDF,W
            MOVWF       TEMP4       ;TEMP4:7存放符号异同标志
            XORWF       INDF,W      ;恢复W
            BTFSC       TEMP4,7
            GOTO        DIFF       
            SUBWF       INDF,W
            BTFSC       STATUS,C
            GOTO        NEXT33
            SUBWF       INDF,W
SWITCH      MOVWF       TEMP2       ;TEMP2暂存将要交换的数
            MOVF        INDF,W
            DECF        FSR,F
            MOVWF       INDF
            MOVF        TEMP2,W
            INCF        FSR,F
            MOVWF       INDF        ;完成交换
            BSF         TEMP1,0     ;置交换标志
NEXT33      DECFSZ      CNT,F
            GOTO        LOOP66
            BTFSS       TEMP1,0
            RETLW       0
            DECFSZ      TEMP3,F
            GOTO        LOOP67
            RETLW       0
DIFF        BTFSC       INDF,7
            GOTO        SWITCH
            GOTO        NEXT33
           ENDIF