formdepartment.pas

Delphi数据库编程

unit FormDepartment;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs,
  Grids, DBGrids, DB, DBTables, StdCtrls, DBCtrls, Mask, ExtCtrls;

type
  TfrmDepartment = class(TForm)
    dbgDepart: TDBGrid;
    btnQuit: TButton;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    dbeDepartID: TDBEdit;
    dbeDepartName: TDBEdit;
    dbeHead: TDBEdit;
    dbeTelephone: TDBEdit;
    dbmDesc: TDBMemo;
    dsDepart: TDataSource;
    tblDepart: TTable;
    GroupBox1: TGroupBox;
    dbnDepart: TDBNavigator;
    tblValid: TTable;
    procedure FormShow(Sender: TObject);
    procedure btnQuitClick(Sender: TObject);
    procedure tblDepartAfterScroll(DataSet: TDataSet);
    procedure tblDepartBeforePost(DataSet: TDataSet);
    procedure tblDepartBeforeDelete(DataSet: TDataSet);
    procedure dbnDepartClick(Sender: TObject; Button: TNavigateBtn);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    function HasClass(var str: string): Boolean;
    procedure ToggleMode;
  public
    { Public declarations }
  end;

var
  frmDepartment: TfrmDepartment;

implementation

{$R *.dfm}

procedure TfrmDepartment.FormShow(Sender: TObject);
begin
  tblDepart.Active := true;
end;

procedure TfrmDepartment.btnQuitClick(Sender: TObject);
begin
  Close;
end;

procedure TfrmDepartment.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  tblDepart.Active := false;
end;

procedure TfrmDepartment.dbnDepartClick(Sender: TObject; Button: TNavigateBtn);
begin
  ToggleMode;
end;

procedure TfrmDepartment.tblDepartAfterScroll(DataSet: TDataSet);
begin
  ToggleMode;
end;

function TfrmDepartment.HasClass(var str: string): Boolean;
begin
  Result := false;
  tblValid.Active := false;
  tblValid.TableName := 'Class';
  tblValid.Filter := 'DepartID=''' + tblDepart['DepartID'] + '''';
  tblValid.Filtered := true;
  tblValid.Active := true;
  if not tblValid.Eof then
  begin
    str := Format('不能修改院系“%s”的编号, 下面的班级：'#13, [tblDepart['DepartName']]);
    repeat
      str := str + Format('%10s - %s'#13, [tblValid['ClassID'], tblValid['ClassName']]);
      tblValid.Next;
    until tblValid.Eof;
    str := str + '隶属于该院系。';
    Result := true;
  end;
  tblValid.Active := false;
end;

procedure TfrmDepartment.ToggleMode;
var
  strMsg: string;

  procedure EnableInput(Enabled: Boolean);
  begin
    dbgDepart.Enabled := not Enabled;
    dbeDepartID.Enabled := Enabled;
    dbeDepartName.Enabled := Enabled;
    dbeHead.Enabled := Enabled;
    dbeTelephone.Enabled := Enabled;
    dbmDesc.Enabled := Enabled;
  end;
begin
  case tblDepart.State of
    dsInsert, dsEdit:
      begin
        EnableInput(true);
        dbnDepart.VisibleButtons := [nbPost, nbCancel];
        dbeDepartID.SetFocus;
      end;
  else
    EnableInput(false);
    dbnDepart.VisibleButtons := [nbFirst, nbPrior, nbNext, nbLast,
      nbInsert, nbDelete, nbEdit, nbPost, nbCancel, nbRefresh];
  end;

  if (tblDepart.State = dsEdit) and HasClass(strMsg) then
  begin
    ShowMessage(strMsg);
    dbeDepartID.Enabled := false;
  end;
end;

procedure TfrmDepartment.tblDepartBeforeDelete(DataSet: TDataSet);
var
  strMsg: string;
begin
  if HasClass(strMsg) then
  begin
    ShowMessage(strMsg);
    Abort;
  end;

  strMsg := Format('确定要删除院系"%s"吗？该院系相关信息如下：'#13, [tblDepart['DepartName']]);
  strMsg := strMsg + Format('  院系编号：%s'#13, [tblDepart['DepartID']]);
  strMsg := strMsg + Format('  院系名称：%s'#13, [tblDepart['DepartName']]);
  strMsg := strMsg + Format('  院系领导：%s'#13, [tblDepart['DepartHead']]);
  if MessageDlg(strMsg, mtConfirmation, [mbYes, mbNo], 0) <> mrYes then
    Abort;
end;

procedure TfrmDepartment.tblDepartBeforePost(DataSet: TDataSet);
  procedure CheckField(FieldName, FieldDesc: string; dbText: TCustomEdit; NotEmpty: Boolean);
  begin
    dbText.Text := Trim(dbText.Text);
    dbText.Text := StringReplace(dbText.Text, '''', '', [rfReplaceAll]);
    dbText.Text := StringReplace(dbText.Text, ' ', '', [rfReplaceAll]);
    if NotEmpty and (dbText.Text = '') then
    begin
      ShowMessageFmt('“%s”不能为空，请输入足够的信息！', [FieldDesc]);
      dbText.SetFocus;
      Abort;
    end
    else
      tblDepart.FieldByName(FieldName).AsString := dbText.Text;
  end;

  function ValidID: Boolean;
  var
    strMsg: string;
  begin
    Result := true;
    tblValid.Active := false;
    tblValid.TableName := 'Department';
    tblValid.Filter := 'DepartID=''' + tblDepart['DepartID'] + '''';
    tblValid.Filtered := true;
    tblValid.Active := true;
    if not tblValid.Eof then
    begin
      strMsg := Format('院系编号“%s”已经存在，请重新输入!'#13, [tblDepart['DepartID']]);
      strMsg := strMsg + Format('  院系编号：%s'#13, [tblValid['DepartID']]);
      strMsg := strMsg + Format('  院系名称：%s'#13, [tblValid['DepartName']]);
      strMsg := strMsg + Format('  院系领导：%s'#13, [tblValid['DepartHead']]);
      ShowMessage(strMsg);
      dbeDepartID.SetFocus;
      Result := false;
    end;
    tblValid.Active := false;
  end;
begin
  CheckField('DepartID', '院系编号', dbeDepartID, true);
  CheckField('DepartName', '院系名称', dbeDepartName, true);
  CheckField('DepartHead', '院系负责人', dbeHead, true);
  CheckField('Telephone', '联系电话', dbeTelephone, true);
  CheckField('Description', '说明', dbmDesc, false);

  if dbeDepartID.Modified and not ValidID then
    Abort;
end;

end.