callddk.txt

来自「这是一个在VC下开发WDM驱动程序的小工具」· 文本 代码 · 共 45 行

@ECHO OFF
REM    #####################################################################
REM    #                                                                   #
REM    #    FileName: CallDDK.bat                                          #
REM    #    Function: Compile & Build Microsoft(R) Windows NT Driver       #
REM    #  Written By: ZhenlongYang 02/27/2006                              #
REM    #                                                                   #
REM    #####################################################################
REM    +---------------- Parameter Declare --------------------------------+
REM    |                                                                   |
REM    |    %1 -> DDK path(X:\NTDDK)                                       |
REM    |    %2 -> "checked" or "free"                                      |
REM    |    %3 -> Source files path                                        |
REM    |                                                                   |
REM    +-------------------------------------------------------------------+

if "%1" == "/?" goto help
if NOT "%2" == "checked" if NOT "%2" == "free" goto end
if NOT EXIST %1 goto end
if NOT EXIST %3 goto end

if "%2" == "checked" set ERROR_FILE_NAME=buildchk.err
if "%2" == "free"    set ERROR_FILE_NAME=buildfre.err

if NOT EXIST %1\bin\setenv.bat set MISS_FILE=%1\bin\setenv.bat& goto errMissFile
if NOT EXIST %1\bin\build.exe  set MISS_FILE=%1\bin\build.exe&  goto errMissFile
if NOT EXIST %3\MAKEFILE       set MISS_FILE=%3\MAKEFILE&       goto errMissFile
if NOT EXIST %3\SOURCES        set MISS_FILE=%3\SOURCES&        goto errMissFile

call %1\bin\setenv.bat %1 %2
cd /d %3
if EXIST %ERROR_FILE_NAME% del /F /Q %ERROR_FILE_NAME%
build
goto end

:errMissFile
echo Missing file: %MISS_FILE%> %3\%ERROR_FILE_NAME%
goto end

:help
echo CALLDDK ^<ddk-path^> ^<checked^|free^> ^<sourcefile-path^>
goto end

:end