user_bookmark.asp

打开目录ads文件夹 找到top_ads.js文件 用记事本打开后就可以看到: -------------------------------------- var head_ads_tx

<!-- #include file="include/con_user.asp" -->
<%
dim n_sort,gid,g_id,gname,select_add,id,name,url,rssum
n_sort="book"
rssum=0
g_id=trim(request.querystring("g_id"))
if not(isnumeric(g_id)) then g_id=0
tit="网络书签"

call web_head(2,1,0,0,0)
'----------------------------左边 开始----------------------------
call user_left("")
'----------------------------左边 结束----------------------------
call web_center(0)
'----------------------------中间 开始----------------------------
%>
<script language=javascript>
function group_edit(geid,gename)
{
  var gevar='请输入要修改的书签组（ID：'+geid+'）的新名称，长度不能超过20位';
  this.document.groupedit_frm.g_id.value=geid;
  var gename=prompt(gevar+'：',gename);
  if (gename == null || gename == '' || gename.length>20)
  { alert(gevar+"！");return; }
  else
  { this.document.groupedit_frm.g_name.value=gename; }
  this.document.groupedit_frm.submit();
}

function group_del(gdid)
{
  if (confirm("此操作将删除ID为 "+gdid+" 的书签组！\n真的要删除吗？\n删除后将无法恢复！"))
  { window.location="?action=groupdel&g_id="+gdid; }
}

function bookmark_edit(bid,bname,burl)
{
  var var1='请输入要修改的个人书签（ID：'+bid+'）的名称，长度不能超过50位';
  var var2='请输入要修改的个人书签（ID：'+bid+'）的地址，长度不能超过100位';
  this.document.bookmarkedit_frm.id.value=bid;
  var bename=prompt(var1+'：',bname);
  if (bename == null || bename == '' || bename.length>50)
  { alert(var1+"！");return; }
  else
  {
    this.document.bookmarkedit_frm.name.value=bename;
    var beurl=prompt(var2+'：',burl);
    if (beurl == null || beurl == '' || beurl.length>100)
    { alert(var2+"！");return; }
    else
    {this.document.bookmarkedit_frm.url.value=beurl;}
  }
  this.document.bookmarkedit_frm.submit();
}

function bookmark_del(bdid)
{
  if (confirm("此操作将删除ID为 "+bdid+" 的个人书签！\n真的要删除吗？\n删除后将无法恢复！"))
  { window.location="?action=bookmarkdel&id="+bdid; }
}
</script>
<%
select case action
case "groupedit"
  call group_edit()
case "bookmarkedit"
  call bookmark_edit()
case "groupdel"
  call group_del()
case "bookmarkdel"
  call bookmark_del()
case "groupadd"
  call group_add()
case "bookmarkadd"
  call bookmark_add()
end select

%>
<table cellspacing=1 cellpadding=4 class=table>
<tr>
<td class=td0 width='90%'>&nbsp;<%response.write img_skin("m_user")%>我的书签组</td>
<td class=td0 width='10%' align=center>组操作</td>
</tr>
<form name=groupedit_frm action='?action=groupedit' method=post>
<input type=hidden name=g_id value='<%response.write g_id%>'>
<input type=hidden name=g_name value=''>
</form>
<tr class=bg_tds>
<td><%response.write img_skin("m_")%><a href='?g_id=0' class=gray>[ 根书签组 ]</a>&nbsp;&nbsp;
<%response.write img_skin("m_")%><a href='?action=all' class=gray>[ 浏览所有书签 ]</a></td>
<td align=center class=gray>暂无</td>
</tr>
<%
sql="select g_id,g_name from jk_group where g_sort='"&n_sort&"' and username='"&login_username&"' order by g_id"
set rs=conn.execute(sql)
do while not rs.eof
  gid=rs("g_id")
  gname=rs("g_name")
  select_add=select_add&vbcrlf&"<option value='"&gid&"'"
  if int(gid)=int(g_id) then select_add=select_add&" selected"
  select_add=select_add&">"&gname&"</option>"
