mmxidct.s

PIXIL is a small footprint operating environment, complete with PDA PIM applications, a browser and

* moved above
*	movq %mm3, %mm5			duplicate tmt5
*	movq 8*13(%esi), %mm4		tmt13
*/
	psubsw %mm4, %mm3		/* V134 */
	pmulhw x5a825a825a825a82, %mm3	/* 23170 ->V136 */
	movq 8*9(%esi), %mm6		/* tmt9 */
	paddsw %mm4, %mm5		/* V135 ; mm4 free */
	movq %mm0, %mm4			/* duplicate tmt1 */
	paddsw %mm6, %mm0		/* V137 */
	psubsw %mm6, %mm4		/* V138 ; mm6 free */
	psllw $2, %mm3			/* t290 */
	psubsw %mm5, %mm3		/* V139 */
	movq %mm0, %mm6			/* duplicate V137 */
	paddsw %mm5, %mm0		/* V140 */
	movq %mm4, %mm2			/* duplicate V138 */
	paddsw %mm3, %mm2		/* V141 */
	psubsw %mm3, %mm4		/* V142 ; mm3 free */
	movq %mm0, 8*9(%esi)		/* V140 */
	psubsw %mm5, %mm6		/* V143 ; mm5 free */
/* moved from next block */
	movq 8*11(%esi), %mm0		/* tmt11 */
	movq %mm2, 8*13(%esi)		/* V141 */
/* moved from next block */
	movq %mm0, %mm2			/* duplicate tmt11 */
/* column 1: odd part (after transpose) */
/* moved up to the prev block
 *	movq 8*11(%esi), %mm0		tmt11
 *	movq %mm0, %mm2			duplicate tmt11
 */
	movq 8*15(%esi), %mm5		/* tmt15 */
	psubsw %mm7, %mm0		/* V144 */
	movq %mm0, %mm3			/* duplicate V144 */
	paddsw %mm7, %mm2		/* V147 ; free mm7 */
	pmulhw x539f539f539f539f, %mm0	/* 21407-> V151 */
	movq %mm1, %mm7			/* duplicate tmt3 */
	paddsw %mm5, %mm7		/* V145 */
	psubsw %mm5, %mm1		/* V146 ; free mm5 */
	psubsw %mm1, %mm3		/* V150 */
	movq %mm7, %mm5			/* duplicate V145 */
	pmulhw x4546454645464546, %mm1	/* 17734-> V153 */
	psubsw %mm2, %mm5		/* V148 */
	pmulhw x61f861f861f861f8, %mm3	/* 25080-> V154 */
	psllw $2, %mm0			/* t311 */
	pmulhw x5a825a825a825a82, %mm5	/* 23170-> V152 */
	paddsw %mm2, %mm7		/* V149 ; free mm2 */
	psllw $1, %mm1			/* t313 */
	nop	/* without the nop - freeze here for one clock */
	movq %mm3, %mm2			/* duplicate V154 */
	psubsw %mm0, %mm3		/* V155 ; free mm0 */
	psubsw %mm2, %mm1		/* V156 ; free mm2 */
/* moved from the next block */
	movq %mm6, %mm2			/* duplicate V143 */
/* moved from the next block */
	movq 8*13(%esi), %mm0		/* V141 */
	psllw $1, %mm1			/* t315 */
	psubsw %mm7, %mm1		/* V157 (keep V149) */
	psllw $2, %mm5			/* t317 */
	psubsw %mm1, %mm5		/* V158 */
	psllw $1, %mm3			/* t319 */
	paddsw %mm5, %mm3		/* V159 */
