sendmail.asp

来自「一个完全仿照阿里巴巴的网站管理系统 本软件没有版权问题」· ASP 代码 · 共 63 行

<%
Dim sendmail

Sub Jmail(Email,Topic,Mailbody)
	On Error Resume Next
	Dim JMail
	Set JMail = Server.CreateObject("JMail.Message")
	JMail.silent=true
	JMail.Logging = True
	JMail.Charset = "gb2312"
	JMail.MailServerUserName = SMT_citysendmail(1) '您的邮件服务器登录名
	JMail.MailServerPassword = SMT_citysendmail(2) '登录密码
	JMail.Priority = 1
	JMail.From = citymail
	JMail.FromName = cityname
	JMail.AddRecipient Email
	JMail.Subject = Topic
	JMail.Body = Mailbody
    JMail.MailDomain = SMT_citysendmail(3)
	JMail.Send (SMT_citysendmail(0))
	Set JMail = Nothing
	sendmail="OK"
	If Err Then sendmail="False"
End Sub
	
Sub Cdonts(Email,Topic,Mailbody)
	On Error Resume Next
	Dim ObjCDOMail
	Set ObjCDOMail = Server.CreateObject("CDONTS.NewMail")
	ObjCDOMail.From = citymail
	ObjCDOMail.To = Email
	ObjCDOMail.Subject = Topic
	ObjCDOMail.BodyFormat = 0 
	ObjCDOMail.MailFormat = 0 
	ObjCDOMail.Body = Mailbody
	ObjCDOMail.Send
	Set ObjCDOMail = Nothing
	sendmail="OK"
	If Err Then sendmail="False"
End Sub

Sub AspEmail(Email,Topic,Mailbody)
	On Error Resume Next
	Dim Mailer
	Set Mailer = Server.CreateObject("Persits.MailSender")
	Mailer.Charset = "gb2312"
	Mailer.IsHTML = False
	Mailer.username = SMT_citysendmail(1)	'服务器上有效的用户名
	Mailer.password = SMT_citysendmail(2)	'服务器上有效的密码
	Mailer.Priority = 1
	Mailer.Host = SMT_citysendmail(0)
	Mailer.Port = 25 ' 该项可选.端口25是默认值
	Mailer.From = citymail
	Mailer.FromName = cityname ' 该项可选
	Mailer.AddAddress Email,Email
	Mailer.Subject = Topic
	Mailer.Body = Mailbody
	Mailer.Send
	Set Mailer = Nothing
	sendmail="OK"
	If Err Then sendmail="False"
End Sub
%>