两组判别m2.bas

<VB数理统计实用算法>书中的算法源程序

Attribute VB_Name = "modMethod"
'两组判别
Option Explicit
'全主元高斯-约当消去法求逆矩阵
'A(1 To m, 1 To m)：开始存放欲求逆的矩阵，最终存求逆的结果矩阵，m是自变量个数
Public Sub Invert(a() As Double)
    Dim n As Integer, ep As Double
    Dim I As Integer, J As Integer, K As Integer
    Dim I0 As Integer, J0 As Integer
    Dim w As Double, z As Double
    Dim b(1 To 100) As Double, c(1 To 100) As Double
    Dim p(1 To 100) As Double, Q(1 To 100) As Double
    n = UBound(a, 1)
    ep = 0.0000000001
    For K = 1 To n
        w = 0#
        For I = K To n
            For J = K To n
                If Abs(a(I, J)) > Abs(w) Then
                    w = a(I, J): I0 = I: J0 = J
                End If
            Next J
        Next I
        If Abs(w) < ep Then
            MsgBox "全主元素的绝对值小于0.0000000001，矩阵是奇异的！"
            Exit Sub
        End If
        If I0 <> K Then
            For J = 1 To n
                z = a(I0, J): a(I0, J) = a(K, J): a(K, J) = z
            Next J
        End If
        If J0 <> K Then
            For I = 1 To n
                z = a(I, J0): a(I, J0) = a(I, K): a(I, K) = z
            Next I
        End If
        p(K) = I0: Q(K) = J0
        For J = 1 To n
            If J = K Then
                b(J) = 1 / w: c(J) = 1
            Else
                b(J) = -a(K, J) / w: c(J) = a(J, K)
            End If
            a(K, J) = 0#: a(J, K) = 0#
        Next J
        For I = 1 To n
            For J = 1 To n
                a(I, J) = a(I, J) + c(I) * b(J)
            Next J
        Next I
    Next K
    For K = n To 1 Step -1
        I0 = p(K): J0 = Q(K)
        If I0 <> K Then
            For I = 1 To n
                z = a(I, I0): a(I, I0) = a(I, K): a(I, K) = z
            Next I
        End If
        If J0 <> K Then
            For J = 1 To n
                z = a(J0, J): a(J0, J) = a(K, J): a(K, J) = z
            Next J
        End If
    Next K
End Sub

'求正态分布的分位数
'Q：上侧概率
'x：分位数
Public Sub PNorm(Q, X)
    Dim p As Double, Y As Double, z As Double
    Dim b0 As Double, b1 As Double, b2 As Double
    Dim b3 As Double, b4 As Double, b5 As Double
    Dim b6 As Double, b7 As Double, b8 As Double
    Dim b9 As Double, b10 As Double, b As Double
    b0 = 1.570796288: b1 = 0.03706987906
    b2 = -0.0008364353589: b3 = -0.0002250947176
    b4 = 0.000006841218299: b5 = 0.000005824238515
    b6 = -0.00000104527497: b7 = 8.360937017E-08
    b8 = -3.231081277E-09: b9 = 3.657763036E-11
    b10 = 6.936233982E-13
    If Q = 0.5 Then
        X = 0: GoTo PN01
    End If
    If Q > 0.5 Then p = 1 - Q Else p = Q
    Y = -Log(4 * p * (1 - p))
    b = Y * (b9 + Y * b10)
    b = Y * (b8 + b): b = Y * (b7 + b)
    b = Y * (b6 + b): b = Y * (b5 + b)
    b = Y * (b4 + b): b = Y * (b3 + b)
    b = Y * (b2 + b): b = Y * (b1 + b)
    z = Y * (b0 + b): X = Sqr(z)
    If Q > 0.5 Then X = -X
PN01:
End Sub

