build.bat

来自「一个java方面的消息订阅发送的源码」· Batch 代码 · 共 58 行

@echo off
rem ---------------------------------------------------------------------------
rem Build script for the OpenJMS examples
rem
rem Required Environment Variables
rem
rem   JAVA_HOME       Points to the Java Development Kit installation.
rem
rem Optional Environment Variables
rem 
rem   OPENJMS_HOME    Points to the OpenJMS installation directory.
rem
rem $Id: build.bat,v 1.1 2004/11/26 02:59:08 tanderson Exp $
rem ---------------------------------------------------------------------------

if "%OS%" == "Windows_NT" setlocal

if not "%JAVA_HOME%" == "" goto gotJavaHome
echo The JAVA_HOME environment variable is not set.
echo This is required to build the examples.
exit /B 1

:gotJavaHome

if exist "%JAVA_HOME%\bin\javac.exe" goto okJavaHome
echo The JAVA_HOME environment variable is not set correctly.
echo This is required to build the examples.
exit /B 1

:okJavaHome

set _RUNJAVAC="%JAVA_HOME%\bin\javac.exe"

rem Guess OPENJMS_HOME if it is not set
if not "%OPENJMS_HOME%" == "" goto gotOpenJMSHome
set OPENJMS_HOME=..\..
if exist "%OPENJMS_HOME%\lib\@OPENJMS@" goto okOpenJMSHome
echo The OPENJMS_HOME variable is not set.
echo This is required to build the examples.
exit /B 1

:gotOpenJMSHome

if exist "%OPENJMS_HOME%\lib\@OPENJMS@" goto okOpenJMSHome
echo The OPENJMS_HOME variable is not set correctly.
echo This is required to build the examples.
exit /B 1

:okOpenJMSHome

set CLASSPATH=%OPENJMS_HOME%\lib\@OPENJMS@;%OPENJMS_HOME%\lib\@JMS@;%OPENJMS_HOME%\lib\@JNDI@

echo Using OPENJMS_HOME: %OPENJMS_HOME%
echo Using JAVA_HOME:    %JAVA_HOME%
echo Using CLASSPATH:    %CLASSPATH%

%_RUNJAVAC% -g -classpath "%CLASSPATH%" *.java