fet140_uart11_02400.s43

MSP430系列单片机P140算法源代码集

#include  "msp430x14x.h"
;******************************************************************************
;   MSP-FET430P140 Demo - USART1 UART 2400 Ultra-low Power Echo ISR, 32kHz ACLK
;
;   Description; Echo a received character, RX ISR used. Normal mode is LPM3, 
;   USART0 RX interrupt triggers TX Echo. 
;   ACLK = UCLK1 = LFXT1 = 32768Hz, MCLK = SMCLK = DCOCLK
;   Baud rate divider with 32768hz XTAL @2400 = 32768Hz/2400 = 13.65 (000Dh)
;   //*An external watch crystal on XIN XOUT is required for ACLK*//	  
;              
;                MSP430F149
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32kHz  
;          --|RST          XOUT|-
;            |                 |
;            |             P3.6|-----------> 
;            |                 | 2400 - 8N1
;            |             P3.7|<-----------
;
;    M.Buccini
;    Texas Instruments, Inc
;    February 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     01100h                  ; Progam Start 
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize 'F149 stackpointer
            call    #Init_Sys               ;
                                            ;   
Mainloop    bis.b   #LPM3,SR                ; Enter LPM3
            jmp     Mainloop                ; Do nothing
                                            ;
;------------------------------------------------------------------------------ 
Init_Sys;   Initalize MSP430 system
;------------------------------------------------------------------------------ 
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupUART0  mov.b   #CHAR,&UCTL1            ; 8-bit characters
            mov.b   #SSEL0,&UTCTL1          ; UCLK = ACLK
            mov.b   #00Dh,&UBR01            ; 32k/2400 - 13.65
            mov.b   #000h,&UBR11            ; 32k 2400
            mov.b   #06Bh,&UMCTL1           ; 32k 2400 modulation 
            bis.b   #UTXE1+URXE1,&ME2       ; Enable USART1 TXD/RXD
            bis.b   #URXIE1,&IE2            ; Enable USART1 RX interrupt
SetupP3     bis.b   #0C0h,&P3SEL            ; P3.6,7 = USART1 option select
            bis.b   #040h,&P3DIR            ; P3.6 = output direction 
            eint                            ; General enable interrupts
            ret                             ; Return from subroutine
                                            ;             
;------------------------------------------------------------------------------ 
USART1RX_ISR;  Echo back RXed character, confirm TX buffer is ready first
;------------------------------------------------------------------------------ 
TX1         bit.b   #UTXIFG1,&IFG2          ; USART1 TX buffer ready?
            jz      TX1                     ; Jump is TX buffer not ready
            mov.b   &RXBUF1,&TXBUF1         ; TX -> RXed character
            reti                            ; 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x13x/14x        
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; 
            DW      RESET                   ; POR, ext. Reset, Watchdog
            ORG     0FFE6h                  ; 
            DW      USART1RX_ISR            ; USART1 receive
            end