二元多项式逐步回归m2.bas

<VB数理统计实用算法>书中的算法源程序

        YY = miY + DY * (I - 1)
        For J = 1 To N
            XX = miX + DX * (J - 1)
            NDS X, Y, Z, XX, YY, F, 3       '取3个点按距离加权插值
            G(I, J) = F - b(I, J)           '求残差
        Next J
    Next I
End Sub

'求正态分布的分位数
'Q：上侧概率
'x：分位数
Public Sub PNorm(Q, X)
    Dim p As Double, Y As Double, Z As Double
    Dim b0 As Double, b1 As Double, b2 As Double
    Dim b3 As Double, b4 As Double, b5 As Double
    Dim b6 As Double, b7 As Double, b8 As Double
    Dim b9 As Double, b10 As Double, b As Double
    b0 = 1.570796288: b1 = 0.03706987906
    b2 = -0.0008364353589: b3 = -0.0002250947176
    b4 = 0.000006841218299: b5 = 0.000005824238515
    b6 = -0.00000104527497: b7 = 8.360937017E-08
    b8 = -3.231081277E-09: b9 = 3.657763036E-11
    b10 = 6.936233982E-13
    If Q = 0.5 Then
        X = 0: GoTo PN01
    End If
    If Q > 0.5 Then p = 1 - Q Else p = Q
    Y = -Log(4 * p * (1 - p))
    b = Y * (b9 + Y * b10)
    b = Y * (b8 + b): b = Y * (b7 + b)
    b = Y * (b6 + b): b = Y * (b5 + b)
    b = Y * (b4 + b): b = Y * (b3 + b)
    b = Y * (b2 + b): b = Y * (b1 + b)
    Z = Y * (b0 + b): X = Sqr(Z)
    If Q > 0.5 Then X = -X
PN01:
End Sub

'计算F分布的分布函数
'n1：自由度，已知
'n2：自由度，已知
'F：F值，已知
'p：下侧概率，所求
'd：概率密度，所求
Public Sub F_DIST(n1 As Integer, n2 As Integer, F As Double, _
            p As Double, D As Double)
    Dim X As Double, U As Double, Lu As Double
    Dim IAI As Integer, IBI As Integer, nn1 As Integer, nn2 As Integer
    Dim I As Integer
    Const PI As Double = 3.14159265359
    If F = 0 Then
        p = 0: D = 0: Exit Sub
    End If
    X = n1 * F / (n2 + n1 * F)
    If (n1 \ 2) * 2 = n1 Then
        If (n2 \ 2) * 2 = n2 Then
            U = X * (1 - X): p = X: IAI = 2: IBI = 2
        Else
            U = X * Sqr(1 - X) / 2: p = 1 - Sqr(1 - X): IAI = 2: IBI = 1
        End If
    Else
        If (n2 \ 2) * 2 = n2 Then
            p = Sqr(X): U = p * (1 - X) / 2: IAI = 1: IBI = 2
        Else
            U = Sqr(X * (1 - X)) / PI
            p = 1 - 2 * Atn(Sqr((1 - X) / X)) / PI: IAI = 1: IBI = 1
        End If
    End If
    nn1 = n1 - 2: nn2 = n2 - 2
    If U = 0 Then
        D = U / F
        Exit Sub
    Else
        Lu = Log(U)
    End If
    If IAI = n1 Then GoTo LL1
    For I = IAI To nn1 Step 2
        p = p - 2 * U / I
        Lu = Lu + Log((1 + IBI / I) * X)
        U = Exp(Lu)
    Next I
LL1:
    If IBI = n2 Then
        D = U / F: Exit Sub
    End If
    For I = IBI To nn2 Step 2
        p = p + 2 * U / I
        Lu = Lu + Log((1 + n1 / I) * (1 - X))
        U = Exp(Lu)
    Next I
    D = U / F
End Sub

'计算F分布的分位数
'n1：自由度，已知
'n2：自由度，已知
'Q：上侧概率，已知
'F：分位数，所求
Public Sub PF_DIST(n1 As Integer, n2 As Integer, _
                Q As Double, F As Double)
    Dim DF12 As Double, DF22 As Double, a As Double, b As Double
    Dim A1 As Double, b1 As Double, p As Double, YQ As Double
    Dim E As Double, FO As Double, pp As Double, D As Double
    Dim GA1 As Double, GA2 As Double, GA3 As Double
    Dim K As Integer
    DF12 = n1 / 2: DF22 = n2 / 2
    a = 2 / (9 * n1): A1 = 1 - a
    b = 2 / (9 * n2): b1 = 1 - b
    p = 1 - Q: PNorm Q, YQ
    E = b1 * b1 - b * YQ * YQ
    If E > 0.8 Then
        FO = ((A1 * b1 + YQ * Sqr(A1 * A1 * b + a * E)) / E) ^ 3
    Else
        lnGamma DF12 + DF22, GA1
        lnGamma DF12, GA2
        lnGamma DF22, GA3
        FO = (2 / n2) * (GA1 - GA2 - GA3 + 0.69315 + (DF22 - 1) * Log(n2) _
            - DF22 * Log(n1) - Log(Q))
        FO = Exp(FO)
    End If
    For K = 1 To 30
        F_DIST n1, n2, FO, pp, D
        If D = 0 Then
            F = FO: Exit Sub
        End If
        F = FO - (pp - p) / D
        If Abs(FO - F) < 0.000001 * Abs(F) Then Exit Sub Else FO = F
    Next K
