command.asp

有很多功能的留言版,很容易上手,有自动添加图片、表情。管理员功能也强大

<script language="vbscript" runat="server">
	'//技术支持:http://localhost/123/index.asp
	'//ReWrite on 2006-04-27 with VBScript by cash.//QQ:87256259//Email:[e-mail]
	
	Class System
		
		Public ArrRs
		
		Public Sub GetWebSys()'//取得全局参数
			Set Rs=Conn.Execute("Execute Gsbook_show_Inc")
				If Rs.Eof Then
					Response.Write "请先设置留言本的参数！"
				Else
					ArrRs=Rs.getrows
				End If
			Rs.close
			Set Rs=Nothing
		End Sub
		
		Public Function FirstUs(BeginUs)
			If BeginUs <> True Then Response.Redirect "Sys_Begin.asp"
		End Function
		
		Public Function CheckFirstUs(BeginUs)
			If BeginUs = True Then CallErr("留言本已完成了初始化设置，请用管理员身份登陆管理后进行站点设置！")
		End Function
		
		Public Function CheckLockIp()
			CookiesLockIp = Request.Cookies("LockIp")
			If CookiesLockIp<>Empty And CookiesLockIp<>"No" Then CallErr("<Li>您的IP已被拒绝访问！")
			If CookiesLockIp = Empty Then
				UserIp = Trim(Request.ServerVariables("REMOTE_ADDR"))
				If Conn.Execute("Execute Gsbook_show_LockIp "&"'"&UserIp&"'").eof Then
					Response.Cookies("LockIp")="No"
				Else
					Response.Cookies("LockIp")="Yes"
					CallErr("<Li>您的IP已被拒绝访问！")
				End If
			End If
		End Function
		
		Public Function Closedb()
			conn.close
			set conn=nothing
		End Function
	End Class
	
	Class CheckUser
	
		Public AdminUser,AdminPass,SaveTime,loginok,GetStyle
		Public UserEdit,UserEditId
		
		Private RegEx
		Private Sub Class_Initialize
		Set regEx = New RegExp
			regEx.IgnoreCase = True
			regEx.Global = True
			AdminUser = ""
			AdminPass = ""
			loginok = ""
			UserEdit = ""
			UserEditId = ""
		End Sub
		
		Public Function CheckOpenGsbook(loginok,OpenGsbook,WebAdvertise)
			If loginok = 0 And OpenGsbook <> True Then CallErr("<Li>留言本已被管理员暂时关闭！<Li>留言板临时公告：<font color=0000FF>"&WebAdvertise&"</font><Li>如果你是管理员，请点此<a href=Login.asp>登陆</a>")
		End Function
		
		Public Function CheckOpenWrite(loginok,OpenWrite)'/检查写权限
			If loginok=0 and OpenWrite<>True Then CallErr("<Li>留言本暂不开放，您没有权限择写！")
		End Function

		Public Function CheckOpenRead(loginok,OpenRead)'/检查读权限
			If loginok=0 and OpenRead<>True Then CallErr("<Li>留言本所有信息已设为保密，您没有权限查看！")
		End Function
		
		Public Sub CallOk(CallType)
			Response.Redirect "CallOk.asp?Type="&CallType
		End Sub
		
		Public Sub GetLoginInfo(sAdminUser,sAdminPass,sSaveTime)
			AdminUser = Trim(sAdminUser)
				If AdminUser = Empty Then CallErr("<li>请输入管理员名字！")
			AdminPass = Trim(sAdminPass)
				If AdminPass = Empty Then CallErr("<li>请输入管理密码！")
			RegEx.Pattern = "['`<>%&.=/\*].*"
			AdminUser = RegEx.Replace(AdminUser,"")
			AdminUser = Replace(AdminUser,mid(" "" ",2,1),"")
			AdminPass = Replace(AdminPass,mid(" "" ",2,1),"")
			SaveTime = Int(sSaveTime)
		End Sub
		
		Public Function CheckUserLogin(AdminUser,AdminPass,sAdminUser,sAdminPass)'//检查用户登陆信息正确性
			If AdminUser<>sAdminUser Or AdminPass<>sAdminPass Then 
				Session("LoginError") = "登陆超时，请重新登陆！"
				Response.Redirect "Login.asp"
			End If
		End Function
		
		Public Sub GetUserCss(sGetStyle)'///////////定义版面式样
			GetStyle = sGetStyle
		End Sub
		
		Public Sub GetUserInfo()'//Cookies方式/取得用户COOKIES信息
			AdminUser=Trim(Request.Cookies("AdminUser"))
			AdminPass=Trim(Request.Cookies("AdminPass"))
			RegEx.Pattern = "['`<>%&.=/\*].*"
			AdminUser = RegEx.Replace(AdminUser,"")
			AdminUser = Replace(AdminUser,mid(" "" ",2,1),"")   
			If AdminUser=empty then
				loginok=0
				Exit sub
			Else 
				loginok=1
				AdminPass = RegEx.Replace(AdminPass,"")
			End If
		End Sub
		
		Public Function SetLoginCookies(AdminUser,AdminPass,SaveTime)'//Cookies方式登陆
			Response.Cookies("AdminUser") = AdminUser
			Response.Cookies("AdminPass") = AdminPass
			Select Case SaveTime
				Case 0
				Case Else
				Response.Cookies("AdminUser").Expires=date+SaveTime
				Response.Cookies("AdminPass").Expires=date+SaveTime
			End Select
		End Function
		
		Public Function GetBackUrl()
			HTTP_REFERER = Request.ServerVariables("HTTP_REFERER")
			If IsNull(HTTP_REFERER) or HTTP_REFERER=Empty or Right(HTTP_REFERER,9) = "Login.asp" Then
				Response.redirect "Index.asp"
			Else
				Response.redirect HTTP_REFERER
			End If
		End Function
		
		Public Function SetLogOut()'//Cookies方式退出
			Response.Cookies("AdminUser") = ""
			Response.Cookies("AdminPass") = ""
		End Function

		Public Function LockUserIp(sIp,Author,GsBookId)
			Ip = Trim(sIp)
			If Not Conn.Execute("Execute Gsbook_show_LockIp "&"'"&Ip&"'").eof Then CallErr("<Li>用户IP[<font color=red>"&Ip&"</font>]已被锁定，不需重复操作！")
			Conn.Execute("Insert Into [LockIp] (Ip,Author,GsBookId) Values ('"&Ip&"','"&Author&"','"&GsBookId&"')")
			Response.write "操作成功"
		End Function
		
		Public Sub SetEditPower()
			UserEdit = Session("UserEdit")
			UserEditId = Session("UserEditId")
		End Sub
		
		Public Sub UserEditLogin(sEditPass,GsBookId,EditPass)
			If Len(EditPass) < 3 Then CallErr("<li>本留言没有设置修改密码，如修改请与管理员联系！")
			If Len(sEditPass) < 3 or Len(sEditPass) > 12 Then CallErr("<li>您输入的密码长度不正确！")
			If isnumeric(sEditPass) = 0 Then CallErr("<li>您输入的密码不正确！")
			If EditPass <> sEditPass Then CallErr("<li>您输入的密码不正确！")
			Session("UserEdit") = "Yes"
			Session("UserEditId") = GsBookId
		End Sub
		
		Public Sub GetEditPower(loginok,EditPass,Add_Date,UserEdit,UserEditId,GsBookId,OpenEdit,EditType)
			Select Case loginok
				Case 0
					If EditType<>3 Then
						If OpenEdit <> True Then CallErr("<li>留言操作功能已被管理员限制，请与管理员联系！")
					End If
					EditPass = Len(EditPass)
					If EditPass < 3 Then CallErr("<li>本留言没有设置密码，您没有权限操作！")
					If UserEdit <> "Yes" Or Int(UserEditId) <> GsBookId  Then Response.Redirect "UserLogin.asp?Id="&GsBookId&"&EditType="&EditType
			 End Select
		End Sub
		
	End Class
	
</script>