kev75401_pwm_gnu_ram.ld

sharp s Lh75401 PWM audio的例子

 /*;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 
 ; $Workfile:   $ 
 ; $Revision:   1.0  $ 
 ; $Author:   AnvikE  $ 
 ; $Date:   Jun 24 2003 17:04:34  $ 
 ; 
 ; Project:     
 ; 
 ; Description: 
 ;  This file implements linker script for the KEV75401 evaluation
 ;  platform
 ; 
 ; Revision History: 
 ; $Log:				
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;  
 ; 
 ;  Copyright (c) 2002 Sharp Microelectronics of the Americas 
 ; 
 ;  All rights reserved 
 ; 
 ;  SHARP MICROELECTRONICS OF THE AMERICAS MAKES NO REPRESENTATION 
 ;  OR WARRANTIES WITH RESPECT TO THE PERFORMANCE OF THIS SOFTWARE, 
 ;  AND SPECIFICALLY DISCLAIMS ANY RESPONSIBILITY FOR ANY DAMAGES, 
 ;  SPECIAL OR CONSEQUENTIAL, CONNECTED WITH THE USE OF THIS SOFTWARE. 
 ; 
 ;  SHARP MICROELECTRONICS OF THE AMERICAS PROVIDES THIS SOFTWARE SOLELY 
 ;  FOR THE PURPOSE OF SOFTWARE DEVELOPMENT INCORPORATING THE USE OF A 
 ;  SHARP MICROCONTROLLER OR SYSTEM-ON-CHIP PRODUCT. USE OF THIS SOURCE 
 ;  FILE IMPLIES ACCEPTANCE OF THESE CONDITIONS. 
 ; 				
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;*/ 

/* Define the supported output formats - elf32-littlearm 
   is the default */
OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm",
	      "elf32-littlearm")

/* Define the target architecture */
OUTPUT_ARCH(arm)

/* Define the system entry point */
ENTRY(__reset)

/* Define the memory sections layout for the bsp 
   SECTION [address] [(type)] : [AT(LMA)] 
   {
	output-sections-command 
	output-sections-command 
   } [>region] [:phdr :phdr ...] [=fillexp] */

SECTIONS
	{
	/* Set up the location counter */
	. = 0x44000000 ;

	/* set up the text output section that starts at 0x48000000 */
	.text :
		{
		/* empty section required for interal symbols */
		}

	LR_FRAM 0x80000000 : 
		AT(ADDR(.text)+SIZEOF(.text))
		{
		__text_fram_start = .;
		__data_fram_start = .;
		__bss_fram_start = .;
		__bss_fram_end = .;
		} 

	LR_ROM ADDR(.text)+SIZEOF(.text)+SIZEOF(LR_FRAM): 
		AT(ADDR(.text) + SIZEOF(.text)+SIZEOF(LR_FRAM))
		{
		kev75401_startup.o (.text)
		kev75401_crt0.o (.text)
		kev75401_relocate.o (.text)
		kev75401_relocate_init.o (.text)
		kev75401_mem_sections.o (.text)
		*(.rodata)
		} 

	LR_SRAM : 
		{
		__text_sram_start = .;
		*(.text)
		__data_sram_start = .;
		*(.data)
		__bss_sram_start = .;
		*(.bss)
		__bss_sram_end = .;
		} 

	__lr_fram    = LOADADDR(LR_FRAM);
	__lr_sram    = LOADADDR(LR_SRAM);
	__text_start = LOADADDR(.text);

	/* provide these symbols if they are referenced 
	   - Note this is the same as weak symbol in arm */
	PROVIDE (end = .);
	PROVIDE (__end = .);
	}