rouletteselect.sci

来自「基于SCILAB的The Genetic Algorithm Toolbox f」· SCI 代码 · 共 34 行

function[newPop] = RouletteSelect(oldPop,options)
//roulette is the traditional selection function with the probability of
//surviving equal to the fittness of i / sum of the fittness of all individuals
//
//function[newPop] = roulette(oldPop,options)
//newPop  - the new population selected from the oldPop
//oldPop  - the current population
//options - options [gen]

//Get the parameters of the population
numVars = size(oldPop,2);
numSols = size(oldPop,1);

//Generate the relative probabilites of selection
totalFit = sum(oldPop(:,numVars));
prob=oldPop(:,numVars) / totalFit; 
prob=cumsum(prob);
//disp(prob');

rNums=gsort(rand(numSols,1),'g','i'); 		//Generate random numbers
//disp(rNums');
newPop=zeros(numSols,numVars);
//Select individuals from the oldPop to the new
fitIn=1;newIn=1;
while newIn<=numSols
  if(rNums(newIn)<prob(fitIn))
    newPop(newIn,:) = oldPop(fitIn,:);
    //disp([newIn,fitIn]);
    newIn = newIn+1;
  else
    fitIn = fitIn + 1;
  end
end