lnk.cmd

一个ccs开发环境下的滤波器程序

/*****************************************************************************/
/*                                                                           */
/* LNK.CMD - V2.00  COMMAND FILE FOR LINKING C PROGRAMS                      */
/*                                                                           */
/*      Usage:  lnk500 <obj files...>    -o <out file> -m <map file> lnk.cmd */
/*              cl500  <src files...> -z -o <out file> -m <map file> lnk.cmd */
/*                                                                           */
/*      Description: This file is a sample command file that can be used     */
/*                   for linking programs built with the C54x C Compiler.    */
/*                   This file has been designed to work for                 */
/*                   548 C54x device.                                        */
/*                   Use it as a guideline; you may want to make alterations */
/*                   appropriate for the memory layout of the target         */
/*                   system and/or your application.                         */
/*                                                                           */
/*      Notes: (1)   You must specify the directory in which rts.lib is      */
/*                   located.  Either add a "-i<directory>" line to this     */
/*                   file, or use the system environment variable C_DIR to   */
/*                   specify a search path for the libraries.                */
/*                                                                           */
/*             (2)   If the run-time library you are using is not            */
/*                   named rts.lib, be sure to use the correct name here.    */
/*****************************************************************************/

-heap  0x0000		/* No HEAP		*/
-stack 0x0200		/* stack size	*/


MEMORY {

   PAGE 0: /* program memory */

	VECTORS:		 origin = 0x0080, length = 0x0080
	PROG_RAM (RWX) : origin = 0x0100, length = 0x1E00
	PROG_EXT (RWX) : origin = 0x8000, length = 0x4000

   PAGE 1: /* data memory, addresses 0-7Fh are reserved */

      /* some (or all) of internal DARAM */
	DATA_RAM (RW): origin = 0x2000, length = 0x2000
	DATA_EXT (RW): origin = 0xC000, length = 0x4000


   PAGE 2: /* I/O memory */

      /* no devices declared */

} /* MEMORY */


SECTIONS {

   /* Interrupt Vectors */

   vectors > VECTORS 			PAGE 0              /* interrupt vectors         */

	/* * USER SECTIONS *
	   * Those section must be properly aligned in memory */

	audio_buffer1	>	DATA_RAM	PAGE 1	align(512)	/* ABU buffer */
	audio_buffer2	>	DATA_RAM	PAGE 1	align(512)	/* ABU buffer */
	coefficients	>	DATA_RAM	PAGE 1	align(32)	/* fir: Circular addressing */
	delay			> 	DATA_RAM	PAGE 1	align(32)   /* fir circular addressing  */

	/* C SECTIONS */

   .text    > PROG_RAM			PAGE 0   			/* code                     */
   .switch  > PROG_RAM 			PAGE 0              /* switch table info        */

   .data    >> DATA_RAM 		PAGE 1  			/* initialized data          */
   .bss     >> DATA_RAM 		PAGE 1  			/* global & static variables */
   .const   >  DATA_RAM 		PAGE 1              /* constant data             */
   .stack   >> DATA_RAM 		PAGE 1  			/* stack                     */
   
   .cinit	> DATA_RAM			PAGE 1

   .sysmem  >> DATA_RAM | DATA_EXT 		PAGE 1  	/* heap                      */
   .cio     >> DATA_RAM | DATA_EXT 		PAGE 1      /* C I/O                     */  

	/* CSL Section */
	.csldata > DATA_RAM					PAGE 1

} /* SECTIONS */