getconnhandle.prg

固定资产管理系统源码..用于企业资产管理,用VFP编码

LOCAL lnSQLState AS Integer,lcConnString AS String
*!* 检查连接是否有效
TRY 
    IF VARTYPE(_SCREEN.ConnectHandle)=="U"
        _SCREEN.AddProperty("ConnectHandle")
    ENDIF 
    lnSQLState=SQLEXEC(_SCREEN.ConnectHandle,"")
CATCH 
    lnSQLState=-1
ENDTRY 

*!* 如果lnSQLState无效则重新连接
IF lnSQLState<1
    =SQLSETPROP(0,"DispLogin",3)
    IF FILE("Connect.XML")
        TRY 
            =XMLTOCURSOR("Connect.XML","curConnect",512)
            lcConnString="Driver="+ALLTRIM(curConnect.Driver)+";"+;
                     "Server="+ALLTRIM(curConnect.Server)+";"+;
                     "UID="+ALLTRIM(curConnect.UID)+";"+;
                     "PWD="+ALLTRIM(curConnect.PWD)+";"+;
                     "Database="+ALLTRIM(curConnect.Database)+";"+;
                     "Trusted_Connection="+ALLTRIM(curConnect.Trusted)
            
        CATCH 
            =MESSAGEBOX("读取连接信息出错，请检查Connect.XML文件是否正确！",0+48,"提示")
            RETURN -1
        ENDTRY 
        _SCREEN.ConnectHandle=SQLSTRINGCONNECT(lcConnString)
    ELSE 
        =MESSAGEBOX("未找到连接配置文件Connect.XML，请与系统管理人员联系！",0+48,"提示")
        _SCREEN.ConnectHandle=0
    ENDIF 
ENDIF

IF _SCREEN.ConnectHandle<0
    =AERROR(aArray)
    =MESSAGEBOX("数据连接错误！错误信息如下："+CHR(13)+CHR(10)+aArray[2],0+48,"提示")
ENDIF 

IF USED("curConnect")
    USE IN curConnect
ENDIF 
RETURN _SCREEN.ConnectHandle