con_video.asp

打开目录ads文件夹 找到top_ads.js文件 用记事本打开后就可以看到: -------------------------------------- var head_ads_tx

<!-- #include file="skin.asp" -->
<!-- #include file="jk_nsort.asp" -->
<!-- #include file="con_video_class.asp" -->
<%
dim pic_dir
cid=0
sid=0
n_sort="video"
index_url="video"
tit_fir=format_menu(index_url)
m_channel=index_url
web_img_m="m_"&m_channel
web_img_h="h_"&m_channel

call video_skin.Mod_Load()
pic_dir=video_skin.Main_PicUrl

'----------影院底部调用----------
sub video_end()
  set video_skin=nothing
end sub
'----------框架顶部、底部调用----------
sub video_bar_top(vimg,vtit)
  video_skin.HtmlNums(1)
  video_skin.HtmlRcod "tit",vtit
  video_skin.HtmlRcod "img_top",vimg
  video_skin.HtmlRcod "img_bg","left_bg"
  video_skin.HtmlView(0)
end sub

sub video_bar_end()
  video_skin.HtmlNums(2)
  video_skin.HtmlRcod "img_end","left_end"
  video_skin.HtmlView(1)
end sub
'----------影院搜索----------
sub video_search()
  call video_bar_top("left_sea","视频搜索")
  video_skin.HtmlNums(4)
  video_skin.HtmlRcod "stit","视频"
  video_skin.HtmlRcod "selects",video_select_type()
  video_skin.HtmlView(0)
  call video_bar_end()
end sub

function video_select_type()
  dim n_dim,ncid,temp1
  video_skin.name="nsort"
  if video_skin.cache_chk() then call video_skin.NsortToCache()
  n_dim=video_skin.value
  temp1="<select name=c_id size=1 style=""width: 90px"">" & _
        vbcrlf&"<option value=''>所有分类</option>"
  for i=0 to ubound(n_dim,2)
    ncid=n_dim(0,i)
    temp1=temp1&vbcrlf&"<option class=bg_td value='"&ncid&"'"
    if int(cid)=int(ncid) then
      temp1=temp1&" selected"
    end if
    temp1=temp1&">&nbsp;&nbsp;"&n_dim(1,i)&"</option>"
  next
  temp1=temp1&vbcrlf&"</select>"
  if isarray(n_dim) then erase n_dim
  video_select_type=temp1
end function
'----------影院滚动图片----------
function video_scroll(snum)
  video_skin.name="scroll"
  if video_skin.cache_chk() then call video_skin.ScrollToCache(snum)
  video_scroll=video_skin.value
end function
'----------影院分类----------
sub video_sort()
  dim s_dim,temp1,ncid,img_vclass
  img_vclass="<img border=0 src='{$picurl}h_class.gif' align=absmiddle>&nbsp;<a href='video_list.asp?"
  video_skin.name="nsort"
  if video_skin.cache_chk() then call video_skin.NsortToCache()
  s_dim=video_skin.value
  for i=0 to ubound(s_dim,2)
    if i mod 2=0 then temp1=temp1&vbcrlf&"<tr>"
    ncid=s_dim(0,i)
    temp1=temp1&vbcrlf&"<td>"&img_vclass&"c_id="&ncid&"'"
    if int(cid)=int(ncid) then
      temp1=temp1&" class=red"
      cname=s_dim(1,i)
    end if
    temp1=temp1&">"&s_dim(1,i)&"</td>"
    if (i+1) mod 2=0 then temp1=temp1&vbcrlf&"</tr>"
  next
  erase s_dim
  call video_bar_top("left_sort","视频分类")
  video_skin.HtmlNums(3)
  video_skin.HtmlRcod "nsorts",temp1
  video_skin.HtmlRcod "img_class",img_vclass
  video_skin.HtmlView(0)
  call video_bar_end()
end sub
'----------影院工具----------
sub video_tool()
  call video_bar_top("left_tool","视频工具")
  video_skin.HtmlNums(5)
  video_skin.HtmlView(0)
  call video_bar_end()
end sub
'----------影院说明----------
sub video_remark()
  call video_bar_top("left_remark","相关说明")
  video_skin.HtmlNums(6)
  video_skin.HtmlRcod "web_unit",joekoe_cms.web_unit
  video_skin.HtmlView(1)
  call video_bar_end()
end sub
'----------热门影片左栏调用----------
sub video_hot_left(hnum)
  call video_bar_top("left_hot","热点视频")
  call video_ishot(hnum,1)
  call video_bar_end()
end sub
'----------影片调用格式化----------
function video_view_body(n_num,v_id,v_counter,v_emoney,v_power,v_star,v_remark,v_lang,v_types,v_name,v_role,v_genre,v_pic)
  dim v_pics,v_urls
  v_pics=video_fk(v_pic,1,"video_view.asp?id="&v_id)
  v_urls="video_view.asp?id="&v_id
  video_skin.HtmlNums(7)
  video_skin.HtmlRcod "v_urls",v_urls
  video_skin.HtmlRcod "v_pics",v_pics
  video_skin.HtmlRcod "v_names",joekoe_cms.code_html(v_name,1,0)
  video_skin.HtmlRcod "v_name",joekoe_cms.code_html(v_name,1,n_num)
  video_skin.HtmlRcod "v_role",v_role
  video_skin.HtmlRcod "v_types",v_types
  video_skin.HtmlRcod "v_genre",genre_view(v_genre)
  video_skin.HtmlRcod "v_lang",v_lang
  video_skin.HtmlRcod "v_star",v_star
  video_skin.HtmlRcod "v_counter",v_counter
  video_skin.HtmlRcod "emoney_power",format_emoney_power(v_emoney,v_power,1)
  video_skin.HtmlRcod "v_remark",v_remark
  video_view_body=video_skin.HtmlGets(0)
end function

function video_hot(v_id,v_count,v_lang,v_type,v_name,v_pic)
  video_skin.HtmlNums(8)
  video_skin.HtmlRcod "hotpic",v_pic
  video_skin.HtmlRcod "v_id",v_id
  video_skin.HtmlRcod "v_name",joekoe_cms.code_html(v_name,1,0)
  video_skin.HtmlRcod "v_type",v_type
  video_skin.HtmlRcod "v_lang",v_lang
  video_skin.HtmlRcod "v_count",v_count
  video_hot=video_skin.HtmlGets(0)
end function
'----------图像边框------------
function video_fk(pvar,pt,purl)
  video_fk=pic_fk(pvar,pt,purl)
  'exit function
  dim gurl,turl
  gurl="images/fk/"
  turl=pic_url(pvar,pt)
  if purl<>"" and var_null(purl)<>"" then turl="<a href='"&purl&"' target=_blank>"&turl&"</a>"
  video_skin.HtmlNums(14)
  video_skin.HtmlRcod "burl",gurl
  video_skin.HtmlRcod "turl",turl
  video_fk=video_skin.HtmlGets(0)
end function
'----------影院推荐调用----------
'n_num 调用个数
'c_num 片名字数
'b_num 主演字数
't_num 简介字数
sub video_istop(n_num,c_num,b_num,t_num)
  dim types,role,remark
  response.write vbcrlf&"<tr valign=top><td width='30%'></td><td width='70%'></td></tr>"
  sql="select top "&n_num&" id,pic,name,types,star,counter,emoney,power,role,genre,lang,remark from video where star=5 and hidden=1 order by tim desc,id desc"
  set rs=joekoe_cms.exec(sql,1)
  do while not rs.eof
    types=rs("types")
    types=type_view(types)
    role=joekoe_cms.code_html(rs("role"),1,b_num)
    remark=joekoe_cms.code_html(rs("remark"),1,t_num)
    response.write vbcrlf&video_view_body(c_num,rs("id"),int(rs("counter")),int(rs("emoney")),rs("power"),int(rs("star")),remark,rs("lang"),types,rs("name"),role,rs("genre"),rs("pic"))
    rs.movenext
  loop
  rs.close
end sub
'----------热门影院调用----------
'n_num 调用个数
sub video_ishot(n_num,vs)
  dim name,types,hpic,tmp1,jpic
  hpic=""
  if vs=0 then
    hpic="<tr><td><img src='{$picurl}right_hot.gif' border=0></td></tr>"
  end if
  sql="select top "&n_num&" id,pic,name,types,counter,lang from video where hidden=1 order by counter desc,id desc"
  set rs=joekoe_cms.exec(sql,1)
  do while not rs.eof
    name=joekoe_cms.code_html(rs("name"),1,0)
    types=rs("types")
    types=type_view(types)
    jpic=video_fk(rs("pic"),5,"video_view.asp?id="&rs("id"))
	tmp1=tmp1&video_hot(rs("id"),rs("counter"),rs("lang"),types,name,jpic)
    rs.movenext
  loop
  rs.close
  video_skin.HtmlNums(9)
  video_skin.HtmlRcod "hotpic",hpic
  video_skin.HtmlRcod "body",tmp1
  video_skin.HtmlView(0)
end sub
'----------错误提示----------
sub video_error(errs)
  dim tmp1
  select case errs
  case "nodown"
    tmp1="影片下载出错：\n\n此影片没有提供下载服务！"
  case "noplay"
    tmp1="影片观看出错：\n\n此影片没有提供在线观看服务！"
  case "nopost"
    tmp1="影片下载出错：\n\n请不要使用WebZip、Teleport这类软件下载本站数据；\n也不要使用googlebot这类浏览器浏览本站；\n\n请更改浏览器或停止非法操作后再访问本站，谢谢。"
  case "nopower"
    tmp1="影片下载出错：\n\n您没有足够的权限或钱币进行刚才的操作！\n\n也可能您还没有注册和登陆本站。"
  case else
    tmp1="错误的ID参数：\n\n您勿向本站提交非法信息！"
  end select
  response.write joekoe_cms.js_put("alert("""&tmp1&""");window.close();",1)
  if not isnull(session("play_video_url")) then session.Contents.Remove("play_video_url")
  call video_end()
  call web_clear(1)
end sub

function genre_view(vg)
	select case lcase(vg)
	case "real"
	  genre_view="<img src='"&pic_dir&"ico_rp.gif' border=0 align=absmiddle alt='Real Player 格式'>"
	case "qt"
	  genre_view="<img src='"&pic_dir&"ico_mov.gif' border=0 align=absmiddle alt='Quick Time 格式'>"
	case else
	  genre_view="<img src='"&pic_dir&"ico_wmp.gif' border=0 align=absmiddle alt='Media Player 格式'>"
	end select
end function

function type_view(tv)
    select case lcase(tv)
    case "music"
      type_view="歌曲"
    case "mtv"
      type_view="MTV"
    case else
      type_view="影片"
    end select
end function
%>