iflash.lcf

COLDFIRE 5282SC的文件

#/*
# * File:		iflash.lcf
# * Purpose:	Linker file for the M5282EVB
# *
# * Notes:		Project running in external Flash
# *
# */

MEMORY 
{
	flash		(RWX)	: ORIGIN = 0x00000000, LENGTH = 0x00080000
	sdram		(RWX)	: ORIGIN = 0x10000000, LENGTH = 0x01000000
	sram		(RWX)	: ORIGIN = 0x20000000, LENGTH = 0x00010000
	vector_ram	(RWX)	: ORIGIN = 0x20000000, LENGTH = 0x00000400
	data_ram	(RWX)	: ORIGIN = 0x20000400, LENGTH = 0x0000FC00
	ext_sram	(RWX)	: ORIGIN = 0x30000000, LENGTH = 0x00080000
	ipsbar		(RWX)	: ORIGIN = 0x40000000, LENGTH = 0x40000000
	ext_flash	(RWX)	: ORIGIN = 0xFFE00000, LENGTH = 0x00200000
}

SECTIONS 
{
	.sdram		: {} > sdram
	.vector_ram	: {} > vector_ram
	.ipsbar		: {} > ipsbar
	.sram		: {} > sram
	.ext_sram	: {} > ext_sram
	.ext_flash	: {} > ext_flash
	
	.flash :
	{
		vectors.s (.text)
		*(.text)
		*(.rodata)
		. 				= ALIGN(0x10);
		___DATA_ROM		= .;
	} > flash	
		
	.data_ram : AT(___DATA_ROM)
	{
		___DATA_RAM		= .;
		*(.data)
		*(.sdata)
		___DATA_END		= .;
	} > data_ram

	.bss :
	{
		.				= ALIGN(0x10);
		___BSS_START	= .;
		*(.sbss)
		*(SCOMMON)
		*(.bss)
		*(COMMON)
		___BSS_END 		= .;

		.				= ALIGN(0x10);
		___HEAP_START	= .;
		.				= . + (32*1024);
		___HEAP_END		= .;
		___SP_END		= .;
		.				= . + (4*1024);
		___SP_INIT		= .;
	} >> data_ram
	
	___IPSBAR			= ADDR(.ipsbar);
	___VECTOR_RAM		= ADDR(.vector_ram);

	___SDRAM			= ADDR(.sdram);
	___SDRAM_SIZE		= 0x01000000;

	___SRAM				= ADDR(.sram);
	___SRAM_SIZE		= 0x00010000;

	___EXT_SRAM			= ADDR(.ext_sram);
	___EXT_SRAM_SIZE	= 0x00080000;

	___FLASH			= ADDR(.flash);
	___FLASH_SIZE		= 0x00080000;

	___EXT_FLASH		= ADDR(.ext_flash);
	___EXT_FLASH_SIZE	= 0x00200000;
}