/* column 1: output butterfly (after transform)
 * moved to the prev block
 *	movq %mm6, %mm2			duplicate V143
 *	movq 8*13(%esi), %mm0		V141
 */
	psubsw %mm3, %mm2		/* V163 */
	paddsw %mm3, %mm6		/* V164 ; free mm3 */
	movq %mm4, %mm3			/* duplicate V142 */
	psubsw %mm5, %mm4		/* V165 ; free mm5 */
	movq %mm2, scratch7		/* out7 */
	psraw $4, %mm6
	psraw $4, %mm4
	paddsw %mm5, %mm3		/* V162 */
	movq 8*9(%esi), %mm2		/* V140 */
	movq %mm0, %mm5			/* duplicate V141 */
/* in order not to perculate this line up,
 * we read 72(%esi) very near to this location
 */

        movq %mm6, 8*9(%edi)		/* out9 */
	paddsw %mm1, %mm0		/* V161 */
	movq %mm3, scratch5		/* out5 */
	psubsw %mm1, %mm5		/* V166 ; free mm1 */
	movq %mm4, 8*11(%edi)		/* out11 */
	psraw $4, %mm5
	movq %mm0, scratch3		/* out3 */
	movq %mm2, %mm4			/* duplicate V140 */
	movq %mm5, 8*13(%edi)		/* out13 */
	paddsw %mm7, %mm2		/* V160 */
/* moved from the next block */
	movq 8(%esi), %mm0
	psubsw %mm7, %mm4		/* V167 ; free mm7 */
/* moved from the next block */
	movq 8*3(%esi), %mm7
	psraw $4, %mm4
	movq %mm2, scratch1		/* out1 */
/* moved from the next block */
	movq %mm0, %mm1
	movq %mm4, 8*15(%edi)		/* out15 */
/* moved from the next block */
	punpcklwd %mm7, %mm0
/* transpose - M2 parts
 * moved up to the prev block
 *	movq 8(%esi), %mm0
 *	movq 8*3(%esi), %mm7
 *	movq %mm0, %mm1
 *	punpcklwd %mm7, %mm0
 */
	movq 8*5(%esi), %mm5
	punpckhwd %mm7, %mm1
	movq 8*7(%esi), %mm4
	movq %mm5, %mm3
/* shuffle the data and write the lower parts of the trasposed in 4 dwords */
	movd %mm0, 8*8(%esi)		/* LS part of tmt8 */
	punpcklwd %mm4, %mm5
	movd %mm1, 8*12(%esi)		/* LS part of tmt12 */
	punpckhwd %mm4, %mm3
	movd %mm5, 8*8+4(%esi)		/* MS part of tmt8 */
	punpckhdq %mm5, %mm0		/* tmt10 */
	movd %mm3, 8*12+4(%esi)		/* MS part of tmt12 */
	punpckhdq %mm3, %mm1		/* tmt14 */
/* transpose - M1 parts */
	movq (%esi), %mm7
	movq 8*2(%esi), %mm2
	movq %mm7, %mm6
	movq 8*4(%esi), %mm5
	punpcklwd %mm2, %mm7
	movq 8*6(%esi), %mm4
	punpckhwd %mm2, %mm6		/* free mm2 */
	movq %mm5, %mm3
	punpcklwd %mm4, %mm5
	punpckhwd %mm4, %mm3		/* free mm4 */
	movq %mm7, %mm2
	movq %mm6, %mm4
	punpckldq %mm5, %mm7		/* tmt0 */
	punpckhdq %mm5, %mm2		/* tmt2 ; free mm5 */
/* shuffle the rest of the data, and write it with 2 mmword writes */
	punpckldq %mm3, %mm6		/* tmt4 */
/* moved from next block */
	movq %mm2, %mm5			/* duplicate tmt2 */
	punpckhdq %mm3, %mm4		/* tmt6 ; free mm3 */
/* moved from next block */
	movq %mm0, %mm3			/* duplicate tmt10 */
