cor_func.asm

G.729协议压缩的语音传输程序

                        .mmregs
                        .include "ld8a.inc"
                        .bss  y32,80
                        .global Cor_h_X
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;Compute correlations of input response h[] with the target vector X[]
;void Cor_h_X(
;     Word16 h[],        /* (i) Q12 :Impulse response of filters      */
;     Word16 X[],        /* (i)     :Target vector                    */
;     Word16 D[]         /* (o)     :Correlations between h[] and D[] */
;                        /*          Normalized to 13 bits            */
;)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Cor_h_X:
    pshm  ar0
    pshm  ar2
    pshm  ar3
    pshm  ar4
    pshm  ar5
    frame  -9    ;*sp(0)--i,*sp(1)--j,*sp(2)(3)--s,*sp(4)(5)--max
                 ;*sp(6)(7)--L_temp,*sp(8)--h
                 ;*sp(15)--X,*sp(16)--D
    stl   a,*sp(8)
    stm   #y32,ar4
    stm   #2,ar0
    
    ld   #0,b
    st   #0,*sp(0)
    
    stm  #L_SUBFR-1,brc
    rptb  cor_h_rep-1
    
    ld  *sp(15),a
    add *sp(0),a
    stlm  a,ar2
    mvdk  *sp(8),ar3
    ld   #L_SUBFR,a
    sub  *sp(0),a
    sub  #1,a
    stl  a,*sp(1)
    ld   #0,a
    rpt  *sp(1)
    mac  *ar2+,*ar3+,a
    
    dst  a,*ar4+0           ;y32--ar4
    abs  a
    max  b
    addm  #1,*sp(0)
cor_h_rep:
    exp  b
    st   t,*sp(1)
    ld   *sp(1),16,b
    sub  #16,16,b
    xc   2,bgt
    st   #16,*sp(1)
    
    ld   #18,16,b
    sub  *sp(1),16,b
    neg  b
    sth  b,*sp(1)
    add  #16,16,b
    bc   cor_h_li,bgeq
    stm  #y32,ar4
    stm  #L_SUBFR-1,brc
    rptb cor_h_rep1-1
    dld  *ar4,b
    ld   b,-16,b
    dst  b,*ar4+0
    addm #16,*sp(1)
cor_h_rep1:
    nop
cor_h_li:
    stm  #y32,ar4
    mvdk *sp(16),ar5
    ld   *sp(1),asm
    stm  #L_SUBFR-1,brc
    rptb cor_h_rep2-1
    dld  *ar4+0,b
    ld   b,asm,b
    stl  b,*ar5+ 
cor_h_rep2:   
    
    
    frame  9
    popm  ar5
    popm  ar4
    popm  ar3
    popm  ar2
    popm  ar0
    ret