sched_arm9.s

一个基于MMU的操作系统

#define 	PID_OFT		0
#define	STATE_OFT		4
#define	COUNT_OFT		8
#define	TIMER_OFT		12
#define	PRIORITY_OFT	16
#define	CONTENT_OFT		20
#define	KERNELSTACK_OFT	100
#define	SIZEOF_TASK_STRUCT	100+1024*4
		

@ 应该转换成虚拟地址	
#define	SDRAM_BASE		0x30000000
#define	SDRAM_SIZE		0x04000000		
	
	
@ 寄存器切换
@ __switch_to(struct task_struct pcur,struct task_struct pnext):	
@ r0 = &pcur, r1 = &pnext
@ 对于linux,__switch_to在arch/arm/kernel/entry-armv.S中定义,以下代码参考它
@ 原进程处于usr/sys模式时(现在处于irq模式：调用__switch_to时处于irq模式的话，原进程必为usr/sys模式)：	
@ 在task[i].content中保存：sp_svc(在此未变，不必再保存),spsr_irq(即cpsr_usr/sys),sp_usr/sys,spsr_usr/sys(不用保存，无此寄存器),"进入irq时，irq堆栈中保存的{r0-r12,lr}"	
@ 原进程处于svc模式时：	
@ 在task[i].content中保存：sp_usr/sys,cpsr,sp_svc,spsr_svc,{r0-r12,lr}
@ 假设处于原来进程状态，给task[i].content中的内容名(int表示被中断时):sp_backup,cpsr_int,sp_int,spsr_int,r0-r12,lr			
@ 恢复时，根据task[i].content中的内容:	
@ 如果spsr_int为svc模式，则先进入sys模式：sp=sp_backup,cpsr=cpsr_int(现在为svc模式),sp=sp_int,spsr=spsr_int,然后恢复{r0-r12,lr}到{r0-r12,pc}
@ 如果spsr_int为usr/sys模式，则先进入svc模式：sp=sp_backup,cpsr=cpsr_int(现在为usr/sys模式),sp=sp_int,然后恢复{r0-r12,lr}到{r0-r12,pc}	
		
@ ENTRY(__switch_to)
.global __switch_to
__switch_to:			@ __switch_to有可能从irq和svc模式调用
	mrs	r2, cpsr
	bic	r2, r2,#0xffffffe0
	cmp	r2, #0x12		@ 判断是否为irq模式
	beq	irq_mode_save
	cmp	r2, #0x13
	beq	svc_mode_save
	mov	pc,lr
irq_mode_save:
	@ 保存原进程(usr/sys模式):	
	add	r0, r0,#CONTENT_OFT
	ldr	sp, =(SDRAM_BASE+0x100000-14*4)

	add	r0, r0,#4		@ 对应sp_svc，不必再存

	mrs	r2, spsr		@ 读出spsr，保存
	stmia	r0!,{r2}
	
	stmia	r0!,{sp}^		@ usr/sys模式下的sp

	mov	r2, #0x13		@ 对于usr/sys模式，无spsr，自己写值进去:0x13(表示svc模式)	
	stmia	r0!,{r2}

	ldmia	sp!,{r2-r8}		@ 把进入中断时保存的寄存器转移到当前task struct中
	stmia	r0!,{r2-r8}
	ldmia	sp!,{r2-r8}
	stmia	r0!,{r2-r8}

	@ 要切换了...
do_switch:		
	ldr	r0, [r1,#PID_OFT]	@ 要切换到的进程的PID
	mov	r0, r0, lsl #25	@ PID存在寄存器的最高7位	
	mcr	p15, 0, r0, c13, c0, 0	@ 写next_pid,从此，VA<32M的取址计算公式就变了，不过现在的VA总是大于32M的

	add	r1, r1, #CONTENT_OFT	@ r1 = &task[next].content

	ldmia	r1!,{r2-r5}		@ sp_backup,cpsr_int,sp_int,spsr_int

	mov	r0, r5
	bic	r0, r0,#0xffffffe0
	cmp	r0, #0x13		@ 判断是sp_backup对应的模式是否为svc模式
	msreq	cpsr_c,#0xd3	@ 若是，进入svc模式
	msrne	cpsr_c,#0xdf	@ 否则，进入sys模式
	mov	sp, r2		@ 设置sp_backup
	msr	cpsr_cxsf,r3	@ 被中断时的cpsr_int
	mov	sp,r4		@ sp_int
	msrne	spsr_cxsf, r5	@ usr/sys模式是没有spsr的

	@ 清中断
@	mov	r0, #0x4a000000
@	mov	r2, #0x400
@	str	r2, [r0]
@	add	r0, r0,#0x10
@	ldr	r2, [r0]
@	str	r2, [r0]

@	mov	pc, #0
	
	mov	r0,r1
	ldmia	r0,{r0-r12,pc}	@ 终于切换了

svc_mode_save:
	@ 保存原进程(svc模式):		
	add	r0, r0,#CONTENT_OFT

	stmia	r0!,{sp}^		@ 对应sp_usr/sys

	mrs	r2, cpsr		@ 读出cpsr，保存
	stmia	r0!,{r2}
	
	stmia	r0!,{sp}		@ svc模式下的sp

	mrs	r2, spsr		@ 对应spsr_svc
	stmia	r0!,{r2}	

	stmia	r0!,{r0-r12,lr}

	b	do_switch