📄 img05.asp

📁 ASPTest 网络基础网页设计
💻 ASP
字号:
<html>

<head>
<title>输出曲线</title>
</head>

<body>

<!-- #include file="imgVar.asp" -->

<%
Dim img   
Set img = Server.CreateObject("myImage.Image")
img.width = xLeft+xRight+xNum*xWidth   '图形总宽=x轴总长+左部空白+右部空白
img.height = yTop+yNum*yWidth+yButtom  '图形总高=y轴总长+上部空白+下部空白
img.Clear img.RGB(255,255,255)         '设置图形颜色为白色

'设定画笔颜色
img.PenColor = img.clBlack

 '建立Y轴
img.Line xLeft,yTop-20,xLeft,yTop+yNum*yWidth
   
'Y轴小箭头
img.Line xLeft-0.5,yTop-20,xleft-5.5,yTop-10
img.Line xLeft+0.5,yTop-20,xleft+5.5,yTop-10
   
'建立X轴
img.Line xLeft,yTop+yNum*yWidth,xLeft+xWidth*xNum+20,yTop+yNum*yWidth
   
'X轴小箭头
img.Line xLeft+xWidth*xNum+20,yTop+yNum*yWidth-0.5,xLeft+xWidth*xNum+10,_
   yTop+yNum*yWidth-5.5
img.Line xLeft+xWidth*xNum+20,yTop+yNum*yWidth+0.5,xLeft+xWidth*xNum+10,_
   yTop+yNum*yWidth+5.5

'间隔为yWidth在横向上画yNum条直线
For i = yTop To yTop+yNum*yWidth Step yWidth
  img.Line xLeft,i,xLeft+xWidth*xNum,i
Next
   
'间隔为xWidth在纵向上画xNum条直线
For i = xLeft To xLeft+xNum*xWidth Step xWidth 
  img.Line i,yTop,i,yTop+yNum*yWidth
Next

'定义字体大小
img.FontSize = 8
img.FontColor = img.clBlack

'定义x轴最大值、最小值；定义y轴最大值、最小值
yMax = 9
yMin = 0
xMax = 23
xMin = 0

'写入横坐标刻度
For i = xMin To xMax  
  If i < 10 Then 
   strTemp = "0"&i
  Else 
    strTemp = i
  End If 
  img.TextOut i*xWidth*2+XLeft-6,yTop+yNum*yWidth+5,strTemp
Next
      
'写入横坐标单位
img.TextOut xLeft+xWidth*xNum+2,yTop+yNum*yWidth-20,"单位："&xUnit
     
'写入纵坐标刻度
yIncrement = (yMax*1.1-yMin*0.9)/yNum   
for i=yTop+yWidth*yNum-6 to yTop-6 step -yWidth  
  strTemp = CStr(Clng(yMax*1.1-((i+6)-yTop)/yWidth*yIncrement))
  img.DrawText 1,i,xLeft-10,i+15,strTemp,img.daRight
next
      
'写入纵坐标单位
img.TextOut 1,1,"单位："&yUnit

'定义三个曲线的说明字段
strDate1 = "第一天"
strDate2 = "第二天"
strDate3 = "第三天"

'输出时间标志字符串
img.FontSize = 8
img.FontColor = img.clRed
img.TextOut xLeft+xNum*xWidth+4,yTop+10,strDate1
img.FontColor = img.clBlue
img.TextOut xLeft+xNum*xWidth+4,yTop+40,strDate2
img.FontColor = img.clGreen
img.TextOut xLeft+xNum*xWidth+4,yTop+70,strDate3

'输出图片标题
strTitle = "日48点数据曲线图"
img.FontColor = img.clBlack
img.FontSize = 12
img.DrawText xLeft,10,xLeft+xWidth*xNum,30,strTitle,img.daCenter

'将三个数据数组赋值，在实际应用中，可由数据库中查询的数据对其赋值
For i = 1 To 48
  yArray1(i) = 7.5
  yArray2(i) = 5.5
  yArray3(i) = 3.5
Next

'设置第一条数据线为红色并输出
img.ClearPoint
For i = 1 To xNum
  img.SetPoint xLeft+(i-1)*xWidth,_
    yTop+yNum*yWidth-(yArray1(i)-yMin*0.9)*yWidth/yIncrement
Next
img.PenColor=img.clRed  
img.PolyLine

'设置第二条数据线为蓝色并输出
img.ClearPoint
For i = 1 To xNum
  img.SetPoint xLeft+(i-1)*xWidth,_
    yTop+yNum*yWidth-(yArray2(i)-yMin*0.9)*yWidth/yIncrement
Next
img.PenColor = img.clBlue  
img.PolyLine

'设置第三条数据线为绿色并输出
img.ClearPoint
For i = 1 To xNum
  img.SetPoint xLeft+(i-1)*xWidth,_
    yTop+yNum*yWidth-(yArray3(i)-yMin*0.9)*yWidth/yIncrement
Next
img.PenColor = img.clGreen  
img.PolyLine

img.JPEGQuality = 100
Response.BinaryWrite img.JPEGImage
Set img = Nothing
%>

</body>

</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -