clientfr.pas

Delphi_7.0数据库开发源代码。有内容十一章节

unit clientfr;



interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DB, DBClient, ExtCtrls, Grids, DBGrids, StdCtrls, MConnect, Variants;

type
  TForm1 = class(TForm)
    SQL: TMemo;
    Label1: TLabel;
    DatabaseName: TComboBox;
    RunButton: TButton;
    DataSource1: TDataSource;
    DBGrid1: TDBGrid;
    Bevel1: TBevel;
    RemoteServer: TDCOMConnection;
    ClientData: TClientDataSet;
    procedure DatabaseNameClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure RunButtonClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  I: Integer;
  DBNames: OleVariant;//数据库名字设定为可变化的类型variant
begin
  RemoteServer.Connected := True; //连接到应用服务器上
  DBNames := RemoteServer.AppServer.GetDatabaseNames;//并得到可用的数据库的名称列表
  if VarIsArray(DBNames) then
    for I := 0 to VarArrayHighBound(DBNames, 1) do
      DatabaseName.Items.Add(DBNames[I]);//将得到的数据库的名称列表存储到数组中
  DatabaseNameClick(Self);
end;

procedure TForm1.RunButtonClick(Sender: TObject);
begin
  //把查询字符串传送到应用服务器端并尝试打开客户端数据集
  ClientData.Close;
  ClientData.CommandText := SQL.Lines.Text;//指定SQL查询语句
  ClientData.Open;
end;

procedure TForm1.DatabaseNameClick(Sender: TObject);
var
  Password: string;
begin
  //改变应用服务器上的数据库名称
  if DatabaseName.Text <> '' then
  begin
    ClientData.Close;
    try
      RemoteServer.AppServer.SetDatabaseName(DatabaseName.Text, '');
    except
      //如上的机制比较粗糙，可能会产生例外，或者是经过更改权限的设定要所取密码
      on E: Exception do
        if E.Message = 'Password Required' then
        begin
          if InputQuery(E.Message, 'Enter password', Password) then
            RemoteServer.AppServer.SetDatabaseName(DatabaseName.Text, Password);
        end else
          raise;
    end;
  end;
end;

end.