End Sub

'计算GAMMA函数
'x：自变量
'z：GAMMA函数值
Public Sub GAMMA(X As Double, Z As Double)
    Dim H As Double, Y As Double, y1 As Double
    H = 1: Y = X
LL1:
    If Y = 2 Then
        Z = H
        Exit Sub
    ElseIf Y < 2 Then
        H = H / Y: Y = Y + 1: GoTo LL1
    ElseIf Y >= 3 Then
        Y = Y - 1: H = H * Y: GoTo LL1
    End If
    Y = Y - 2
    y1 = Y * (0.005159 + Y * 0.001606)
    y1 = Y * (0.004451 + y1)
    y1 = Y * (0.07211 + y1)
    y1 = Y * (0.082112 + y1)
    y1 = Y * (0.41174 + y1)
    y1 = Y * (0.422787 + y1)
    H = H * (0.999999 + y1)
    Z = H
End Sub

'求Gamma函数的对数LogGamma(x)
'x：自变量
'G：Gamma函数的对数
Public Sub lnGamma(X As Double, G As Double)
    Dim Y As Double, Z As Double, a As Double
    Dim b As Double, b1 As Double, N As Integer
    Dim I As Integer
    If X < 8 Then
        Y = X + 8: N = -1
    Else
        Y = X: N = 1
    End If
    Z = 1 / (Y * Y)
    a = (Y - 0.5) * Log(Y) - Y + 0.9189385
    b1 = (0.0007663452 * Z - 0.0005940956) * Z
    b1 = (b1 + 0.0007936431) * Z
    b1 = (b1 - 0.002777778) * Z
    b = (b1 + 0.0833333) / Y
    G = a + b
    If N >= 0 Then Exit Sub
    Y = Y - 1: a = Y
    For I = 1 To 7
        a = a * (Y - I)
    Next I
    G = G - Log(a)
End Sub

'计算t分布的分布函数
'n：自由度，已知
'T：t值，已知
'pp：下侧概率，所求
'dd：概率密度，所求
Public Sub T_Dist(N As Integer, T As Double, pp As Double, dd As Double)
    Dim Sign As Integer, TT As Double, X As Double
    Dim p As Double, U As Double, GA1 As Double, GA2 As Double
    Dim IBI As Integer, n2 As Integer, I As Integer
    Const PI As Double = 3.14159265359
    If T = 0 Then
        Call GAMMA(N / 2, GA1): Call GAMMA(N / 2 + 0.5, GA2): pp = 0.5
        dd = GA2 / (Sqr(N * PI) * GA1): Exit Sub
    End If
    If T < 0 Then Sign = -1 Else Sign = 1
    TT = T * T: X = TT / (N + TT)
    If (N \ 2) * 2 = N Then                 'n为偶数
        p = Sqr(X): U = p * (1 - X) / 2
        IBI = 2
    Else                                    'n为奇数
        U = Sqr(X * (1 - X)) / PI
        p = 1 - 2 * Atn(Sqr((1 - X) / X)) / PI
        IBI = 1
    End If
    If IBI = N Then GoTo LL1 Else n2 = N - 2
    For I = IBI To n2 Step 2
        p = p + 2 * U / I
        U = U * (1 + I) / I * (1 - X)
    Next I
LL1:
    dd = U / Abs(T)
    pp = 0.5 + Sign * p / 2
End Sub

'求t分布的分位数
'n：自由度，已知
'Q：上侧概率（<=0.5），已知
'T：分位数，所求
Public Sub PT_DIST(N As Integer, Q As Double, T As Double)
    Dim PIS As Double, DFR2 As Double, C As Double
    Dim Q2 As Double, p As Double, YQ As Double, E As Double
    Dim GA1 As Double, GA2 As Double, GA3 As Double
    Dim T0 As Double, pp As Double, D As Double
    Dim K As Integer
    Const PI As Double = 3.14159265359
    PIS = Sqr(PI): DFR2 = N / 2
    If N = 1 Then
        T = Tan(PI * (0.5 - Q)): Exit Sub
    End If
    If N = 2 Then
        If Q > 0.5 Then C = -1 Else C = 1
        Q2 = (1 - 2 * Q) ^ 2
        T = Sqr(2 * Q2 / (1 - Q2)) * C
        Exit Sub
    End If
    p = 1 - Q: PNorm Q, YQ              '正态分布分位数
    E = (1 - 1 / (4 * N)) ^ 2 - YQ * YQ / (2 * N)
    If E > 0.5 Then
        T0 = YQ / Sqr(E)
    Else
        lnGamma DFR2, GA1: lnGamma DFR2 + 0.5, GA2
        GA3 = Exp((GA1 - GA2) / N)
        T0 = Sqr(N) / (PIS * Q * N) ^ (1 / N) / GA3
    End If
    For K = 1 To 30
        T_Dist N, T0, pp, D
        If D = 0 Then
            T = T0: Exit Sub
        End If
        T = T0 - (pp - p) / D
        If Abs(T0 - T) < 0.000001 * Abs(T) Then _
            Exit Sub Else T0 = T
    Next K
End Sub