image.ld

嵌入式实时内核源代码

/*==========================================================================
** Copyright (c) 2000-2004,  Elastos, Inc.  All Rights Reserved.
**==========================================================================
*/

/*
** image.ld -- ld script for Elaxir image
*/
OUTPUT_FORMAT(pei-i386)
ENTRY(_mainCRTStartup)
SECTIONS
{
    . = __image_base__;
    __ImageBegin = __image_base__;

    . += SIZEOF_HEADERS;

    . = ALIGN(0x1000);

    .text ALIGN(__section_alignment__) :
    {
        __TextBegin = .;

        __GlobalCtorBegin = .;
        *(SORT(.ctors.*));
        *(.ctors);
        *(.ctor);
        __GlobalCtorEnd = .;

        *(.text)
        *(SORT(.text$*))

        *(.data)
        *(SORT(.data$*))

        *(.rdata)
        *(SORT(.rdata$*))

        *(.bss)
        *(COMMON)

        __TextEnd = .;
    }

    __ImageEnd = .;

    .stab ALIGN(__section_alignment__) (NOLOAD) :
    {
        *(.stab)
    }

    .stabstr ALIGN(__section_alignment__) (NOLOAD) :
    {
        *(.stabstr)
    }

    /DISCARD/ :
    {
        *(.idata)
        *(.edata)
        *(.reloc)
    }

}