fet140_tb03.s43

MSP430系列单片机P140算法源代码集

#include  "msp430x14x.h"
;******************************************************************************
;   MSP-FET430P140 Demo - Timer_B Toggle P1.0, TBoverflow ISR, DCO SMCLK
;
;   Description; Toggle P1.0 using using software and timer_B overflow ISR. 
;   In this example an ISR will trigger when TB overflows.  Inside the TA
;   overflow ISR P1.0 is toggled.  Toggle rate is approximatlely 12hz. 
;   MCLK = SMCLK = TBCLK = DCO ~ 800k 
;
;                MSP430F149
;             -----------------
;         /|\|              XIN|-  
;          | |                 |
;          --|RST          XOUT|-
;            |                 |
;            |             P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     01100h                  ; Progam Start 
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize 'F149 stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupTB     mov.w   #TBSSEL1+TBCLR+TBIE,&TBCTL  ; SMCLK, clr. TAR, interrupt
SetupP1     bis.b   #001h,&P1DIR            ; P1.0 output 
            bis.w   #MC1,&TBCTL             ; Start timer_B continous mode
            eint                            ; Enable interrupts
                                            ;						  
Mainloop    bis.w   #CPUOFF,SR              ; CPU off
            nop                             ; Required for C-spy
                                            ;
;------------------------------------------------------------------------------ 
TBX_ISR;    Common ISR for TBCCR1-6 and overflow
;------------------------------------------------------------------------------ 
            add.w   &TBIV,PC                ; Add Timer_B offset vector
            reti                            ; TBCCR0 - no source
            reti                            ; TBCCR1
            reti                            ; TBCCR2
            reti                            ; TBCCR3
            reti                            ; TBCCR4
            reti                            ; TBCCR5
            reti                            ; TBCCR6
TB_over     xor.b   #001h,&P1OUT            ; Toggle P1.0
            reti                            ; Return from overflow ISR		 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x13x/14x          
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF8h                  ; Timer_BX Vector
            DW      TBX_ISR                 ; 
            END