%>
<tr class=bg_td>
<td><%response.write img_skin("m_")%><a href='?g_id=<%response.write gid%>'<%if int(g_id)=int(gid) then response.write " class=red_3"%>><%response.write gname%></a></td>
<td align=center><a href="javascript:group_edit(<%response.write gid%>,'<%response.write gname%>');"><img src='<%response.write joekoe_cms.web_dir_skin%>small/edit.gif' border=0></a>&nbsp;<a href="javascript:group_del(<%response.write gid%>);"><img src='<%response.write joekoe_cms.web_dir_skin%>small/del.gif' border=0></a></td>
</tr>
<%
  rs.movenext
loop
rs.close
%>
</table>

<table cellspacing=1 cellpadding=4 class=table>
<tr align=center>
<td class=td0 width='6%'>序号</td>
<td class=td0 width='34%'>我的个人书签名称</td>
<td class=td0 width='50%'>书签地址</td>
<td class=td0 width='10%'>操 作</td>
</tr>
<form name=bookmarkedit_frm action='?g_id=<%response.write g_id%>&action=bookmarkedit' method=post>
<input type=hidden name=id value=''>
<input type=hidden name=name value=''>
<input type=hidden name=url value=''>
</form>
<%
sql="select id,name,url from user_bookmark where"
if action<>"all" then sql=sql&" g_id="&g_id&" and"
sql=sql&" username='"&login_username&"' order by id desc"
set rs=joekoe_cms.exec(sql,1)
do while not rs.eof
  id=rs("id")
  name=rs("name")
  url=rs("url")
  rssum=rssum+1
%>
<tr class=bg_td>
<td align=center class=tims><%response.write rssum%></td>
<td><a href='<%response.write url%>' target=_blank alt='<%response.write joekoe_cms.code_html(name,1,0)%>'><%response.write joekoe_cms.code_html(name,1,15)%></a></td>
<td><a href='<%response.write url%>' target=_blank alt='<%response.write joekoe_cms.code_html(url,1,0)%>'><%response.write joekoe_cms.code_html(url,1,35)%></a></td>
<td align=center><a href="javascript:bookmark_edit(<%response.write id%>,'<%response.write name%>','<%response.write url%>');"><img src='<%response.write joekoe_cms.web_dir_skin%>small/edit.gif' border=0></a>&nbsp;<a href="javascript:bookmark_del(<%response.write id%>);"><img src='<%response.write joekoe_cms.web_dir_skin%>small/del.gif' border=0></a></td>
</tr>
<%
  rs.movenext
loop
rs.close
%>
</table>

<table cellspacing=1 cellpadding=4 class=table>
<tr><td class=td0>&nbsp;<%response.write img_skin("m_user")%>添加新的书签组</td></tr>
<tr class=bg_tds><td>
  <table border=0 cellpadding=2>
  <form action='?action=groupadd' method=post onsubmit="javascript:frm_submitonce(this);">
  <tr>
  <td>组名称：</td>
  <td><input type=text name=g_name size=20 maxlength=20></td>
  <td><input type=submit value='添加书签组'></td>
  </tr>
  </form>
  </table>
</td></tr>
</table>
<table cellspacing=1 cellpadding=4 class=table>
<tr><td class=td0>&nbsp;<%response.write img_skin("m_user")%>添加新的个人书签</td></tr>
<tr class=bg_tds><td>
  <table border=0>
  <form action='?action=bookmarkadd' method=post onsubmit="javascript:frm_submitonce(this);">
  <tr>
  <td>书签名称：</td>
  <td>
    <table border=0 cellpadding=0>
    <tr>
    <td><input type=text name=name size=30 maxlength=50></td>
    <td>　书签组：</td>
    <td><select name=g_id>
    <option value='0'>[ 根书签组 ]</option>
<%response.write select_add%>
</select></td>
    </tr>
    </table>
  </td></tr>
  <tr>
  <td>书签地址：</td>
  <td>
    <table border=0 cellpadding=0>
    <tr>
    <td><input type=text name=url size=50 value='http://' maxlength=100></td>
    <td>　<input type=submit value='添加书签'></td>
    </tr>
    </table>
  </td></tr>
  </form>
  </table>
</td></tr>
</table>
<%
response.write ukong
'----------------------------中间 结束----------------------------
call web_end(0,0)

