ansys-flac.txt

ansys to flac3d 的转换程序

!ANSYS转FLAC3D程序，ANSYS中为SOLID45单元
!能转四面体，锲形块，和八面体
!group是以体来分的。

nsel,all
esel,all
NUMCMP,NODE 
NUMCMP,ELEM 
*get,NodeNum,node,,NUM,MAX
*get,EleNum,elem,,NUM,MAX
*dim,NodeData,array,NodeNum,3
*dim,EleData,table,EleNum,8 
 

*do,i,1,NodeNum,1 
  *get,NodeData(i,1),node,i,LOC,x 
  *get,NodeData(i,2),node,i,LOC,y 
  *get,NodeData(i,3),node,i,LOC,z 
*enddo
!写数据到文件 
*GET, filename, ACTIVE, 0, jobname,
*cfopen,filename,dat
*vwrite, 
(';The file from ANSYS') 
*vwrite, 
('NEW') 
*vwrite,sequ,NodeData(1,1),NodeData(1,2),NodeData(1,3) !写入节点信息 
gen point id	 %G %G %G %G  

*do,i,1,EleNum,1 
  *get,N1,elem,i,NODE,1 
  *get,N2,elem,i,NODE,2 
  *get,N3,elem,i,NODE,3
  *get,N4,elem,i,NODE,4 
  *get,N5,elem,i,NODE,5 
  *get,N6,elem,i,NODE,6 
  *get,N7,elem,i,NODE,7 
  *get,N8,elem,i,NODE,8
  *GET, MATNO, ELEMENT, i, ATTR,MAT	

  *if, N3,EQ,N4,then			!判断节点3，4的是否相同
   	*if, N5,EQ,N6, then	 	!写入单元信息 四面体
		*vwrite,N1,N2,N3,N5,MATNO
gen zone tetrahedron size 1 1 1 p0 point %G p1 point %G p2 point %G p3 point %G rat 1 1 1 group %G
  	*else	    			!写入单元信息 五面体
		*vwrite,N1,N3,N5,N2,N7,N6,MATNO
gen zone wedge size 1 1 1 p0 point %G p1 point %G p2 point %G p3 point %G p4 point %G p5 point %G rat 1 1 1 group %G
	*endif
  *else					!写入单元信息 八面体
     		
		*vwrite,N1,N2,N4,N5,N3,N8,N6,N7,MATNO
gen zone brick size 1 1 1 p0 point %G p1 point %G p2 point %G p3 point %G p4 point %G p5 point %G p6 point %G p7 point %G rat 1 1 1 group %G
  *endif
*enddo

*vwrite, 
('plot') 
*vwrite, 
('create view0') 
*vwrite, 
('add block group') 
*vwrite, 
('add axes black') 
*vwrite, 
('show') 
*vwrite, 
('quit') 

*cfclos