/* column 0: odd part (after transpose)
 *moved up to prev block
 *	movq %mm0, %mm3			duplicate tmt10
 *	movq %mm2, %mm5			duplicate tmt2
 */
	psubsw %mm4, %mm0		/* V110 */
	paddsw %mm4, %mm3		/* V113 ; free mm4 */
	movq %mm0, %mm4			/* duplicate V110 */
	paddsw %mm1, %mm2		/* V111 */
	pmulhw x539f539f539f539f, %mm0	/* 21407-> V117 */
	psubsw %mm1, %mm5		/* V112 ; free mm1 */
	psubsw %mm5, %mm4		/* V116 */
	movq %mm2, %mm1			/* duplicate V111 */
	pmulhw x4546454645464546, %mm5	/* 17734-> V119 */
	psubsw %mm3, %mm2		/* V114 */
	pmulhw x61f861f861f861f8, %mm4	/* 25080-> V120 */
	paddsw %mm3, %mm1		/* V115 ; free mm3 */
	pmulhw x5a825a825a825a82, %mm2	/* 23170-> V118 */
	psllw $2, %mm0			/* t266 */
	movq %mm1, (%esi)		/* save V115 */
	psllw $1, %mm5			/* t268 */
	psubsw %mm4, %mm5		/* V122 */
	psubsw %mm0, %mm4		/* V121 ; free mm0 */
	psllw $1, %mm5			/* t270 */
	psubsw %mm1, %mm5		/* V123 ; free mm1 */
	psllw $2, %mm2			/* t272 */
	psubsw %mm5, %mm2		/* V124 (keep V123) */
	psllw $1, %mm4			/* t274 */
	movq %mm5, 8*2(%esi)		/* save V123 ; free mm5 */
	paddsw %mm2, %mm4		/* V125 (keep V124) */
/* column 0: even part (after transpose) */
	movq 8*12(%esi), %mm0		/* tmt12 */
	movq %mm6, %mm3			/* duplicate tmt4 */
	psubsw %mm0, %mm6		/* V100 */
	paddsw %mm0, %mm3		/* V101 ; free mm0 */
	pmulhw x5a825a825a825a82, %mm6	/* 23170 ->V102 */
	movq %mm7, %mm5			/* duplicate tmt0 */
	movq 8*8(%esi), %mm1		/* tmt8 */
	paddsw %mm1, %mm7		/* V103 */
	psubsw %mm1, %mm5		/* V104 ; free mm1 */
	movq %mm7, %mm0			/* duplicate V103 */
	psllw $2, %mm6			/* t245 */
	paddsw %mm3, %mm7		/* V106 */
	movq %mm5, %mm1			/* duplicate V104 */
	psubsw %mm3, %mm6		/* V105 */
	psubsw %mm3, %mm0		/* V109; free mm3 */
	paddsw %mm6, %mm5		/* V107 */
	psubsw %mm6, %mm1		/* V108 ; free mm6 */
/* column 0: output butterfly (after transform) */
	movq %mm1, %mm3			/* duplicate V108 */
	paddsw %mm2, %mm1		/* out4 */
	psraw $4, %mm1
	psubsw %mm2, %mm3		/* out10 ; free mm2 */
	psraw $4, %mm3
	movq %mm0, %mm6			/* duplicate V109 */
	movq %mm1, 8*4(%edi)		/* out4 ; free mm1 */
	psubsw %mm4, %mm0		/* out6 */
	movq %mm3, 8*10(%edi)		/* out10 ; free mm3 */
	psraw $4, %mm0
	paddsw %mm4, %mm6		/* out8 ; free mm4 */
	movq %mm7, %mm1			/* duplicate V106 */
	movq %mm0, 8*6(%edi)		/* out6 ; free mm0 */
	psraw $4, %mm6
	movq (%esi), %mm4		/* V115 */
	movq %mm6, 8*8(%edi)		/* out8 ; free mm6 */
	movq %mm5, %mm2			/* duplicate V107 */
	movq 8*2(%esi), %mm3		/* V123 */
	paddsw %mm4, %mm7		/* out0 */
/* moved up from next block */
	movq scratch3, %mm0
	psraw $4, %mm7