'计算F分布的分布函数
'n1：自由度，已知
'n2：自由度，已知
'F：F值，已知
'p：下侧概率，所求
'd：概率密度，所求
Public Sub F_DIST(N1 As Integer, N2 As Integer, F As Double, _
            p As Double, D As Double)
    Dim X As Double, U As Double, Lu As Double
    Dim IAI As Integer, IBI As Integer, nn1 As Integer, nn2 As Integer
    Dim I As Integer
    Const PI As Double = 3.14159265359
    If F = 0 Then
        p = 0: D = 0: Exit Sub
    End If
    X = N1 * F / (N2 + N1 * F)
    If (N1 \ 2) * 2 = N1 Then
        If (N2 \ 2) * 2 = N2 Then
            U = X * (1 - X): p = X: IAI = 2: IBI = 2
        Else
            U = X * Sqr(1 - X) / 2: p = 1 - Sqr(1 - X): IAI = 2: IBI = 1
        End If
    Else
        If (N2 \ 2) * 2 = N2 Then
            p = Sqr(X): U = p * (1 - X) / 2: IAI = 1: IBI = 2
        Else
            U = Sqr(X * (1 - X)) / PI
            p = 1 - 2 * Atn(Sqr((1 - X) / X)) / PI: IAI = 1: IBI = 1
        End If
    End If
    nn1 = N1 - 2: nn2 = N2 - 2
    If U = 0 Then
        D = U / F
        Exit Sub
    Else
        Lu = Log(U)
    End If
    If IAI = N1 Then GoTo LL1
    For I = IAI To nn1 Step 2
        p = p - 2 * U / I
        Lu = Lu + Log((1 + IBI / I) * X)
        U = Exp(Lu)
    Next I
LL1:
    If IBI = N2 Then
        D = U / F: Exit Sub
    End If
    For I = IBI To nn2 Step 2
        p = p + 2 * U / I
        Lu = Lu + Log((1 + N1 / I) * (1 - X))
        U = Exp(Lu)
    Next I
    D = U / F
End Sub

'计算F分布的分位数
'n1：自由度，已知
'n2：自由度，已知
'Q：上侧概率，已知
'F：分位数，所求
Public Sub PF_DIST(N1 As Integer, N2 As Integer, _
                Q As Double, F As Double)
    Dim DF12 As Double, DF22 As Double, a As Double, b As Double
    Dim A1 As Double, b1 As Double, p As Double, YQ As Double
    Dim E As Double, FO As Double, pp As Double, D As Double
    Dim GA1 As Double, GA2 As Double, GA3 As Double
    Dim K As Integer
    DF12 = N1 / 2: DF22 = N2 / 2
    a = 2 / (9 * N1): A1 = 1 - a
    b = 2 / (9 * N2): b1 = 1 - b
    p = 1 - Q: PNorm Q, YQ
    E = b1 * b1 - b * YQ * YQ
    If E > 0.8 Then
        FO = ((A1 * b1 + YQ * Sqr(A1 * A1 * b + a * E)) / E) ^ 3
    Else
        lnGamma DF12 + DF22, GA1
        lnGamma DF12, GA2
        lnGamma DF22, GA3
        FO = (2 / N2) * (GA1 - GA2 - GA3 + 0.69315 + (DF22 - 1) * Log(N2) _
            - DF22 * Log(N1) - Log(Q))
        FO = Exp(FO)
    End If
    For K = 1 To 30
        F_DIST N1, N2, FO, pp, D
        If D = 0 Then
            F = FO: Exit Sub
        End If
        F = FO - (pp - p) / D
        If Abs(FO - F) < 0.000001 * Abs(F) Then Exit Sub Else FO = F
    Next K
End Sub

'求Gamma函数的对数LogGamma(x)
'x：自变量
'G：Gamma函数的对数
Public Sub lnGamma(X As Double, G As Double)
    Dim Y As Double, z As Double, a As Double
    Dim b As Double, b1 As Double, n As Integer
    Dim I As Integer
    If X < 8 Then
        Y = X + 8: n = -1
    Else
        Y = X: n = 1
    End If
    z = 1 / (Y * Y)
    a = (Y - 0.5) * Log(Y) - Y + 0.9189385
    b1 = (0.0007663452 * z - 0.0005940956) * z
    b1 = (b1 + 0.0007936431) * z
    b1 = (b1 - 0.002777778) * z
    b = (b1 + 0.0833333) / Y
    G = a + b
    If n >= 0 Then Exit Sub
    Y = Y - 1: a = Y
    For I = 1 To 7
        a = a * (Y - I)
    Next I
    G = G - Log(a)
End Sub