sql server200一个实现分页显示的存储过程.txt

一个MS SQLServer2000的存储过程

/******************************************************************************\
创建日期: 2005-10-13
修改历史: 
2005-10-18 修改对于@Sort 中无法处理 "ASC" 的情况;
2005-10-18 修改对于@Sort , @Tables 中带 owner 无法处理 的情况;
2005-10-18 修改对于多表情况下@Sort 中不带 表名 无法处理 的情况;
2005-10-18 修改对于@Sort 中有计算域  无法处理 数据类型的情况, 而加入参数 @SortType;
2005-10-20 修改对于计算域的SELECT 问题；


\******************************************************************************/
CREATE PROCEDURE Paging_RowCount
	(
	@Tables varchar(1000),
	@PK varchar(100),
	@Sort varchar(200) = NULL,
	@SortType varchar(200) = NULL,
	@PageNumber int = 1,
	@PageSize int = 10,
	@Fields varchar(1000) = '*',
	@Filter varchar(1000) = NULL,
	@Group varchar(1000) = NULL/*,
	@TotalPage int OUTPUT*/)
AS

/*Default Sorting*/
IF (@Sort IS NULL OR @Sort = '') SET @Sort = @PK

/*Find the @PK type*/
DECLARE @SortTable		varchar(100)
DECLARE @SortName		varchar(100)

DECLARE @SortTableOwner	varchar(100) --排序表的 Owner
DECLARE @Temp		varchar(200) --临时

DECLARE @strSortColumn	varchar(200)
DECLARE @operator		char(2)
DECLARE @type		varchar(100)
DECLARE @prec		int

/*Set sorting variables.*/ 
IF CHARINDEX('DESC',@Sort)>0
 BEGIN
	SET @strSortColumn = REPLACE(@Sort, ' DESC', '')
	SET @operator = '<='
 END
ELSE
 BEGIN
	IF (CHARINDEX('ASC', @Sort)> 0) SET @strSortColumn = REPLACE(@Sort, ' ASC', '')
	ELSE  SET @strSortColumn = @Sort
	SET @operator = '>='
 END


IF CHARINDEX('.', @strSortColumn) > 0
  BEGIN
	IF CHARINDEX('.', SUBSTRING(@strSortColumn, CHARINDEX('.',@strSortColumn) + 1, LEN(@strSortColumn))) > 0
	  BEGIN
		SET @Temp = SUBSTRING(@strSortColumn, CHARINDEX('.',@strSortColumn) + 1, LEN(@strSortColumn))
		SET @SortTable = SUBSTRING(@Temp, 0, CHARINDEX('.',@Temp))
		SET @SortName = SUBSTRING(@Temp, CHARINDEX('.',@Temp) + 1, LEN(@Temp))
		SET @SortTableOwner = SUBSTRING(@strSortColumn, 0, CHARINDEX('.',@strSortColumn));
	  END
	ELSE
	  BEGIN
		SET @SortTable = SUBSTRING(@strSortColumn, 0, CHARINDEX('.',@strSortColumn))
		SET @SortName = SUBSTRING(@strSortColumn, CHARINDEX('.',@strSortColumn) + 1, LEN(@strSortColumn))
		SET @SortTableOwner = '';
	  END
  END
ELSE
  BEGIN
	IF CHARINDEX('.', @Tables) > 0
	  BEGIN
		SET @SortTable = SUBSTRING(@Tables, CHARINDEX('.',@Tables) + 1, LEN(@Tables))
	  END
	ELSE
	  BEGIN
		SET @SortTable = @Tables
	  END
	SET @SortName = @strSortColumn
	SET @SortTableOwner = '';
  END

IF (@SortType IS NULL OR @SortType = '') 
  BEGIN
	SELECT @type=t.name, @prec=c.prec
	FROM sysobjects o 
		JOIN syscolumns c on o.id=c.id
		JOIN systypes t on c.xusertype=t.xusertype
		JOIN sysusers u on o.uid=u.uid
	WHERE o.name = @SortTable AND c.name = @SortName
		AND u.name = case @SortTableOwner when '' then u.name else @SortTableOwner end
	
	IF (CHARINDEX('char', @type) > 0)  SET @type = @type + '(' + CAST(@prec AS varchar) + ')';
  END
ELSE SET @type = @SortType;

DECLARE @strPageSize varchar(50)
DECLARE @strStartRow varchar(50)
DECLARE @strFilter varchar(1000)
DECLARE @strSimpleFilter varchar(1000)
DECLARE @strGroup varchar(1000)

/*Default Page Number*/
IF @PageNumber < 1
 SET @PageNumber = 1

/*Set paging variables.*/
SET @strPageSize = CAST(@PageSize AS varchar(50))
SET @strStartRow = CAST(((@PageNumber - 1)*@PageSize + 1) AS varchar(50))

/*Set filter & group variables.*/
IF @Filter IS NOT NULL AND @Filter != ''
 BEGIN
	SET @strFilter = ' WHERE ' + @Filter + ' '
	SET @strSimpleFilter = ' AND ' + @Filter + ' '
 END
ELSE
 BEGIN
	SET @strSimpleFilter = ''
	SET @strFilter = ''
 END
IF @Group IS NOT NULL AND @Group != ''
	SET @strGroup = ' GROUP BY ' + @Group + ' '
ELSE
	SET @strGroup = ''
/*Execute dynamic query*/ 
IF (@SortType IS NULL OR @SortType = '') 
	EXEC(
	'
	DECLARE @SortColumn ' + @type + '
	SET ROWCOUNT ' + @strStartRow + '
	SELECT @SortColumn=' + @strSortColumn + ' FROM ' + @Tables + @strFilter + ' ' + @strGroup + ' ORDER BY ' + @Sort + '
	SET ROWCOUNT ' + @strPageSize + '
	SELECT ' + @Fields + ' FROM ' + @Tables + ' WHERE ' + @strSortColumn + @operator + ' @SortColumn ' + @strSimpleFilter + ' ' + @strGroup + ' ORDER BY ' + @Sort + '
	'
	)
ELSE
	EXEC(
	'
	DECLARE @SortColumn ' + @type + '
	SET ROWCOUNT ' + @strStartRow + '
	SELECT @SortColumn=' + @strSortColumn + ' FROM ' + @Tables + @strFilter + ' ' + @strGroup + ' ORDER BY ' + @Sort + '
	SET ROWCOUNT ' + @strPageSize + '
	SELECT ' + @Fields + ' FROM ' + @Tables + ' WHERE 1=1 ' + @strSimpleFilter + ' ' + @strGroup +  ' HAVING ' + @strSortColumn + @operator + ' @SortColumn '+ ' ORDER BY ' + @Sort + '
	'
	)
GO