jmail.asp

不错的ASP整站源代码。在IIS环境下运行都没有问题

<%
function SendMail(mailto,subject,msg)
dim JMail
'on error resume next
Set JMail = Server.CreateObject("JMail.SMTPMail")
JMail.LazySend 		= true
JMail.silent 		= true
JMail.Charset 		= "gb2312"
JMail.ContentType 	= "text/plain"
JMail.Sender 		= "[e-mail]"
JMail.ReplyTo 		= "[e-mail]"
JMail.SenderName 	= "龙川交友网"
JMail.Subject 		= subject
JMail.SimpleLayout 	= true
JMail.Body 		= msg
JMail.Priority 		= 1
JMail.AppendBodyFromFile(Server.MapPath("/Love/Inc/Mailend.txt"))
JMail.AddRecipient mailto
JMail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR")
SendMail = JMail.Execute()
JMail.Close
set JMail=nothing
call RecordLog(mailto,subject,msg)
end function

function NeedMail(MType,ToID,subject,msg)
dim Rs,sql,Rss
set Rs=server.createobject("adodb.recordset")
sql="select email from user_reg where user_id=" & ToID
Rs.open sql,conn,1,1
If Not Rs.Eof Then
	set Rss=server.createobject("adodb.recordset")
	sql="select * from user_option where user_id=" & Cint(ToID)
	Rss.open sql,conn,1,1
	If Not Rss.Eof Then
		TType=Rss(MType)
	Else
		TType=True
	End If
	Rss.Close
	set Rss=Nothing
	If TType=True Then
		If Rs("email")<>"" Then
			call SendMail(Rs("email"),subject,msg)
		End If
	End If
End If
Rs.Close
end function

function RecordLog(mailto,subject,msg)
Dim LogFileName,FileObject,Out
LogFileName=Server.MapPath("isi/maillog.txt")
Set FileObject=Server.CreateObject("SCRIPTING.FILESYSTEMOBJECT")
Set Out=FileObject.OpenTextFile(LogFileName,8,True)
Out.WriteLine("Time     : " & Now())
Out.WriteLine("MailTo   : " & mailto)
Out.WriteLine("Subject  : " & subject)
Out.WriteLine("Contents : ")
Out.WriteLine(msg)
Out.WriteLine("----------")
Out.WriteLine()
Out.Close
end function
%>