/* moved up from next block */
	movq scratch5, %mm6 
	psubsw %mm4, %mm1		/* out14 ; free mm4 */
	paddsw %mm3, %mm5		/* out2 */
	psraw $4, %mm1
	movq %mm7, (%edi)		/* out0 ; free mm7 */
	psraw $4, %mm5
	movq %mm1, 8*14(%edi)		/* out14 ; free mm1 */
	psubsw %mm3, %mm2		/* out12 ; free mm3 */
	movq %mm5, 8*2(%edi)		/* out2 ; free mm5 */
	psraw $4, %mm2
/* moved up to the prev block */
	movq scratch7, %mm4
/* moved up to the prev block */
	psraw $4, %mm0
	movq %mm2, 8*12(%edi)		/* out12 ; free mm2 */
/* moved up to the prev block */
	psraw $4, %mm6
/* move back the data to its correct place
* moved up to the prev block
 *	movq scratch3, %mm0
 *	movq scratch5, %mm6
 *	movq scratch7, %mm4
 *	psraw $4, %mm0
 *	psraw $4, %mm6
*/
	movq scratch1, %mm1
	psraw $4, %mm4
	movq %mm0, 8*3(%edi)		/* out3 */
	psraw $4, %mm1
	movq %mm6, 8*5(%edi)		/* out5 */
	movq %mm4, 8*7(%edi)		/* out7 */
	movq %mm1, 8(%edi)		/* out1 */
	popl %edi
	popl %esi
	popl %edx
	popl %ecx
	popl %ebx
	movl %ebp,%esp
	popl %ebp
	ret
.Lfe1:
	.size	 IDCT_mmx,.Lfe1-IDCT_mmx




       	.align 8
.text
	.align 4
.globl IDCT_16bit8bit
	.type	 IDCT_16bit8bit,@function
IDCT_16bit8bit:
	pushl %ebp
	movl %esp,%ebp
	pushl %ebx
	pushl %ecx
	pushl %edx
	pushl %esi
	pushl %edi
        movl 16(%ebp),%ebx		/* output skip */
        movl 12(%ebp),%edi		/* output XXX */
       	movl 8(%ebp),%esi		/* source matrix */

        movq 1*8(%esi),%mm0
        movq 0*8(%esi),%mm1
        packuswb %mm0,%mm1
        movq %mm1,(%edi)
        add %ebx,%edi

        movq 3*8(%esi),%mm0
        movq 2*8(%esi),%mm1
        packuswb %mm0,%mm1
        movq %mm1,(%edi)
        add %ebx,%edi

        movq 5*8(%esi),%mm0
        movq 4*8(%esi),%mm1
        packuswb %mm0,%mm1
        movq %mm1,(%edi)
        add %ebx,%edi

        movq 7*8(%esi),%mm0
        movq 6*8(%esi),%mm1
        packuswb %mm0,%mm1
        movq %mm1,(%edi)
        add %ebx,%edi

        movq 9*8(%esi),%mm0
        movq 8*8(%esi),%mm1
        packuswb %mm0,%mm1
        movq %mm1,(%edi)
        add %ebx,%edi

        movq 11*8(%esi),%mm0
        movq 10*8(%esi),%mm1
        packuswb %mm0,%mm1
        movq %mm1,(%edi)
        add %ebx,%edi

        movq 13*8(%esi),%mm0
        movq 12*8(%esi),%mm1
        packuswb %mm0,%mm1
        movq %mm1,(%edi)
        add %ebx,%edi

        movq 15*8(%esi),%mm0
        movq 14*8(%esi),%mm1
        packuswb %mm0,%mm1
        movq %mm1,(%edi)
        
        popl %edi
	popl %esi
	popl %edx
	popl %ecx
	popl %ebx
	movl %ebp,%esp
	popl %ebp
	ret





       	.align 8
.text
	.align 4
