pay_return_shop.asp

打开目录ads文件夹 找到top_ads.js文件 用记事本打开后就可以看到: -------------------------------------- var head_ads_tx

<!-- #include file="include/con_shop.asp" -->
<!-- #include file="include/jk_md5.asp" -->
<%
tit="在线支付反馈"

call web_head(0,0,0,0,0)
call shop_load(0,0,0)
'----------------------------左边 开始----------------------------
call shop_left()
call shop_left_nsort(0)
'----------------------------左边 结束----------------------------
call web_center(0)
'----------------------------中间 开始----------------------------

call pay_true()

response.write vbcrlf&ukong
'----------------------------中间 结束----------------------------
call web_end(0,0)

sub pay_true()
  dim obj_pay,o_id,o_nname,o_prices,o_ispay
  set obj_pay=new joekoe_pay
  call obj_pay.pay_return()
  select case cint(obj_pay.val_num)	'0为验证通过
  case 1
    set obj_pay=nothing
    call pay_true_err("错误的支付反馈表单（反馈信息不完整）！")
    exit sub
  case 2
    set obj_pay=nothing
    call pay_true_err("错误的验证签名（非法提交或参数错误）！")
    exit sub
  end select
  
  sql="select top 1 id,nname,prices,ispay from shop_orders where ordernum='"&obj_pay.pay_ordernum&"' and ispayment=1"
  set rs=joekoe_cms.exec(sql,1)
  if rs.eof then
    rs.close
    call pay_true_err("错误的支付反馈表单（"&obj_pay.pay_sort&":"&obj_pay.pay_ordernum&"）！请与网站管理员联系处理。")
    set obj_pay=nothing
    exit sub
  end if
  o_id=rs("id")
  o_nname=rs("nname")
  o_prices=rs("prices")
  o_ispay=rs("ispay")
  rs.close
  if o_ispay=true then
    call pay_true_err("在线支付订单（"&obj_pay.pay_sort&":"&obj_pay.pay_ordernum&"）已支付！请与网站管理员联系处理。")
    set obj_pay=nothing
    exit sub
  end if
  if cstr(fm_price(obj_pay.pay_amount,1))<>cstr(fm_price(o_prices,1)) then
    call pay_true_err("在线支付订单（"&obj_pay.pay_sort&":<font class=blue>"&obj_pay.pay_ordernum&"</font>）的应支付金额（<font class=blue>"&o_prices&val_unit&"</font>）与实支付金额（"&obj_pay.pay_amount&val_unit&"）不等！<br>如有问题请与网站管理员联系处理。")
    set obj_pay=nothing
    exit sub
  end if
  call joekoe_cms.exec("update shop_orders set ispay=1,pay_tim='"&joekoe_cms.now_time&"' where id="&o_id,0)
%>
<table cellspacing=1 cellpadding=4 class=table>
<tr><td colspan=2 class=td align=center><b><%response.write tit%>　　在线支付成功</b></td></tr>
<tr class=bg_td>
<td width='20%'>订 单 号：</td>
<td width='80%'><%response.write obj_pay.pay_ordernum%></td>
</tr>
<tr class=bg_td>
<td>支付金额：</td>
<td><%response.write obj_pay.pay_amount%></td>
</tr>
<tr class=bg_td>
<td>支付时间：</td>
<td><%response.write joekoe_cms.now_time%></td>
</tr>
<tr class=bg_td>
<td>支付状态：</td>
<td><font class=red>成功支付！</font></td>
</tr>
<tr class=bg_td><td colspan=2 align=center height=50><input type=button value='点击继续购物' onClick="javascript:window.location.href='shop.asp';"></td></tr>
</table>
<%
  set obj_pay=nothing
end sub

sub pay_true_err(emsg)
%>
<table cellspacing=1 cellpadding=4 class=table>
<tr><td class=td align=center><b><%response.write tit%>　　错误信息</b></td></tr>
<tr class=bg_td><td align=center height=200 class=htd><font class=red><%response.write emsg%></font><br><br><input type=button value='点击继续购物' onClick="javascript:window.location.href='shop.asp';"></td></tr>
</table>
<%
end sub
%>