sram.lcf

CodeWarrior IDE!COLDFIRE 5275源程序!

#/*
# * File:		sram.lcf
# * Purpose:	MetroWerks linker command file for the M5275EVB 
# *
# * Notes:		Linked to run in on-chip SRAM.
# *
# */

MEMORY 
{
	sdram		(RWX)	: ORIGIN = 0x00000000, LENGTH = 0x01000000
	sram		(RWX)	: ORIGIN = 0x20000000, LENGTH = 0x00010000
	vector_ram	(RWX)	: ORIGIN = 0x20000000, LENGTH = 0x00000400
	ext_sram	(RWX)	: ORIGIN = 0x30000000, LENGTH = 0x00080000
	ipsbar		(RWX)	: ORIGIN = 0x40000000, LENGTH = 0x40000000
	ext_flash	(RWX)	: ORIGIN = 0xFFE00000, LENGTH = 0x00200000
}

SECTIONS 
{
	.sdram		: {} > sdram
	.ipsbar		: {} > ipsbar
	.ext_sram	: {} > ext_sram
	.ext_flash	: {} > ext_flash
	.vector_ram	: {} > vector_ram
	
	.sram :
	{
		vectors.s (.text)
		*(.text)
		*(.rodata)
		___DATA_ROM = .;

		___DATA_RAM = .;
		*(.data)
		*(.sdata)
		___DATA_END = .;
 
		___BSS_START = .;
		*(.sbss)
		*(SCOMMON)
		*(.bss)
		*(COMMON)
		___BSS_END = .;

		___HEAP_START	= .;
		.				= . + 0x1000;
		___HEAP_END		= .;
		___SP_END		= .;
		.				= . + 0x1000;
		___SP_INIT		= .;
	} > sram
	
	___IPSBAR			= ADDR(.ipsbar);
	___VECTOR_RAM		= ADDR(.vector_ram);

	___SDRAM			= ADDR(.sdram);
	___SDRAM_SIZE		= 0x01000000;

	___SRAM				= ADDR(.sram);
	___SRAM_SIZE		= 0x00010000;

	___EXT_SRAM			= ADDR(.ext_sram);
	___EXT_SRAM_SIZE	= 0x00080000;

	___EXT_FLASH		= ADDR(.ext_flash);
	___EXT_FLASH_SIZE	= 0x00200000;
}