.globl IDCT_16bit8bit_add
	.type	 IDCT_16bit8bit_add,@function
IDCT_16bit8bit_add:
	pushl %ebp
	movl %esp,%ebp
	pushl %ebx
	pushl %ecx
	pushl %edx
	pushl %esi
	pushl %edi
        movl 16(%ebp),%ebx		/* output skip */
        movl 12(%ebp),%edi		/* output XXX */
       	movl 8(%ebp),%esi		/* source matrix */

        pxor %mm7,%mm7
        
        movq (%edi),%mm2
        movq 1*8(%esi),%mm0
        movq %mm2,%mm3
        movq 0*8(%esi),%mm1
        punpcklbw %mm7,%mm3
        punpckhbw %mm7,%mm2
        paddw %mm1,%mm3
        paddw %mm0,%mm2
        packuswb %mm2,%mm3
        movq %mm3,(%edi)
        add %ebx,%edi
        
        movq (%edi),%mm2
        movq 3*8(%esi),%mm0
        movq %mm2,%mm3
        movq 2*8(%esi),%mm1
        punpcklbw %mm7,%mm3
        punpckhbw %mm7,%mm2
        paddw %mm1,%mm3
        paddw %mm0,%mm2
        packuswb %mm2,%mm3
        movq %mm3,(%edi)
        add %ebx,%edi
        
        movq (%edi),%mm2
        movq 5*8(%esi),%mm0
        movq %mm2,%mm3
        movq 4*8(%esi),%mm1
        punpcklbw %mm7,%mm3
        punpckhbw %mm7,%mm2
        paddw %mm1,%mm3
        paddw %mm0,%mm2
        packuswb %mm2,%mm3
        movq %mm3,(%edi)
        add %ebx,%edi
        
        movq (%edi),%mm2
        movq 7*8(%esi),%mm0
        movq %mm2,%mm3
        movq 6*8(%esi),%mm1
        punpcklbw %mm7,%mm3
        punpckhbw %mm7,%mm2
        paddw %mm1,%mm3
        paddw %mm0,%mm2
        packuswb %mm2,%mm3
        movq %mm3,(%edi)
        add %ebx,%edi
        
        movq (%edi),%mm2
        movq 9*8(%esi),%mm0
        movq %mm2,%mm3
        movq 8*8(%esi),%mm1
        punpcklbw %mm7,%mm3
        punpckhbw %mm7,%mm2
        paddw %mm1,%mm3
        paddw %mm0,%mm2
        packuswb %mm2,%mm3
        movq %mm3,(%edi)
        add %ebx,%edi
        
        movq (%edi),%mm2
        movq 11*8(%esi),%mm0
        movq %mm2,%mm3
        movq 10*8(%esi),%mm1
        punpcklbw %mm7,%mm3
        punpckhbw %mm7,%mm2
        paddw %mm1,%mm3
        paddw %mm0,%mm2
        packuswb %mm2,%mm3
        movq %mm3,(%edi)
        add %ebx,%edi
        
        movq (%edi),%mm2
        movq 13*8(%esi),%mm0
        movq %mm2,%mm3
        movq 12*8(%esi),%mm1
        punpcklbw %mm7,%mm3
        punpckhbw %mm7,%mm2
        paddw %mm1,%mm3
        paddw %mm0,%mm2
        packuswb %mm2,%mm3
        movq %mm3,(%edi)
        add %ebx,%edi
        
        movq (%edi),%mm2
        movq 15*8(%esi),%mm0
        movq %mm2,%mm3
        movq 14*8(%esi),%mm1
        punpcklbw %mm7,%mm3
        punpckhbw %mm7,%mm2
        paddw %mm1,%mm3
        paddw %mm0,%mm2
        packuswb %mm2,%mm3
        movq %mm3,(%edi)
        
        popl %edi
	popl %esi
	popl %edx
	popl %ecx
	popl %ebx
	movl %ebp,%esp
	popl %ebp
	ret