sub group_del()
  gid=trim(request.querystring("g_id"))
  if not(isnumeric(gid)) then
    response.write vbcrlf & joekoe_cms.js_put("alert(""您在删除书签组时输入的书签组ID出错！\n\n请返回重新输入。"");history.back(1);",1)
    exit sub
  end if
  sql="delete from jk_group where g_id="&gid&" and g_sort='"&n_sort&"' and username='"&login_username&"'"
  call joekoe_cms.exec(sql,1)
  sql="delete from user_bookmark where g_id="&gid&" and username='"&login_username&"'"
  call joekoe_cms.exec(sql,1)
  response.write vbcrlf & joekoe_cms.js_put("alert(""成功的删除了一书签组！"");",1)
end sub

sub group_edit()
  gname=joekoe_cms.code_form(request.form("g_name"))
  gid=trim(request.form("g_id"))
  if len(gname)<1 or len(gname)>20 or not(isnumeric(gid)) then
    response.write vbcrlf & joekoe_cms.js_put("alert(""您在修改书签组的 组名称 时输入的数据有误！\n\n请返回重新输入。"");history.back(1);",1)
    exit sub
  end if
  sql="update jk_group set g_name='"&gname&"' where g_id="&gid&" and g_sort='"&n_sort&"' and username='"&login_username&"'"
  call joekoe_cms.exec(sql,1)
  g_id=gid
  response.write vbcrlf & joekoe_cms.js_put("alert(""成功的修改了书签组的名称："&gname&""");",1)
end sub

sub bookmark_del()
  id=trim(request.querystring("id"))
  if not(isnumeric(id)) then
    response.write vbcrlf & joekoe_cms.js_put("alert(""您在删除个人书签时输入的书签ID出错！\n\n请返回重新输入。"");history.back(1);",1)
    exit sub
  end if
  sql="delete from user_bookmark where id="&id&" and username='"&login_username&"'"
  call joekoe_cms.exec(sql,1)
  response.write vbcrlf & joekoe_cms.js_put("alert(""成功的删除了一书签组！"");",1)
end sub

sub bookmark_edit()
  name=joekoe_cms.code_form(request.form("name"))
  url=joekoe_cms.code_form(request.form("url"))
  id=trim(request.form("id"))
  if len(name)<1 or len(name)>50 or len(url)<1 or len(url)>100 or not(isnumeric(id)) then
    response.write vbcrlf & joekoe_cms.js_put("alert(""您在修改个人书签时输入的数据有误！\n\n请返回重新输入。"");history.back(1);",1)
    exit sub
  end if
  sql="update user_bookmark set name='"&name&"',url='"&url&"' where id="&id&" and username='"&login_username&"'"
  call joekoe_cms.exec(sql,1)
  response.write vbcrlf & joekoe_cms.js_put("alert(""成功的修改了个人书签（名称："&name&"）！"");",1)
end sub

sub group_add()
  gname=joekoe_cms.code_form(request.form("g_name"))
  if len(gname)<1 or len(gname)>20 then
    response.write vbcrlf & joekoe_cms.js_put("alert(""添加书签组的 组名称 是必须要的！\n\n请返回新输入。"");history.back(1);",1)
    exit sub
  end if
  sql="insert into jk_group(g_sort,g_name,username) values('"&n_sort&"','"&gname&"','"&login_username&"')"
  call joekoe_cms.exec(sql,1)
  response.write vbcrlf & joekoe_cms.js_put("alert(""成功的添加了一书签组："&gname&""");",1)
end sub

sub bookmark_add()
  dim gg
  gg=trim(request.form("g_id"))
  if not(isnumeric(gg)) then gg=0
  name=joekoe_cms.code_form(request.form("name"))
  url=joekoe_cms.code_form(request.form("url"))
  if len(name)<1 or len(name)>50 or len(url)<8 or len(url)>100 then
    response.write vbcrlf & joekoe_cms.js_put("alert(""添加新书签的 书签名称 和 书签地址 是必须要的！\n\n请返回新输入。"");history.back(1);",1)
    exit sub
  end if
  sql="insert into user_bookmark(g_id,username,name,url) values("&gg&",'"&login_username&"','"&name&"','"&url&"')"
  call joekoe_cms.exec(sql,1)
  g_id=gg
  response.write vbcrlf &joekoe_cms.js_put("alert(""成功的添加了一个我的个人书签："&name&""");",1)
end sub
%>