vectors.asm

ucos-IIv2.52在TMS320c6416上的移植

;*********************************************************************
;File:		vectors.asm - vector interrupt table 
;Author:	rongjie 
;Data:		2006.04.20
;modification history:

;DESCRIPTION:
;*********************************************************************



SP			.set	B15			; Redefine for convenience
	
		
	

;******************************************************************************
;						Vector Table
;
; ====== vectors in use ========
;  Plug in the entry point at the ISR function in the interrupt vector table
;
; ====== unused ========
;  plug inifinite loop -- with nested branches to
;  disable interrupts -- for all undefined vectors
;
;******************************************************************************
unused  .macro id

        .global unused:id:
unused:id:
        b unused:id:    ; nested branches to block interrupts
        nop 4
        b unused:id:
        nop
        nop
        nop
        nop
        nop

        .endm
		
		.sect ".vectors"

	    .align  32*8*4          ; must be aligned on 256 word boundary
        .ref _c_int00           ; C entry point

RESET:                          ; reset vector
        mvkl _c_int00,b0        ; load destination function address to b0
        mvkh _c_int00,b0
        b b0                    ; start branch to destination function
        mvc PCE1,b0             ; address of interrupt vectors
        mvc b0,ISTP             ; set table to point here
        nop 3                   ; fill delay slot
        nop
        nop

								;------------------------------------------------
        unused 1 ;NMI     		;  plug unused interrupts with infinite loops to
        unused 2 ;Reserved		;  catch stray interrupts
        unused 3 ;Reserved		;------------------------------------------------
        unused 4 ;INT4
        unused 5 ;INT5
        unused 6 ;INT6
        unused 7 ;INT7
        unused 8 ;INT8
        unused 9 ;INT9
        unused 10 ;INT10
        unused 11 ;INT11
        unused 12 ;INT12
        unused 13 ;INT13
        
INT14: 			; Maskable Interrupt #14
		.global	 _OSTickISR		;OSTickISR for uC/OS-II, as the ISR of Timer0
		STW 	B0, *SP--[2]
	||	MVKL 	_OSTickISR, B0
		MVKH	_OSTickISR, B0
		B		B0
		LDW 	*++SP[2], B0
		NOP 	2
		NOP
		NOP        
        
        unused 15 ;INT15

.end